Moyenne de CA en fonction du jour et du mois

[alolaterre]

Bonjour,
J'aimerais faire un fichier dans lequel je rentre la date et en face le chiffre d'affaires quotidien?

J'aimerais récapituler dans un tableau
avec en abscisse: lundi; mardi; mercredi; ...; dimanche
et en ordonnée : les mois

Est il possible de calculer la moyenne des lundi du mois d'avril par exemple.

Je vous joint mon tableau ce sera peut être plus parlant .....

Document Cjoint


Par avance merci

 

[chris]

Re : Moyenne de CA en fonction du jour et du mois

Bonjour

Avec une colonne supplémentaire et un TCD.

Edit : remplacé somme par moyenne... Boujour à tous🙂

 

[excfl]

Re : Moyenne de CA en fonction du jour et du mois

Bonjour alolaterre, chris

Une proposition : E3 :

=SOMMEPROD((MOIS($A$2:$A$1000)=MOIS($D3))*((JOURSEM($A$2:$A$1000)=JOURSEM(E$2))*($B$2:$B$1000)))

A tirer vers la droite, puis vers le bas.

 

[Paf]

Re : Moyenne de CA en fonction du jour et du mois

Bonjour à tous,

Dans le même esprit que la formule de excfl:
=SOMMEPROD((JOURSEM($A$2:$A$274)=JOURSEM(E$2))*(MOIS($A$2:$A$274)=MOIS($D3))*($B$2:$B$274))/SOMMEPROD((JOURSEM($A$2:$A$274)=JOURSEM(E$2))*(MOIS($A$2:$A$274)=MOIS($D3)))

pour obtenir la moyenne.

Par ailleurs, j'ai été obligé de mettre des dates en D3😀11 (avec affichage du mois) pour que ça fonctionne

Bonne journée

 

[JCGL]

Re : Moyenne de CA en fonction du jour et du mois

Bonjour à tous,

Un essai sur les moyennes par jour avec choix de l'année :

=SIERREUR(SOMMEPROD((JOURSEM($A$2:$A$5000;2)=COLONNES($A:A))*(ANNEE($A$2:$A$5000)=$D$2)*(MOIS($A$2:$A$5000)=MOIS(1&$D3))*$B$2:$B$5000)/SOMMEPROD((JOURSEM($A$2:$A$5000;2)=COLONNES($A:A))*(ANNEE($A$2:$A$5000)=$D$2)*(MOIS($A$2:$A$5000)=MOIS(1&$D3)));"**")

Bise à Chris
A+ à tous

 

[excfl]

Re : Moyenne de CA en fonction du jour et du mois

Lecture trop rapide du sujet en effet : "moyenne des lundi du mois d'avril par exemple" et non pas somme.

Donc :

=SIERREUR(SOMMEPROD((MOIS($A$2:$A$1000)=MOIS($D3))*((JOURSEM($A$2:$A$1000)=JOURSEM(E$2))*($B$2:$B$1000)))/SOMMEPROD((MOIS($A$2:$A$1000)=MOIS($D3))*((JOURSEM($A$2:$A$1000)=JOURSEM(E$2))));"")

 

[alolaterre]

Re : Moyenne de CA en fonction du jour et du mois

Merci beaucoup
C'est parfait