Autres Formule Cellule avec chiffre et texte

[ultra_v]

bonjour ,

la colonne "A" contient des milliers de données ( numerique , text , numerique & text )
j'en ai pas réussi avec les filtres classiques je voudrais svp une formule :
si la Cellule contient que du texte " aaa aaa a aaa" = renvoie la valeur "text "
si la Cellule contient que du texte & numerique genre " aaa 1589 " = renvoie la valeur "alphanumerique "
si la Cellule contient que du chiffre = renvoie la valeur "numerique "
merci

Excel 2007

 

[Jacky67]

bonjour ,

la colonne "A" contient des milliers de données ( numerique , text , numerique & text )
j'en ai pas réussi avec les filtres classiques je voudrais svp une formule :
si la Cellule contient que du texte " aaa aaa a aaa" = renvoie la valeur "text "
si la Cellule contient que du texte & numerique genre " aaa 1589 " = renvoie la valeur "alphanumerique "
si la Cellule contient que du chiffre = renvoie la valeur "numerique "
merci

Excel 2007

Bonjour
A tester

=SI(ESTNUM(A1);"Numérique";SI(NBCAR(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(A1;0;"");1;"");2;"");3;"");4;"");5;"");6;"");7;"");8;"");9;""))=NBCAR(A1);"Texte";"Alphanumérique"))

 

[job75]

Bonjour ultra_v, Jacky67,

Une autre solution dans ce fichier avec en B2 :

=SI(A2="";"";SI(SOMMEPROD(-ESTNUM(-STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)));SI(ESTNUM(-A2);"numérique";"alphanumérique");"alpha"))

A+

 

[Jacky67]

Bonjour ultra_v, Jacky67,

Une autre solution dans ce fichier avec en B2 :

=SI(A2="";"";SI(SOMMEPROD(-ESTNUM(-STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)))=0;"alpha";SI(SOMMEPROD(--ESTNUM(-STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)))<NBCAR(A2);"alphanumérique";"numérique")))

A+

Hello job75
Certainement que
alpha=texte
Des difficultés avec des nombres avec décimale..

**Ouppss!!, Pas vu que c'était modifié

 

[job75]

J'ai modifié ma formule du post #3.

 

[ultra_v]

merci à vous tous
ça marche parfait
une petite modif svp jacky les cellules vides ça me renvoit text

 

[Jacky67]

merci à vous tous
ça marche parfait
une petite modif svp jacky les cellules vides ça me renvoit text

Re..
Ben ça alors...

=SI(A1="";"";SI(ESTNUM(A1);"Numérique";SI(NBCAR(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(A1;0;"");1;"");2;"");3;"");4;"");5;"");6;"");7;"");8;"");9;""))=NBCAR(A1);"Texte";"Alphanumérique")))

 

[patricktoulon]

Bonjour à tous
j'ai peut être un moyen de réduire les kilomètres de substitue
fair un equiv 0 matriciel sur une matrice grâce à stxt indirect ligne
grace à cela tout les caractères de la chaine sont passés en revue
et le principe va me donner la première position d'un chiffre dans la chaine le tout dans un si(esterreur ....)bien sur
le tout dans un si esnum( valeur ;"numerique" ; si(estnum(matriciel de recherche ; "alphanumérique" ; "alpha")
la formule ca donnerait ceci

=SI(ESTNUM(A2);"numérique";SI(ESTNUM(EQUIV(0;ESTERREUR(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)*1)*1;0));"Alphanumérique";"Alpha"))

le résultat me parait cohérent

sinon il y a secence pour 365 mais celle ci valider en matriciel sur <365 fonctionne
donc compatible 2007 à 365

 

[patricktoulon]

re
allez en réfléchissant un peu plus je fait avec une matrice codée en dur
la formule est encore plus courte
c'est un peu pareil sauf que la le cherche matriciel me renvoie 0 si pas de chiffre
doncdans la 2d condition si numerique , alors alpha numerique sinon numerique

=SI(ESTNUM(A2);"Numerique";SI(MIN(SIERREUR(CHERCHE({0;1;2;3;4;5;6;7;8;9};A2);""))>0;"Alphanumerique";"Alpha"))

là aussi compatible 2007 à 365 (valider en matriciel en dessouis de 365 )
je joins un fichier avec les deux exemples

 

[Jacky67]

re
allez en réfléchissant un peu plus je fait avec une matrice codée en dur
la formule est encore plus courte
c'est un peu pareil sauf que la le cherche matriciel me renvoie 0 si pas de chiffre
doncdans la 2d condition si numerique , alors alpha numerique sinon numerique

=SI(ESTNUM(A2);"Numerique";SI(MIN(SIERREUR(CHERCHE({0;1;2;3;4;5;6;7;8;9};A2);""))>0;"Alphanumerique";"Alpha"))

là aussi compatible 2007 à 365 (valider en matriciel en dessouis de 365 )
je joins un fichier avec les deux exemples

Hello Patrick,
J'avais cherché dans cette direction, sans succès, certainement dû à mon manque de patience.
Bravo
Le seul avantage des rallonges de 'SUBSTITUE' c'est quelle n'a pas de validation matricielle.

 

[patricktoulon]

bonsoir @Jacky67
ben je cherche et j'apprends en même temps c'est pourtant pas mon truc les formules
je suis plutôt VB c'est l'association des fonctions dans la formule qui plus difficile pour moi

 

[job75]

Bonsoir Patrick,

Il faudrait ajouter un test dans ta formule pour le cas où A2 est vide.

A+

 

[patricktoulon]

Bonsoir @job75
oui en effet

 

[patricktoulon]

re
@Jacky67 , @job75
tiens pour le coup je soulève une autre question
version 1 (2 formules valables)

a

=SI(A2<>"";SI(ESTNUM(A2);"numérique";   SI(ESTNUM(EQUIV(0;ESTERREUR(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)*1)*1;0));   "Alphanumérique"; "Alpha"));"")

b

=SI(ESTNUM(A2);"numérique";   SI(ESTNUM(EQUIV(0;ESTERREUR(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)*1)*1;0));   "Alphanumérique"; SI(A2<>"";"Alpha";"")))

version 2 (2 formules valables)

a

=SI(A2<>"";SI(ESTNUM(A2);"Numerique";SI(MIN(SIERREUR(CHERCHE({0;1;2;3;4;5;6;7;8;9};A2);""))>0;"Alphanumerique";"Alpha"));"")

b

=SI(ESTNUM(A2);"Numerique";SI(MIN(SIERREUR(CHERCHE({0;1;2;3;4;5;6;7;8;9};A2);""))>0;"Alphanumerique";si(A2<>"";"Alpha";"")))

la question;
quelle est l'incidence (en terme de ressource) de faire le test A2<>"" en global ou dans le matriciel?

 

[job75]

Quand tu te poses des questions de ce genre rends les formules volatiles avec ALEA().

Et exécute en VBA 10 000 ou 100 000 boucles sur Calculate pour mesurer la durée d'exécution.