liaison excel - powerpoint

[FredC]

Bonjour à tous,

J'ai un fichier powerpoint assez conséquent à trier et je dois créer un fichier excel renvoyant des infos de ce ppt: le titre des slides (ou un bref descriptif) et leur numéro de page. Le souci c'est que le ppt est "vivant" et peut être modifié par différents utilisateurs: les liaisons doivent donc être mises à jour régulièrement.

J'ai pensé à des liens hypertexte, mais je ne suis pas sûr de leur robustesse (slide avec titres similaires, changement de l'ordre des slides...).

J'ai aussi pensé à créer une macro permettant d'extraire le numéro de page de chaque diapo et quelques autres infos (comme le titre) et de les renvoyer dans un classeur xls. Mais il semble que VBA pour xls ne soit pas directement lié à VBA pour ppt. J'ai d'ailleurs recontré des difficultés en voulant enregistrer une macro...

Quelqu'un aurait-il une (des?) piste(s) pour moi?
Merci d'avance,

FredC

 

[James007]

Re : liaison excel - powerpoint

Bonjour,

Avant tout, il faut savoir que les VBA Excel et Powerpoint savent très bien se parler ...et que les liens de communication entre ces deux applications sont relativement aisés ...

En matière de sources d'infos disponibles, MichelXLD a posté récemment un lien qui t'aidera certainement à avancer ...

FAQ MS-Excel - Club d'entraide des développeurs francophones

A+

 

[FredC]

Re : liaison excel - powerpoint

Bonjour,

Merci pour le lien, ça aide pas mal pour la syntaxe au moins.
Par contre ça dit comment piloter powerpoint à partir d'excel, mais est-il possible par exemple de créer/modifier un fichier excel à partir d'un ppt?

Merci...

 

[Caillou]

Re : liaison excel - powerpoint

Bonjour,

Essayes ce code qui tu places dans un module du fichier PowerPoint.
Il faut aussi référence la bilbio Excel dans le fichier PowerPoint (dans VB : Outils/Références/Microsoft Excel x) selon ta version

Sub Extract_Excel()
  Dim appXL As Excel.Application
  Dim claXL As Excel.Workbook
  Dim presPPT As PowerPoint.Presentation
  Dim Diapo As PowerPoint.Slide
  Dim i As Integer
  
  'presPPT représente la présentation active
  Set presPPT = ActivePresentation
  'Créer une nouvelle instance de l'application Excel
  Set appXL = New Excel.Application
  'Créer un nouveau classeur dans cette instance
  Set claXL = appXL.Workbooks.Add
  'Commencer en ligne 2 dans Excel
  i = 2
  
  'Boucle sur les diapositives de la présentation
  For Each Diapo In presPPT.Slides
    With appXL
      'Ecrire le titre en colonne A
      .Cells(i, 1) = Diapo.Shapes.Title.TextFrame.TextRange.Text
      'Ecrire l'index en colonne B
      .Cells(i, 2) = Diapo.SlideIndex
      'Ligne suivante dans Excel
      i = i + 1
    End With
  Next

  'Afficher le classeur Excel
  appXL.Visible = True
  
End Sub

Caillou

 

[FredC]

Re : liaison excel - powerpoint

Great!
Merci Caillou pour le code 😉

Par contre est ce qu'il est possible de sélectionner le texte provenant d'une autre zone de texte que le titre?
J'ai essayé quelque chose du genre:

  For Each Diapo In presPPT.Slides
    With appXL
      'Ecrire le titre en colonne A
      .Cells(i, 1) = Diapo.Shapes(#).TextFrame.TextRange.Text
      'Ligne suivante dans Excel
      i = i + 1
    End With
  Next

en changeant "#" par 1, 2,3... mais cela ne fonctionnait que pour "1", qui est la zone du titre.
Si ce n'est pas possible, tant pis, mais si quelqu'un a une idée, merci d'avance.

 

[Caillou]

Re : liaison excel - powerpoint

re,

Essayes ceci:

Sub Extract_Excel()
On Error Resume Next
  Dim appXL As Excel.Application
  Dim claXL As Excel.Workbook
  Dim presPPT As PowerPoint.Presentation
  Dim Diapo As PowerPoint.Slide
  Dim Forme As PowerPoint.Shape
  Dim i As Integer 'ligne
  Dim j As Integer 'colonne
  
  'presPPT représente la présentation active
  Set presPPT = ActivePresentation
  'Créer une nouvelle instance de l'application Excel
  Set appXL = New Excel.Application
  'Créer un nouveau classeur dans cette instance
  Set claXL = appXL.Workbooks.Add
  'Commencer en ligne 2 dans Excel
  i = 2
  
  'Boucle sur les diapositives de la présentation
  For Each Diapo In presPPT.Slides
    'Commencer en colonne 3 pour les zones de texte
    j = 3
    With appXL
      'Ecrire le titre en colonne A
      .Cells(i, 1) = Diapo.Shapes.Title.TextFrame.TextRange.Text
      'Ecrire l'index en colonne B
      .Cells(i, 2) = Diapo.SlideIndex
      For Each Forme In Diapo.Shapes
'        If Forme.Type = msoTextBox Then
        .Cells(i, j) = Left(Forme.TextFrame.TextRange.Text, 255)
        j = j + 1
'        End If
      Next
      'Ligne suivante dans Excel
      i = i + 1
    End With
  Next

  'Afficher le classeur Excel
  appXL.Visible = True
  
End Sub

Caillou

 

[FredC]

Re : liaison excel - powerpoint

Ok merci, ça marche plutot bien!
Bonne journée