XL 2013 jour de la semaine

Dugenou

XLDnaute Barbatruc

• 29 Février 2016

• #2

Re : jour de la semaine

Bonjour,
On peut commencer avec (si ta date en A1) : =MAJUSCULE(GAUCHE(TEXTE(A1;"jjj");1))
et pour avoir les deux lettres pour les mercredis : =NOMPROPRE(GAUCHE(TEXTE(A1;"jjj");SI(JOURSEM(A1;1)=4;2;1)))

Cordialement

 

Vote positif 0 Vote négatif

C

Caillou

XLDnaute Impliqué

• 29 Février 2016

• #3

Re : jour de la semaine

Bonjour,

si date en A1 :

Code:

=CHOISIR(JOURSEM(A1;2);"L";"M";"Me";"J";"V";"S";"D")

Caillou

 

Vote positif 0 Vote négatif

Dugenou

XLDnaute Barbatruc

• 29 Février 2016

• #4

Re : jour de la semaine

Bravo Caillou ! c'est tellement plus simple! : j'ai honte !

 

Vote positif 0 Vote négatif

Modeste geedee

XLDnaute Barbatruc

• 29 Février 2016

• #5

Re : jour de la semaine

Bonsour®
plus court !!!
=CHOISIR(JOURSEM(A1);"D";"L";"M";"Me";"J";"V";"S")


autres propositions :
=STXT("D L M MeJ V S ";2*JOURSEM(A1)-1;2)
ou bien :
=MAJUSCULE(GAUCHE(TEXTE(A1;"jjj")))&REPT("e"; JOURSEM(A1)=4)
ou encore :
=INDEX({"D";"L";"M";"Me";"J";"V";"S"};JOURSEM(A1))
et puis
=STXT("DLMMJVS";JOURSEM(A1);1)&REPT("e";JOURSEM(A1)=4)
=STXT("DLMMJVS";JOURSEM(A1);1)&SI(JOURSEM(A1)=4;"e";"")
=GAUCHE(NOMPROPRE(TEXTE(A1;"jjj"));1+(JOURSEM(A1)=4))

en nommant la Matrice
NJ fait référence à :
={"D";"L";"M";"Me";"J";"V";"S"}
=INDEX(NJ;JOURSEM(A1))

 

Dernière édition: 29 Février 2016

Vote positif 0 Vote négatif

ROGER2327

XLDnaute Barbatruc

• 29 Février 2016

• #6

Re : jour de la semaine

moins deux caractères :
=STXT("S D L M MeJ V ";2*MOD(A1;7)+1;2)

 

Vote positif 0 Vote négatif

P

patrick7676

XLDnaute Occasionnel

• 29 Février 2016

• #7

Re : jour de la semaine

je n'arrive à résoudre ce problème
je vous joint un fichier

 

Pièces jointes

• JOUR DE LA SEMAINE.xlsx

  11.1 KB · Affichages: 48
• JOUR DE LA SEMAINE.xlsx

  11.1 KB · Affichages: 53

Vote positif 0 Vote négatif

ROGER2327

XLDnaute Barbatruc

• 29 Février 2016

• #8

Re : jour de la semaine

Re...

Voyez si la pièce jointe vous convient...​

Bonne soirée.


ℝOGER2327
#8216

Vendredi 6 Pédale 143 (Vers Belges - fête Suprême Quarte)
10 Ventôse An CCXXIV, 7,6450h - bêche
2016-W09-1T18:20:52Z

 

Pièces jointes

• Copie de JOUR DE LA SEMAINE.xlsx

  13.7 KB · Affichages: 52

Vote positif 0 Vote négatif

Jocelyn

XLDnaute Barbatruc

• 29 Février 2016

• #9

Re : jour de la semaine

Bonjour le Forum,
Bonjour patrick7676, Dugenou, Caillou, Modeste geedee, Roger2327,

en partant de la formule de Roger2327 tu peux mettre en C5 cette formule

Code:

=STXT("S D L M MeJ V ";2*MOD(DATE($A$5;MOIS($C$4&1);C6);7)+1;2)

et l'étirer vers la droite

Cordialement

EDIT : Désolé Roger je n'avais pas vu que tu étais connecté

 

Dernière édition: 29 Février 2016

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 29 Février 2016

• #10

Re : jour de la semaine

Bonjour à tous,

En C5 à tirer sur D5:AG5 :

Code:

=SIERREUR(NOMPROPRE(GAUCHE(TEXTE(DATEVAL(C6&$C4&$A5);"jjj");1+(JOURSEM(C6&$C4&$A5)=4)));"")

Bonne soirée.

Edit : pas terrible pour mon 20000ème post, je n'avais pas regardé les solutions précédentes...

 

Dernière édition: 29 Février 2016

Vote positif 0 Vote négatif

P

patrick7676

XLDnaute Occasionnel

• 29 Février 2016

• #11

Re : jour de la semaine

bonjour
quelle différence avec celle de Roger 2327

 

Vote positif 0 Vote négatif

Modeste geedee

XLDnaute Barbatruc

• 29 Février 2016

• #12

Re : jour de la semaine

Bonsour®

en nommant la Matrice
NJ fait référence à :
={"D";"L";"M";"Me";"J";"V";"S"}
=INDEX(NJ;JOURSEM(A1))

Cliquez pour agrandir...

 

Pièces jointes

• Capture.jpg

  49.1 KB · Affichages: 39
• JOUR DE LA SEMAINE.xlsx

  31.4 KB · Affichages: 34
• JOUR DE LA SEMAINE.xlsx

  31.4 KB · Affichages: 39

Vote positif 0 Vote négatif

P

patrick7676

XLDnaute Occasionnel

• 1 Mars 2016

• #13

Re : jour de la semaine

je remercie tous pour l'aide apportée
merci

 

Vote positif 0 Vote négatif