Microsoft 365 Ouvrir un fichier Excel rapidement en VBA

[iliess]

Je suis actuellement chargé de la gestion comptable sur un logiciel de comptabilité qui me donne la capacité de générer des états financiers sous forme de fichiers Excel. Cependant, un inconvénient notable est la lenteur d'ouverture de ces rapports.
Est-il possible de réduire le temps d’ouverture du classeur en VBA en important, par exemple, l’intégralité de la feuille 1 sans ouvrir le fichier source pour un traitement personnalisé ?
Cordialement.

Est-il possible de joindre mon fichier de démonstration qui fait 12 Mo en taille ?

 

[wDog66]

Bonjour Iliess,

Office 365... quelle lenteur aujourd'hui 🙄 Impensable au pris de l'abonnement payé ☹️

Sinon, vous pouvez travailler avec Power Query pour récupérer des données d'un autre fichier

A+

 

[iliess]

Bonjour wdog66
merci pour votre réponse
Effectivement je travaille avec power query et le vba

 

[job75]

Bonjour iliess, wDog66,

Dans le fichier Source.xlsx nommez Tableau la plage que vous voulez récupérer.

Dans le fichier Pilote.xlsm exécutez la macro :

Sub Copier()
Dim fichier As Variant, form$, nlig&, ncol%
fichier = Application.GetOpenFilename("Fichiers Excel (*.xlsx), *.xlsx")
If fichier = False Then Exit Sub
form = "'" & fichier & "'!Tableau"
nlig = ExecuteExcel4Macro("ROWS(" & form & ")")
ncol = ExecuteExcel4Macro("COLUMNS(" & form & ")")
Application.ScreenUpdating = False
Cells.Delete 'RAZ
With [A1].Resize(nlig, ncol)
    .FormulaArray = "=" & form 'formule matricielle
    .Value = .Value 'supprime la formule
    .Replace 0, "", xlWhole 'efface les valeurs zéro
End With
End Sub

Le fichier Source est copié sans qu'on l'ouvre.

A+

 

[job75]

J'ai testé avec un tableau de 10 colonnes et 10 000 lignes (fichier de 1,8 Mo).

La durée d'exécution après fermeture de la boîte de dialogue est de 0,6 seconde chez moi.

 

[Cousinhub]

Bonjour,
@job75 , ne pas oublier d'annoncer au demandeur (sous 365), qu'il faut valider l'autorisation des macros xl4
Bonne fin d'apm

 

[job75]

En effet, merci Cousinhub.

 

[iliess]

Bonsoir
M @job75 , Merci pour votre solution. Mais le problème, c'est que mon fichier source est très lent à l'ouverture pour nommer la plage Tableau.

 

[iliess]

Bonsoir
M @job75 , M @Cousinhub
Est-ce que je peux modifier la ligne suivante ?

form = "'" & fichier & "'!Tableau"

Par

form = "'" & fichier & "Range("A1").CurrentRegion"

 

[job75]

Bonjour ilies, le forum,

Non car pour obtenir CurrentRegion il faut que le fichier Source soit ouvert.

Prenez votre mal en patience et ouvrez-le pour créer le nom Tableau.

A+

 

[job75]

Si vous ne voulez pas créer le nom Tableau il faut un minimum d'informations :

- le nom de la feuille à copier => "Feuil1"

- le numéro de la ligne des en-têtes => 1

- la nature des valeurs en colonne A ou B (textes ou nombres).

La nouvelle macro :

Sub Copier()
Dim fichier As Variant, chemin$, feuille$, form$, nlig&, ncol%
fichier = Application.GetOpenFilename("Fichiers Excel (*.xlsx), *.xlsx")
If fichier = False Then Exit Sub
chemin = Left(fichier, InStrRev(fichier, "\"))
fichier = Mid(fichier, InStrRev(fichier, "\") + 1)
feuille = "Feuil1" 'nom de la feuille à copier
form = "'" & chemin & "[" & fichier & "]" & feuille & "'!"
'nlig = ExecuteExcel4Macro("MATCH(""zzz""," & form & "C1)") 'textes en colonne A
nlig = ExecuteExcel4Macro("MATCH(9^9," & form & "C2)") 'ou nombres en colonne B
ncol = ExecuteExcel4Macro("MATCH(""zzz""," & form & "R1)") 'ligne des en-têtes
Application.ScreenUpdating = False
Cells.Delete 'RAZ
With [A1].Resize(nlig, ncol)
    .FormulaArray = "=" & form & "R1C1:R" & nlig & "C" & ncol 'formule matricielle
    .Value = .Value 'supprime la formule
    .Replace 0, "", xlWhole 'efface les valeurs zéro
End With
End Sub

 

[iliess]

bonsoir
Mr @job75
Est-ce que je peux partager avec vous mon fichier réel pour faire un test ?

 

[job75]

Bizarre, vous n'êtes pas en mesure de tester vous-même votre fichier ?

Et d'abord combien de temps vous faut-il pour l'ouvrir ?

 

[job75]

J'ai testé ma dernière macro sur un fichier de 12,5 Mo (tableau de 17 colonnes x 80 000 lignes).

Elle s'exécute en 5,7 secondes après fermeture de la boîte de dialogue.

 

[Laurent78]

Bonsoir à Tous,
Petite remarque/complément : la taille des fichiers Excel, depuis Excel 2007, ne veut pas dire grand chose dans la mesure où les données sont compressées (format zip).
Ce qui serait intéressant serait de connaitre la taille du fichier "à plat". Par ailleurs, je ne sais pas si c'est le cas ici, mais certains logiciels exportent au format Excel, mais en fait, il s'agit d'un format texte dont l'extension est xls.
Il pourrait même peut-être être plus performant en exportant du logiciel les données comptable en format texte (csv, etc ...) et faire un test de performance.
Le top serait de fournir ici un fichier anonymisé.
Cdlt