enregistrement ds des colonnes différentes

[bpol]

bonjour le forum,

le but que je recherche est d'enregistrer des données ds des colonnes différentes suivnt une cellule avec liste déroulante
je vous joins un exemple.

Merci d'avance
bpol

 

[Compte Supprimé 979]

Re : enregistrement ds des colonnes différentes

Salut bpol,

Je pense que la solution passe par ce bon vieux VBA 😉
Qu'elle est la donnée qui est saisie en dernière, c'est le 'Temp' !?

A+

 

[bpol]

Re : enregistrement ds des colonnes différentes

bonjour BrunoM145,
je sélectionne d'abord la cellule A13 puis le N° de voiture et ensuite le temps


Merci
Bpol

 

[Compte Supprimé 979]

Re : enregistrement ds des colonnes différentes

Salut Bpol,

Tu trouveras ci-dessous ton fichier modifié avec :
1) du code VBA dans Feuil1
2) un module 'fonctions'

A+

 

[bpol]

Re : enregistrement ds des colonnes différentes

mille excuse BrunoM45,
j'ai besoin d'explication
ds le fichier que tu m'envois je ne trouve pas le code VBA ni de macro

A+

Bpol

 

[Compte Supprimé 979]

Re : enregistrement ds des colonnes différentes

Re, bpol

Désolé 😱 , le code se trouve dans Feuil1

Private Sub Worksheet_Change(ByVal Target As Range)
  ' Vérifie si la modification est faite dans la cellule D13
  If Target.Address <> "$D$13" Then Exit Sub
  '
  Dim ColF As Integer, DerLig As Integer, VSearch As String
  VSearch = ActiveSheet.Range("A13").Value
  ' Recherche de la valeur de la liste déroulante
  ColF = ColFind("Feuil2", 1, VSearch)
  ' Si la valeur à été trouvée
  If ColF <> 0 Then
    DerLig = Sheets("Feuil2").Cells(65536, ColF).End(xlUp).Row + 1
    ' Inscrit le numéro de voiture
    Sheets("Feuil2").Cells(DerLig, ColF).Value = ActiveSheet.Range("C13")
    ' Inscrit le temps
    Sheets("Feuil2").Cells(DerLig, ColF + 1).Value = ActiveSheet.Range("D13")
    ' Message d'information
    MsgBox "Valeurs enregistrées", vbInformation, "TOUT EST OK ...."
  Else
    MsgBox "Impossible de trouver : " & VSearch & " sur la ligne 1 de 'Feuil2"
  End If
End Sub

J'utilise également une fonction, qui se trouve dans module 'Fonctions"

Function ColFind(Feuil As String, NumLig As Integer, Quoi)
  On Error Resume Next
  With Sheets(Feuil).Rows(NumLig)
    ColFind = .Find(What:=Quoi, LookIn:=xlValues, LookAt:=xlWhole, SearchDirection:=xlNext, _
      SearchOrder:=xlByColumns, MatchCase:=False).Column
  End With
  On Error GoTo 0
End Function

Voilà 😉

 

[bpol]

Re : enregistrement ds des colonnes différentes

merci brunoM45,
j'ai toujours la tête en vacances mais:

une dernièrevquestion comment activé le code et la fonction pour que les données se copient

A+
bpol

 

[Compte Supprimé 979]

Re : enregistrement ds des colonnes différentes

Salut Bpol,

Comme suite à ta demande, voici le code pour le faire fonctionner via un bouton 😉

Sub ValidationDonnees()
  Dim ColF As Integer, DerLig As Integer, VSearch As String
  VSearch = ActiveSheet.Range("A13").Value
  ' Recherche de la valeur de la liste déroulante
  ColF = ColFind("Feuil2", 1, VSearch)
  ' Si la valeur à été trouvée
  If ColF <> 0 Then
    DerLig = Sheets("Feuil2").Cells(65536, ColF).End(xlUp).Row + 1
    ' Inscrit le numéro de voiture
    Sheets("Feuil2").Cells(DerLig, ColF).Value = ActiveSheet.Range("C13")
    ' Inscrit le temps
    Sheets("Feuil2").Cells(DerLig, ColF + 1).Value = ActiveSheet.Range("D13")
    ' Message d'information
    MsgBox "Valeurs enregistrées", vbInformation, "TOUT EST OK ...."
  Else
    MsgBox "Impossible de trouver : " & VSearch & " sur la ligne 1 de 'Feuil2"
  End If
End Sub

A mettre dans un module, tout est dans le fichier joint.

Voilà 😉