XL 2016 Équivalent à Filtre sous Excel 2016 ?

riton00

XLDnaute Impliqué

• 1 Mars 2023

• #2

Bonsoir,

Une proposition

Slts

 

Pièces jointes

• test-filtre.xlsx

  15.3 KB · Affichages: 29

Vote positif 1 Vote négatif

mapomme

XLDnaute Barbatruc

Supporter XLD

• 1 Mars 2023

• #3

Bonsoir @telemarrk , @riton00 ,

Une autre formule matricielle en L3 puis :

• recopier L3 sur la droite jusqu'à Q3
• formater les cellules de cette plage L3:Q3
• recopier la plage L3:Q3 vers le bas jusqu'à obtenir des cellules vides

La formule matricielle en L3 :
=SIERREUR(INDEX(C:C;PETITE.VALEUR(SI($C$3:$C$999=$L$1;LIGNE($C$3:$C$999);"");LIGNES($1:1)));"")

nota : il faut recopier la plage L3:Q3 suffisamment vers le bas pour pouvoir afficher toutes les lignes filtrées mais aussi en prévision de l'augmentation de taille du tableau source. C'est pour cela que les cellules avec les formules ont une ligne pointillée en bordure basse pour visualiser les cellules avec formules.

rem : si besoin, augmentez la valeur 999 dans la formule.

 

Pièces jointes

• telemarrk- test-filtre- v1.xlsx

  13.2 KB · Affichages: 22

Vote positif 1 Vote négatif

job75

XLDnaute Barbatruc

• 1 Mars 2023

• #4

Bonsoir telemarrk, riton00, mapomme,

Voyez le fichier joint et cette fonction VBA :

VB:

Function FiltreVBA(plage As Range, critere(), defaut)
Dim ub1&, ub2%, resu(), i&, n&, j%
ub1 = Application.Caller.Rows.Count
ub2 = Application.Caller.Columns.Count
ReDim resu(1 To ub1, 1 To ub2)
For i = 1 To plage.Rows.Count
    If critere(i, 1) Then
        If n = ub1 Then Exit For
        n = n + 1
        For j = 1 To ub2
            resu(n, j) = plage(i, j)
        Next j
    End If
Next i
For i = n + 1 To ub1
    For j = 1 To ub2
        resu(i, j) = defaut
Next j, i
FiltreVBA = resu 'matrice
End Function

Le code doit être placé impérativement dans un module standard.

Dans la feuille de calcul la fonction est entrée matriciellement en bloc sur la plage L19:Q22.

Les arguments sont les mêmes que ceux de la fonction FILTRE, donc il suffira de remplacer le nom "FILTRE" par "FiltreVBA".

A+

 

Pièces jointes

• FiltreVBA(1).xlsm

  21.5 KB · Affichages: 47

Vote positif 1 Vote négatif

T

telemarrk

XLDnaute Occasionnel

• 2 Mars 2023

• #5

Bonjour,

Merci à vous tous.

Riton00 : C'est parfait, c'est ce que je cherche à faire.
Mapomme : Idem et merci pour les explications
Job75 : Idem, as-tu un site pour débutant en VBA ?

Il ne me reste plus qu'a tester cela sur les PC ayant Excel 2016.

Je vous tiens au courant dans la journée.

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 2 Mars 2023

• #6

Bonjour,

telemarrk à dit:

Job75 : Idem, as-tu un site pour débutant en VBA ?

Cliquez pour agrandir...

excel-downloads

A+

 

Vote positif 0 Vote négatif

T

telemarrk

XLDnaute Occasionnel

• 2 Mars 2023

• #7

Bien vu Job75, je suis tellement habitué à regarder les messages sur le forum que j'ai oublié que le site n'est pas qu'un forum.

 

Vote positif 0 Vote négatif

T

telemarrk

XLDnaute Occasionnel

• 2 Mars 2023

• #8

Je reviens vers vous pour vous remercier de nouveau et confirmer que vos propositions fonctionnent.

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 17 Mars 2023

• #9

Bonjour le fil, le forum,

Repassant par ici j'en profite pour simplifier ma fonction FiltreVBA :

VB:

Function FiltreVBA(tableau, critere(), defaut)
Dim ub1&, ub2%, i&, n&, j%
tableau = tableau
ub1 = UBound(tableau, 1)
ub2 = UBound(tableau, 2)
For i = 1 To ub1
    If critere(i, 1) Then
        n = n + 1
        For j = 1 To ub2
            tableau(n, j) = tableau(i, j)
        Next j
    End If
Next i
For i = n + 1 To ub1
    For j = 1 To ub2
        tableau(i, j) = defaut
Next j, i
FiltreVBA = tableau 'matrice
End Function

Application.Caller et la variable resu() étaient inutiles.

A+

 

Pièces jointes

• FiltreVBA(2).xlsm

  20.6 KB · Affichages: 59

Vote positif 0 Vote négatif

T

telemarrk

XLDnaute Occasionnel

• 17 Mars 2023

• #10

Bonjour job75,

Je teste cela et je reviens vers toi

Merci encore.

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 17 Mars 2023

• #11

J'ai testé en recopiant le tableau C3:H10 sur 100 000 lignes.

Chez moi la fonction FiltreVBA se recalcule en 0,51 seconde.

C'est légèrement plus rapide que l'application du filtre automatique 0,58 s.

 

Vote positif 0 Vote négatif

T

telemarrk

XLDnaute Occasionnel

• 17 Mars 2023

• #12

Je viens de tester c'est parfait.

Je peux donc utiliser mon fichier sur Excel 2016.

Merci.

 

Vote positif 0 Vote négatif

O

obii

XLDnaute Nouveau

• 17 Mai 2023

• #13

job75 à dit:

J'ai testé en recopiant le tableau C3:H10 sur 100 000 lignes.

Chez moi la fonction FiltreVBA se recalcule en 0,51 seconde.

C'est légèrement plus rapide que l'application du filtre automatique 0,58 s.

Cliquez pour agrandir...

Bonjour pour ma part j'ai copié ta fonction vba sur un module et j'essaie de l'utiliser sur sur une cellule excel mais elle ne fonctionne pas :/
y'a quelque chose de particulier à faire ?

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 17 Mai 2023

• #14

Bonjour obii, bienvenue sur XLD,

job75 à dit:

Le code doit être placé impérativement dans un module standard.

Dans la feuille de calcul la fonction est entrée matriciellement en bloc sur la plage L19:Q22.

Cliquez pour agrandir...

La fonction est entrée dans une plage.

La validation matricielle se fait par les 3 touches Ctrl+Maj+Entrée.

A+

 

Vote positif 0 Vote négatif

O

obii

XLDnaute Nouveau

• 17 Mai 2023

• #15

job75 à dit:

Bonjour obii, bienvenue sur XLD,

La fonction est entrée dans une plage.

La validation matricielle se fait par les 3 touches Ctrl+Maj+Entrée.

A+

Cliquez pour agrandir...

Merci,

C'est bien ce que je fais mais j'au un #VALEUR! qui s'affiche pour je ne sais quelle raison, peux tu me montrer un exemple de comment la formule s'utilise ?

 

Vote positif 0 Vote négatif