moyenne en relation

[Berg1664]

Bonsoir,

Voici le petit problème sur lequel je bute

J'ai une colonne "Age"(A) et une colonne "euros "(B), j'aimerais trouver une fonction qui me donnerait dans la colonne (C) la moyenne en euros des personnes de même age, mais sans passer par les tableaux croisés dynamique qui je sais ,peuvent donner cette info

Merci pour votre aide,voir fichier joint

Salut à tous

 

[Jocelyn]

Re : moyenne en relation

Bonjour le Forum,
Bonjour Berg1664,

Un essai en pièce jointe

Jocelyn

Edit je mets un autre fichier qui fait la moyenne suivant le choix du filtre avec la fonction sous.total comme ca 2 solutions possible

 

[ROGER2327]

Re : moyenne en relation

Bonsoir Berg1664, Jocelyn

Je n'ai pas mieux à proposer, si ce ne sont des variantes (toutes matricielles).
Trois versions de la formule de Jocelyn :

[COLOR="DarkSlateGray"]=SI(NB.SI(A$2:A2;A2)=1;MOYENNE(SI(A$2:A$224=A2;B$2:B$224));"")
=SI(NB.SI(A$2:A2;A2)-1;"";MOYENNE(SI(A$2:A$224=A2;B$2:B$224)))
=SI(NB.SI(A$1:A1;A2);"";MOYENNE(SI(A$2:A$224=A2;B$2:B$224)))[/COLOR]

Quelques autres formules :

[COLOR="DarkSlateGray"]=SI(EQUIV(A2;A:A;0)<LIGNE();"";MOYENNE(SI(A$2:A$224=A2;B$2:B$224)))
=SI(EQUIV(A2;A:A;0)=LIGNE();MOYENNE(SI(A$2:A$224=A2;B$2:B$224));"")
=SI(EQUIV(A2;A:A;0)-LIGNE();"";MOYENNE(SI(A$2:A$224=A2;B$2:B$224)))
=SI(ESTNA(EQUIV(A2;A$1:A1;0));MOYENNE(SI(A$2:A$224=A2;B$2:B$224));"")[/COLOR]

Et aussi (moins élaboré) :

[COLOR="DarkSlateGray"]=MOYENNE(SI(A$2:A$224=A2;B$2:B$224))
=SOMME((A$2:A$224=A2)*B$2:B$224)/NB.SI(A$2:A$224;A2)
=SOMME((A$2:A$224=A2)*B$2:B$224)/SOMME((A$2:A$224=A2)*1)[/COLOR]

Bonne nuit !
ROGER2327

 

[Berg1664]

Re : moyenne en relation

Merci Jocelyn et Roger2327 pour ces riches réponses qui me seront précieuses
A Bientôt
Berg1664