CA année glissante

[othelo11]

Bonjour à tous,

Besoin d'un petit coup de main svp ...

Je cherche la formule me permettant d'afficher, en temps réel, le CA réalisé en trimestre et année glissante par rapport à la date du jour.

Fichier joint pour info

Merci de votre aide

 

[mth]

Re : CA année glissante

Bonjour Othello11,

Un essai en H3:

=SOMMEPROD((E3:E113>DATE(ANNEE(J2)-1;MOIS(J2);JOUR(J2)))*C3:C113)

et I3:

=SOMMEPROD((E3:E113>DATE(ANNEE(J2);MOIS(J2)-3;JOUR(J2)))*C3:C113)

peut-être?

Bonne journée,

mth

 

[Dugenou]

Re : CA année glissante

Bonjour,

en H3 :
=SOMME.SI($E$3:$E$112;">"&DATE(ANNEE(J2)-1;MOIS(J2);JOUR(J2)+1);$C$3:$C$112)-SOMME.SI($E$3:$E$112;">"&J2;$C$3:$C$112)

en I3 :
=SOMME.SI($E$3:$E$112;">"&MOIS.DECALER(J2;-3);$C$3:$C$112)-SOMME.SI($E$3:$E$112;">"&J2;$C$3:$C$112)

la fonction mois.decaler (ou Edate en anglais) est dispo si tu a installé la macro complémentaire Analysis toolpack

Cordialement

mth : le mois -3 ne fonctionne que si on est après Mars

 

[mth]

Re : CA année glissante

re 🙂

Bonjour Dugenou, merci pour ta remarque, mais ça fonctionne de mon coté, par exemple si je mets la date 23/01/2010; la formule

=DATE(ANNEE(J2);MOIS(J2)-3;JOUR(J2))

me renvoie 23/10/2009 et n'indique pas d'erreur. Est-ce la version 2007 qui fait que c'est bon et cette formule ne fonctionnerait pas sur d'autres versions ?
Rien d'urgent mais juste pour ma culture générale et m'éviter de futures bêtises, tu pourras regarder sur ta version et me dire si ok ou pas?

🙂 merci d'avance

m

 

[othelo11]

Re : CA année glissante

Merci beaucoup,

La formule de Dugenou fonctionne à merveille

Encore merci et bonne journée

 

[kjin]

Re : CA année glissante

Bonjour,
En H3

=SOMMEPROD(($E$3:$E112>DATE(ANNEE($J$2);1;1))*($C$3:$C112))

en I3

=SOMMEPROD(($E$3:$E112>MOIS.DECALER(DATE(ANNEE($J$2);1;1);ENT((MOIS($J$2)+2)/3)*3-3))*($C$3:$C112))

A+
kjin

 

[Dugenou]

Re : CA année glissante

Salut mth,

tu as raison , j'avais pas essayé mais ça marche direct avec mois()-3. Pour une date en mars cela donne bien 11/2009

merci de l'info

 

[mth]

Re : CA année glissante

re Dugenou 🙂 et bonjour kjin 🙂

C'est bon à savoir j'avais peur d'avoir fait une bourde sans m'en rendre compte, alors merci beaucoup Dugenou pour ton test 🙂

Bonne journée à tous et @ +

m

 

[othelo11]

Re : CA année glissante

Bonjour à tous,

Je cherche à reprendre les formules de Dugenou en ajoutant un critère, par exemple pour la vendeuse karine...
Merci pour votre aide

Bonjour,

en H3 :
=SOMME.SI($E$3:$E$112;">"&DATE(ANNEE(J2)-1;MOIS(J2);JOUR(J2)+1);$C$3:$C$112)-SOMME.SI($E$3:$E$112;">"&J2;$C$3:$C$112)

en I3 :
=SOMME.SI($E$3:$E$112;">"&MOIS.DECALER(J2;-3);$C$3:$C$112)-SOMME.SI($E$3:$E$112;">"&J2;$C$3:$C$112)

la fonction mois.decaler (ou Edate en anglais) est dispo si tu a installé la macro complémentaire Analysis toolpack

Cordialement

mth : le mois -3 ne fonctionne que si on est après Mars