Liste déroulante et ComboBox

[Cydor007]

Bonjour à tous,

J'essaie de rendre une droplist dans un ComboBox utilisable à partir d'une liste dans ma feuille TEST. J'ai essayé de plusieurs façon, mais sans succes, de faire défiler la liste. J'obtiens toujours un erreur de compilation.

Le but est de pouvoir faciliter l'affichage d'une pièce quand je veux la sélectionner à partir d'une BD de plus de 3000 pièces.

Si vous avec une autre idée d'afficher rapidement un item provenant d'une liste (autre qu'une validation des données), je suis tout oui.

Je vous laisse un exemple comme test.

Merci de votre aide🙂

Cydor007

 

[BOISGONTIER]

Re : Liste déroulante et ComboBox

Bonsoir,

Option Compare Text
Private Sub ComboBox1_Change()
  [A1] = ComboBox1
End Sub

Private Sub ComboBox1_DropButtonClick()
  Dim temp()
  Set F = Sheets("TEST")
  Set MonDico = CreateObject("Scripting.Dictionary")
  For Each c In F.Range("L3:L" & F.[L65000].End(xlUp).Row)
    If c.Value <> "" Then MonDico.Item(c.Value) = ""
  Next c
  temp = MonDico.keys
  Call tri(temp, LBound(temp), UBound(temp))
  Me.ComboBox1.List = temp
End Sub

Sub tri(a, gauc, droi)          ' Quick sort
 ref = a((gauc + droi) \ 2)
 g = gauc: d = droi
 Do
     Do While a(g) < ref: g = g + 1: Loop
     Do While ref < a(d): d = d - 1: Loop
     If g <= d Then
       temp = a(g): a(g) = a(d): a(d) = temp
       g = g + 1: d = d - 1
     End If
 Loop While g <= d
 If g < droi Then Call tri(a, g, droi)
 If gauc < d Then Call tri(a, gauc, d)
End Sub

JB

 

[Cydor007]

Re : Liste déroulante et ComboBox

Merci à toi JB, j'avais oublié la partie tri.

Bonne journée