VBA Conversion Numéro d'une colonne en Lettre Colonne > à 27

[perdinch]

Bonsoir,

Peut-on adapter le code pour gérer la conversion de colonne en chiffre vers colonne en lettre au delà de la colonne 27 soit la colonne Z
Ce code génère des zones nommées automatiquement colonne par colonne dans des onglets dont le nom commence par Data_Base_?

Il crée bien des zones nommées colonne par colonne mais s'arrête à la colonne Z soit LA 26ème.

un fichier exemple en pièce jointe

merci de vos suggestions

 

[Robert]

Re : VBA Conversion Numéro d'une colonne en Lettre Colonne > à 27

Bonjour Perdinch, bonjour le forum,

Peut-être avec :

colonne = Split(c.Address, "$")(1)

 

[Modeste geedee]

Re : VBA Conversion Numéro d'une colonne en Lettre Colonne > à 27

Bonsour®

Sub Creer_plages_Auto_ongl_Data_Base()
Dim c As Range
Dim DernLigne As String
Dim cell_depart As String
Dim lig_fin As Range
Dim colonne As String
Dim feuill As Worksheet

For Each feuill In ActiveWorkbook.Worksheets
If feuill.Name Like "Data_Base_*" Then
  feuill.Select
  For Each c In Range([A1], [IV1].End(xlToLeft))
    '************* identification de la lettre de la colonne active
    colonne = Application.Substitute(Cells(1, c.Column).Address(False, False), "1", "")
    DernLigne = Range(colonne & Rows.Count).End(xlUp).Address
    'zone nommées crées depuis la ligne 2
    cell_depart = c.Offset(1, 0).Address
    If Not IsEmpty(c.Offset(1, 0)) Then
    '-------------------------------------------     vvvv
       ActiveWorkbook.Names.Add Name:=feuill.Name & colonne, RefersTo:="= " & feuill.Name & "! " & cell_depart & ":" & DernLigne & ""
    End If
  Next
End If
Next feuill
End Sub

 

[PMO2]

Re : VBA Conversion Numéro d'une colonne en Lettre Colonne > à 27

Bonjour,

Le code d'un algorithme de mon cru qui permet de convertir le numéro de colonne en caractères Alpha.

Sub test()
MsgBox ConvNum2Alpha(ActiveCell.Column)
End Sub

'###################################################
'### Patrick Morange : Algorithme pour convertir ###
'### le numéro de colonne en caractères Alpha    ###
'###################################################
Function ConvNum2Alpha(Colonne As Long) As String
Dim x&
Dim y&
Dim A$
'---
x& = Colonne
'--- x00 ---
If x& > 702 Then
  y& = x& \ 26 ^ 2
  If y& > 0 Then
    A$ = Chr(65 + y& - 1)
  End If
End If
x& = x& - (y& * 26 ^ 2)
'--- 0x0 ---
If x& > 26 Then
  y& = x& \ 26 ^ 1
  If y& > 0 Then
     If y& * 26 ^ 1 = x& Then
      A$ = A$ & Chr(65 + y& - 2)
    Else
      A$ = A$ & Chr(65 + y& - 1)
    End If
  End If
End If
x& = x& - (y& * 26 ^ 1)
'--- 00x ---
  If x& > 0 Then
    A$ = A$ & Chr(65 + x& - 1)
  Else
    A$ = A$ & "Z"
  End If
'---
ConvNum2Alpha = A$
End Function

 

[Modeste geedee]

Re : VBA Conversion Numéro d'une colonne en Lettre Colonne > à 27

Bonsour® Salut Patrick©!

🙄
selon proposition intégrée dans : #3

Sub LettresColonne()
MsgBox Application.Substitute(Cells(1, ActiveCell.Column).Address(False, False), "1", "")
End Sub