Ceci est une page optimisée pour les mobiles. Cliquez sur ce texte pour afficher la vraie page.

Microsoft 365 Vérification de ma formule

Usine à gaz

XLDnaute Barbatruc
Bonsoir à toutes et à tous,

J'ai encore du faire une formule "biscornue"

Je n'arrive à comprendre pourquoi elle fonctionne chez moi et pas chez ma collègue Grrrr !!!

Nous sommes tous les deux avec le même windows 10 64 et le même excel office365 en 64.

Pourriez-vous me dire si ma formule est bonne ?
en colonne P :
VB: 
=SI(OU(J8="";K8="");"";SI(CNUM(SUBSTITUE(GAUCHE(J8;8);"-";".";1))=AUJOURDHUI();1;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(GAUCHE(J8;8);"-";".";1));0))=MOIS(AUJOURDHUI());2;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(GAUCHE(J8;8);"-";".";1));0))<MOIS(AUJOURDHUI());"3";""))))

Je joins le fichier test pour comprendre le contexte.
Je vous remercie,
Amicalement,
lionel,
 

Pièces jointes

  • comptage_test.xlsm
    23.6 KB · Affichages: 6
Solution
Bonsoir @Usine à gaz

=SI(OU(J4="";K4="");"";SI(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1))=AUJOURDHUI();1;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1));0))=MOIS(AUJOURDHUI());2;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1));0))<MOIS(AUJOURDHUI());"3";""))))

AUJOURDHUI c'est un numéro de série, et donc comparer avec un numéro de série DATEVAL(Ici la date)
Trier par date Trier par votes

laurent950

XLDnaute Barbatruc
Bonsoir @Usine à gaz

=SI(OU(J4="";K4="");"";SI(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1))=AUJOURDHUI();1;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1));0))=MOIS(AUJOURDHUI());2;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1));0))<MOIS(AUJOURDHUI());"3";""))))

AUJOURDHUI c'est un numéro de série, et donc comparer avec un numéro de série DATEVAL(Ici la date)
 
Dernière édition:
Vote positif 0 Vote négatif
Solution

TooFatBoy

XLDnaute Barbatruc
Usine à gaz à dit:
Pourriez-vous me dire si ma formule est bonne ?
en colonne P :
Cliquez pour agrandir...
VB: 
=SI(OU(J8="";K8="");"";SI(CNUM(SUBSTITUE(GAUCHE(J8;8);"-";".";1))=AUJOURDHUI();1;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(GAUCHE(J8;8);"-";".";1));0))=MOIS(AUJOURDHUI());2;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(GAUCHE(J8;8);"-";".";1));0))<MOIS(AUJOURDHUI());"3";""))))
Est-ce qu'on n'avait pas déjà traité ce problème il y a quelques jours et immédiatement déduit qu'il fallait logiquement utiliser un slash plutôt qu'un point comme séparateur au niveau de la date ?
À moins que ce soit encore ma mémoire qui me joue des tours.
 
Dernière édition:
Vote positif 0 Vote négatif

Usine à gaz

XLDnaute Barbatruc
Bonjour à toutes et à tous,
je vous souhaite un beau dimanche

Je reviens sur ce fil car l'année à changé et ma formule ne fonctionne plus Grrrrrr !!!
En #post5, laurent950 m'avait donné la bonne formule :
=SI(OU(J4="";K4="");"";SI(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1))=AUJOURDHUI();1;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1));0))=MOIS(AUJOURDHUI());2;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1));0))<MOIS(AUJOURDHUI());"3";""))))

Mais depuis le 1er janvier 2022 ... ça ne marche plus .. Nada ... queue d'ail.

Je n'arrive pas à la modifier.
Je joins le fichier et je continue mes tests.
Pourriez-vous me donner la bonne formule ?
Je vous remercie
lionel
 

Pièces jointes

  • comptage_test.xlsm
    23.1 KB · Affichages: 7
Vote positif 0 Vote négatif

Bernard_XLD

XLDnaute Barbatruc
Membre du Staff
Supporter XLD
Bonjour Lionel, le fil, le forum

Si tu fais une comparaison sur un nombre de mois inférieur au mois d'aujourd'hui, il te faut prendre en compte le changement d'année et ajouter 12 pour ta comparaison quand l'année d'aujourd'hui est supérieure à l'année de J4.

VB: 
=SI(OU(J4="";K4="");"";SI(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1))=AUJOURDHUI();1;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1));0))=MOIS(AUJOURDHUI());2;SI(ANNEE(DATEVAL(GAUCHE(J4;8)))<ANNEE(AUJOURDHUI());SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1));0))<12+MOIS(AUJOURDHUI());"3";"");SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1));0))<MOIS(AUJOURDHUI());"3";"")))))
 
Vote positif 0 Vote négatif

Bernard_XLD

XLDnaute Barbatruc
Membre du Staff
Supporter XLD
re,
un peu plus simple comme cela
VB: 
=SI(OU(J4="";K4="");"";SI(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1))=AUJOURDHUI();1;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1));0))=MOIS(AUJOURDHUI());2;SI(MOIS(FIN.MOIS(CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1));0))<((ANNEE(AUJOURDHUI())-ANNEE(DATEVAL(GAUCHE(J4;8))))*12)+MOIS(AUJOURDHUI());"3";""))))
 
Vote positif 0 Vote négatif

Bernard_XLD

XLDnaute Barbatruc
Membre du Staff
Supporter XLD
re,

D'ailleurs en relisant les posts précédents de cette discussion, je pense qu'en utilisant dateval, tes cnum et substitue sont devenus inutiles, dateval renvoyant le numéro de série de la date, on peut donc encore simplifier.
VB: 
=SI(OU(J4="";K4="");"";SI(DATEVAL(GAUCHE(J4;8))=AUJOURDHUI();1;SI(MOIS(FIN.MOIS(DATEVAL(GAUCHE(J4;8));0))=MOIS(AUJOURDHUI());2;SI(MOIS(FIN.MOIS(DATEVAL(GAUCHE(J4;8));0))<((ANNEE(AUJOURDHUI())-ANNEE(DATEVAL(GAUCHE(J4;8))))*12)+MOIS(AUJOURDHUI());"3";""))))
 
Vote positif 0 Vote négatif

mapomme

XLDnaute Barbatruc
Supporter XLD
Re,

Ma première tentative avec LET(...)

Avec la formule du post #10

Si on nomme l'expression: CNUM(SUBSTITUE(DATEVAL(GAUCHE(J4;8));"-";".";1)) avec le nom laDate,
et si on nomme AUJOURDHUI() avec le nom Auj

alors la formule s'écrit :
VB: 
SI(laDate=Auj;1;SI(MOIS(laDate)=MOIS(Auj);2;SI(ANNEE(laDate)<ANNEE(Auj);SI(MOIS(FIN.MOIS(laDate;0))<12+MOIS(Auj);"3";"");SI(MOIS(laDate)<MOIS(Auj);"3";"")))))

Avec office 365, on peut utiliser le LET(...) et la formule devient :
VB: 
=LET(Auj;AUJOURDHUI();laDate;CNUM(SUBSTITUE(DATEVAL(GAUCHE(J5;8));"-";".";1));SI(OU(J5="";K5="");"";SI(laDate=Auj;1;SI(MOIS(laDate)=MOIS(Auj);2;SI(ANNEE(laDate)<ANNEE(Auj);SI(MOIS(FIN.MOIS(laDate;0))<12+MOIS(Auj);"3";"");SI(MOIS(laDate)<MOIS(Auj);"3";""))))))

Voir colonne Q
 

Pièces jointes

  • Usine à gaz- comptage_test- v1.xlsm
    32.8 KB · Affichages: 1
Dernière édition:
Vote positif 0 Vote négatif
Identifiez-vous ou inscrivez-vous pour participer.

Discussions similaires

  • Résolu(e)
Microsoft 365 formule jj mm aaaa hh:mm qui ne fonctionne pas complètement
Réponses
14
Affichages
907
Usine à gaz
  • Résolu(e)
Microsoft 365 formule compliquée pour moi
2
Réponses
19
Affichages
2 K
Usine à gaz
  • Question
Microsoft 365 fonction qui peut contenir du texte ou une date
2 3
Réponses
43
Affichages
3 K
patricktoulon
P
  • Résolu(e)
XL 2016 Tournoi de volley - Tri par terrain
2
Réponses
21
Affichages
2 K
Phil22
P
  • Résolu(e)
Microsoft 365 Formule que je ne parviens pas à adapter
Réponses
2
Affichages
472
Usine à gaz
  • Question
XL 2013 problème formule
Réponses
3
Affichages
730
djidji59430
  • Résolu(e)
Microsoft 365 Mon casse-tête depuis 1 semaine = je vais devenir maboul
4 5 6
Réponses
79
Affichages
5 K
Usine à gaz
  • Résolu(e)
Microsoft 365 Format date qui ne fonctionne pas sur office2019
2 3
Réponses
36
Affichages
3 K
Usine à gaz
  • Résolu(e)
Microsoft 365 code renvoie formule dans ma cellule avec des @
2
Réponses
15
Affichages
1 K
Usine à gaz
M
  • Question
XL 2016 Réduire le nombre de SI dans ma formule (limité à 64)
Réponses
11
Affichages
1 K
mapomme
Menu
Connexion
S'inscrire
Les cookies sont requis pour utiliser ce site. Vous devez les accepter pour continuer à utiliser le site. En savoir plus…