Empecher des doublons dans un Combobox

[cpeens]

Bonjour à tous je cherche depuis quelque temps faire en sorte qu'une valeur apparaisse qu'une fois dans ma combobox même si dans ma BD elle reviens plusieur fois .
quelqu'un aurait il une idée svp merci.

 

[Guest]

Re : Empecher des doublons dans un Combobox

Bonjour,

Lien dans la faq: https://www.excel-downloads.com/threads/ref-wiki-2-de-michelxld-ce-qui-touche-aux-userform.92357/

A+

 

[cpeens]

Re : Empecher des doublons dans un Combobox

Bonjour hasco et merci pour ton aide ne maitrissant pas tous j'ai bien trouver le bout de code que tu m'à proposé soucis c'est que le mien est un peut plus complexe il recherche sur plusieur feuille et colonne.

Dim x As Long
 Dim Sht As Worksheet, Col As Integer, Lig As Long
  ' Définir la colonne de recherche
  Col = Me.ComboBox1.ListIndex + 1
  ' Pour chaque feuille
  For Each Sht In ThisWorkbook.Worksheets
    ' Si le début du nom de la feuille correspond
    If Left(Sht.Name, 3) = "SAS" Then
      ' Pour chaque ling
      For x = 2 To 4
      For Lig = 2 To 10
        ' Ajouter la valeur de la colonne sélectionnée
        Me.ComboBox2.AddItem Sht.Cells(Lig, x + Col)
       
      Next Lig

  Next x
End If
Next Sht

donc je vois pas trop comment ajouter celui ci

désolé mais la sa deviens un peu compliqué pour moi.

 

[BOISGONTIER]

Re : Empecher des doublons dans un Combobox

Bonjour,

Combobox sans doublons

Méthode rapide (0,15 sec pour 5000 éléments)

Private Sub UserForm_Initialize()
  Set f = Sheets("BD")
  Set mondico = CreateObject("Scripting.Dictionary")
  For Each c In f.Range("a2:a" & f.[a65000].End(xlUp).Row)
     mondico.Item(c.Value) = c.Value
  Next c
  Me.ComboBox1.List = mondico.items
End Sub

Méthode lente (3,5sec pour 5000 éléments)

Private Sub UserForm_Initialize()
  For i = 1 To Sheets(1).[A65000].End(xlUp).Row
      Me.ComboBox1 = Sheets(1).Cells(i, "A")        ' on se positionne dans le combobox
      If Me.ComboBox1.ListIndex = -1 Then           ' Existe t-il?
        Me.ComboBox1.AddItem Sheets(1).Cells(i, "A")
      End If
   Next i
End Sub

Private Sub UserForm_Initialize()
 Dim x As Long
 Set mondico = CreateObject("Scripting.Dictionary")
 Dim Sht As Worksheet, Col As Integer, Lig As Long
  ' Définir la colonne de recherche
  Col = Me.ComboBox1.ListIndex + 1
  ' Pour chaque feuille
  For Each Sht In ThisWorkbook.Worksheets
    ' Si le début du nom de la feuille correspond
    If Left(Sht.Name, 3) = "SAS" Then
      ' Pour chaque ling
      For x = 2 To 4
      For Lig = 2 To 10
        ' Ajouter la valeur de la colonne sélectionnée
        temp = Sht.Cells(Lig, x + Col)
        If temp <> "" Then mondico.Item(temp) = temp
      Next Lig
   Next x
 End If
 Next Sht
 Me.ComboBox2.List = mondico.items
End Sub

JB

 

[cpeens]

Re : Empecher des doublons dans un Combobox

bonjour boisgontier mais sauf erreur de ma part ta proposition recherche uniquement sur 1 Feuil et 1 collone.

alors que mon code actuel recherche sur plusieur feuils et collone.

merci tout de même

 

[Guest]

Re : Empecher des doublons dans un Combobox

Re bonjour,
hello Jacques🙂

Dim x As Long
Dim Sht As Worksheet, Col As Integer, Lig As Long
' Définir la colonne de recherche
Col = Me.ComboBox1.ListIndex + 1
' Pour chaque feuille
For Each Sht In ThisWorkbook.Worksheets
    ' Si le début du nom de la feuille correspond
    If Left(Sht.Name, 3) = "SAS" Then
        ' Pour chaque ling
        For x = 2 To 4
            For Lig = 2 To 10
                ' Ajouter la valeur de la colonne sélectionnée
                With Me.ComboBox2
                    .Text = Sht.Cells(Lig, x + Col)
                    If .ListIndex = -1 Then .AddItem Sht.Cells(Lig, x + Col)
                End With
            Next Lig
        Next x
    End If
Next Sht

A+

 

[cpeens]

Re : Empecher des doublons dans un Combobox

Re bonjour hasco je te remerci pour ton aide sa fonctionne trés bien à trés bientot