INDEX EQUIV avec doublons

[banane59]

Bonjour à tous,

J'ai longuement cherché la solution à mon problème sur les forums mais sans succès. Je n'arrive pas à appliquer les formules données à mon cas, j'espère que vous pourrez m'aider.
Voici mon problème: je récupère les 5 plus petits MTTR (voir fichier joint) puis je cherche à récupérer les noms des machines associées à ces MTTR. Le soucis est que chaque mois, certains MTTR sont égaux alors excel me renvoie 2 fois les mêmes machines. La pièce jointe est une petite partie du fichier réel, les formules doivent conserver la condition K2:K350=VRAI. Avez-vous une solution ?

Merci beaucoup d'avance de votre aide.

 

[danielco]

Bonjour,

En A21 :

=INDEX($A$1:$A$16;AGREGAT(15;6;(1/($G$2:$G$16=C21))*LIGNE($G$2:$G$16);NB.SI($C$21:C21;C21)))

A recopier vers le bas.

Cordialement.

Daniel

 

[banane59]

Bonjour Daniel,

Merci beaucoup, la formule fonctionne très bien pour éviter les doublons !
Juste une petite question, pourquoi mettre $A$1 et non $A$2 dans la matrice de la fonction INDEX ? En ajoutant la condition *($K$2:$K$350=VRAI) dans la matrice de la fonction AGREGAT (formule matricielle), la formule me renvoie parfois "Equipement" et en changeant pour $A$2 les valeurs se décalent parfois, pouvez-vous m'éclairer s'il vous plait ?

 

[danielco]

AGREGAT(15;6;(1/($G$2:$G$16=C21))*LIGNE($G$2:$G$16);NB.SI($C$21:C21;C21) renvoie le numéro de ligne, par exemple 8 en A23. La plage utilisée par INDEX doit donc commencer en A1. En ce qui concerne la condition ($K$2:$K$350=VRAI) , utilise :

=INDEX($A$1:$A$16;AGREGAT(15;6;(1/(($G$2:$G$16=C21)*($K$2:$K$16=VRAI)))*LIGNE($G$2:$G$16);NB.SI($C$21:C21;C21)))

en A21.

Daniel

 

[banane59]

Ça fonctionne parfaitement ! Merci beaucoup !

 

[R@chid]

Bonjour @ tous,
une matricielle en A21 :

=SIERREUR(INDEX(A$2:A$16;PETITE.VALEUR(SI(G$2:G$16=C21;LIGNE(INDIRECT("1:"&LIGNES(G$2:G$16))));NB.SI(C$21:C21;C21)));"")

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas


Cordialement