Ajouter un bouton en haut dans le bandeau excel a cote du ? Apres fenetre

MichD à dit:

Bonjour,

Pour les versions d'Excel antérieure à Excel 2007,

Essaie ceci :

VB:

Sub test()
Dim Mbar As CommandBar

With Application.CommandBars("Worksheet Menu Bar").Controls.Add(Type:=msoControlButton)
    .FaceId = 2992
    .OnAction = "mois_moins_un"
    .TooltipText = "M-1"
    .Caption = "BOUTON A DEPLACER A COTE DE ? APRES FENETRE"
    .Style = msoButtonIconAndCaption
End With

End Sub

Cliquez pour agrandir...

MichD à dit:

Et ça provoque une erreur ? Quelle est-elle?

Quelle est ta version d'Excel ?

Cliquez pour agrandir...

mcj1997 à dit:

Cela ne fonctionnne pas.

Cliquez pour agrandir...

MichD à dit:

Place tout le code suivant dans le ThisWorkbook de ton classeur.

La configuration des barres d'outils est conservée dans un fichier
dédié à cette tâche : Excelxx.xlb situé dans ce répertoire sous Windows 7
C:\Users\Ton profil\AppData\Roaming\Microsoft\Excel\

Le xx dans ExcelXX.xlb représente le numéro de ta version d'Excel.

Si tu supprimes ce fichier, toutes les personnalisations des barres d'outils
seront perdues. Lors de l'ouverture suivante, Excel le recrée tel qu'il existait
après l'installation d'Excel. La sauvegarde de la configuration des barres
d'outils se fait à la fermeture d'Excel.

VB:

Private Sub Workbook_Activate()
Dim Mbar As CommandBar
On Error Resume Next
Application.CommandBars(1).Controls("Mon_Bouton").Delete
With Application.CommandBars(1).Controls.Add(Type:=msoControlButton)
      .FaceId = 2992
      .OnAction = "mois_moins_un"
      .TooltipText = "M-1"
      .Caption = "Mon_Bouton"
      .Style = msoButtonIconAndCaption
End With
End Sub
'--------------------------------------
Private Sub Workbook_Deactivate()
On Error Resume Next
Application.CommandBars(1).Controls("Mon_Bouton").Delete
End Sub
'--------------------------------------
Private Sub Workbook_Open()
Dim Mbar As CommandBar
On Error Resume Next
Application.CommandBars(1).Controls("Mon_Bouton").Delete
With Application.CommandBars(1).Controls.Add(Type:=msoControlButton)
      .FaceId = 2992
      .OnAction = "mois_moins_un"
      .TooltipText = "M-1"
      .Caption = "Mon_Bouton"
      .Style = msoButtonIconAndCaption
End With
End Sub

Cliquez pour agrandir...

MichD à dit:

Comme ceci :

Place tout le code dans un module standard.
Dans le ThisWorkbook, événement Workbook_Open,
tu appelles la macro : "Bouton_Mes_Macros"

VB:

Sub Bouton_Mes_Macros()
Dim Ctl As CommandBarControl

On Error Resume Next
Application.CommandBars(1).Controls("Mes macros").Delete

With Application.CommandBars(1)
    Set Ctl = .Controls.Add(Type:=msoControlPopup)
End With

With Ctl
    .Caption = "Mes macros"
End With

With Ctl.Controls.Add
    .Caption = "Macro1"
    .Style = msoButtonCaption
    .OnAction = "Bonjour"
    '.FaceId = ???
End With
With Ctl.Controls.Add
    .Caption = "Macro2"
    .Style = msoButtonCaption
    .OnAction = "Bonsoir"
   ' .FaceId = ???
End With
'///Tu peux ajouter autant de contrôle que tu désires
'With Ctrl.Controls.add
    '....
'end with

End Sub
'--------------------------------------
Sub Bonjour()
MsgBox "Bonjour"
End Sub
'--------------------------------------
Sub Bonsoir()
MsgBox "Bonsoir"
End Sub

Cliquez pour agrandir...

MichD à dit:

Après avoir copié les macros précédentes dans un module standard,
tu ajoutes ceci dans le Thisworkbook de ton fichier.
C'est le même principe que précédemment.

VB:

Private Sub Workbook_Activate()
Call Bouton_Mes_Macros
End Sub
'----------------------
Private Sub Workbook_Deactivate()
On Error Resume Next
Application.CommandBars(1).Controls("Mes macros").Delete
End Sub
'----------------------
Private Sub Workbook_Open()
Bouton_Mes_Macros
End Sub

Cliquez pour agrandir...