Détection de cellule par une partie de leur contenu

ograin

XLDnaute Nouveau
Bonjour,
J'aimerai savoir s'il est possible de détecter les cellules par une partie de leur contenu dans visual basic.
Mes cellules contiennent du texte et je voudrais détecter toutes celles qui ont un mot que j'écris dans une textbox.
Merci d'avance
Ograin
 

mromain

XLDnaute Barbatruc
Re : Détection de cellule par une partie de leur contenu

Bonjour ograin,

voici une macro montrant l'utilisation de la méthode .Find qui devrait correspondre à ce que tu cherches:
VB:
Sub TestRecherche()
'déclaration des variables
Dim laCell As Range, zoneRecherche As Range, memAdressePremCell As String, motRecherche As String

    'initialiser les variables
    motRecherche = "toto"               'on recherche "toto"
    Set zoneRecherche = ActiveSheet.Cells   'dans toutes les cellules de la feuille active
    
    'rechercher avec la méthode Find la première cellule contenant le mot recherché dans la feuille active
    '   xlPart signifie qu'on ne recherche pas la totalité du contenu de la cellule ("tititi toto tata" sera trouvé)
    '   le remplacer xlWhole pour rechercher la totalité du contenu de la cellule (que "toto")
    Set laCell = zoneRecherche.Find(motRecherche, , xlValues, xlPart)
    
    'si une cellule a été trouvé
    If Not laCell Is Nothing Then
        'mémoriser l'adresse de cette première cellule trouvée
        memAdressePremCell = laCell.Address
        
        'boucler sur toutes les cellules contenant le texte recherché
        Do
            'traiter la cellule trouvée
            MsgBox "Cellule " & laCell.Address & " : """ & laCell.Text & """."
            
            'trouver la cellule suivante contenant le texte recherché
            Set laCell = zoneRecherche.FindNext(laCell)
            
        'boucler jusqu'à qu'on revienne sur la première cellule trouvée
        Loop Until laCell.Address = memAdressePremCell
    End If
End Sub
a+
 
Dernière édition:

Discussions similaires

Réponses
1
Affichages
236

Membres actuellement en ligne

Statistiques des forums

Discussions
312 827
Messages
2 092 557
Membres
105 451
dernier inscrit
mariane_lp