Editer une feuille excel sous reseau

[saggigo]

Bonjour à tous,
Voilà j'aimerais éditer une feuille excel qui se trouve sous réseau à partir d'une feuille en local. par exemple copier certaine cellule de la feuille en locale vers la feuille sous réseau.

Quelqu'un à-t-il une idée.

Merci d'avance pour votre aide.

 

[Staple1600]

Re : Editer une feuille excel sous reseau

Bonsoir à tous

saggigo
Tester ceci et nous redire si cela fonctionne

Sub testWoorkBook_ON_NetWork()
Dim nwPath$, nfic$, nwWBK As Workbook
'ici chemin réseau
strPath$ = "\\NOMSERVEUR\Network\FolderName\" 'adapter chemin réseau en conséquence
'ici exemple chemin local
'strPath$ = "C:\Temp\" 'test OK
nfic = "toto.xls" 'adapter nom fichier en conséquence
If Len(Dir(strPath & nfic)) > 0 Then
Set nwWBK = Workbooks.Open(strPath & nfic)
ThisWorkbook.Sheets(1).Cells(1, 1).Copy nwWBK.Sheets(1).Cells(2, 10).Offset(2014)
Else
MsgBox "Le fichier " & strPath & nfic & " n'a pas été trouvé !", vbCritical, "ErroR, Monsignor!"
Exit Sub
End If
End Sub

 

[saggigo]

Re : Editer une feuille excel sous reseau

Bonjour Staple1600
Je te remercie pour ta réponse, ça marche sans l'instruction "Offset (2014)

cependant, pourrais-tu s'il te plait m'aider à introduire les instructions suivantes dans la ton code:

Dim Ligne As Long
Ligne = .Range("A" & Rows.Count).End(xlUp).Row + 1
Range("A8").Copy Destination:=.Range("A" & Ligne) 'Nom du client
Range("C12").Copy Destination:=.Range("B" & Ligne) 'Référence de l'offre
Range("E24").Copy Destination:=.Range("C" & Ligne) 'Montant de l'offre
Range("E8").Copy Destination:=.Range("D" & Ligne) 'Date de l'offre
Range("G8").Copy Destination:=.Range("E" & Ligne) 'Offre établie par
end with


Car pour être plus précis, j'aimerais copier quelques cellules de la feuille locale et les classer dans la feuille en réseau sous forme de tableau

 

[Staple1600]

Re : Editer une feuille excel sous reseau

Bonsoir à tous

saggigo
Essaies avec ces modifications
(Test OK en local sur mon PC )

Modifie comme il se doit avant de tester sur ton réseau: commentes cette ligne : strPath$ = "C:\Temp\" 'test OK
et décommentes celle-ci:
'strPath$ = "\\NOMSERVEUR\Network\FolderName\" 'adapter chemin réseau en conséquence

Code VB:
Sub testWoorkBook_ON_NetWork_BIS()
Dim nwPath$, nfic$, CellAdr, cpt As Byte, nwWBK As Workbook
CellAdr = Array(Array("A8", "A"), Array("C12", "B"), Array("E24", "C"), Array("E8", "D"), Array("G8", "E"))

'ici chemin réseau
'strPath$ = "\\NOMSERVEUR\Network\FolderName\" 'adapter chemin réseau en conséquence

'ici exemple chemin local
strPath$ = "C:\Temp\" 'test OK
nfic = "toto.xls" 'adapter nom fichier en conséquence

If Len(Dir(strPath & nfic)) > 0 Then
Set nwWBK = Workbooks.Open(strPath & nfic)
'Set nwWBK = Workbooks("Classeur2")
For cpt = LBound(CellAdr) To UBound(CellAdr)
ThisWorkbook.Sheets(1).Range(CellAdr(cpt)(0)).Copy nwWBK.Sheets(1).Cells(Rows.Count, CellAdr(cpt)(1)).End(xlUp)(2)
Next cpt
nwWBK.Close True
Else
MsgBox "Le fichier " & strPath & nfic & " n'a pas été trouvé !", vbCritical, "ErroR, Monsignor!"
Exit Sub
End If
Set nwWBK = Nothing
End Sub

 

[saggigo]

Re : Editer une feuille excel sous reseau

Bonjour Staple1600,
J'ai testé et ça marche. Merci beaucoup pour ton aide.