Une erreur dans ma formule de condition

[creolia]

Bonjour à tous je souhaitais effacer les valeurs d'une plage de cellule sous deux conditions

si dans M1 il est afficher dimanche ou samedi les valeur de N1 et O1 s'efface

j'ai donc essayer avec ceci

=SI(M1<>("dimanche");N1;"");SI(M1<>("samedi");N1;"")

mais evidement sa fonctionne pas du tout donc si quelqu'un pouvais m'aider svp je precise que je souhaiterais une formule et non de la vba svp

petite precision c'est pas un secret je suis un trés nul en formule donc c'est peut etre du charabia ce que j'ai mis en formule.

je vous remercie d'avance

 

[JNP]

Re : Une erreur dans ma formule de condition

Bonsoir Creolia 🙂,
C'est surtout que par formule, tu ne peux pas effacer une valeur d'une autre cellule 🙄...
Par contre tu peux écrire en N1 et O1

=SI(OU(M1="dimanche";M1="samedi");"";"ce que tu veux dans le cas contraire")

ceci à condition que la formule soit remplie du texte dimanche ou samedi 😛...
Si c'est une date en format personnalisé, c'est

=SI(OU(JOURSEM(M1)=1;JOURSEM(M1)=7);"";"ce que tu veux dans le cas contraire")

qu'il faudra écrire 🙄...
Bon courage 😎

 

[Tibo]

Re : Une erreur dans ma formule de condition

Bonsoir,

Essaye avec ceci :

=SI(OU(M1<>"dimanche";M1<>"samedi");N1;"")

Si les cellules contiennent des dates, la formule devient :

=SI(JOURSEM(M1;2)>5;"";N1)

Je te laisse tester

@+

Edit : Bing ! salut Jean-Noël 🙂

@+

 

[creolia]

Re : Une erreur dans ma formule de condition

Bonjour tibo bonjour Jnp et merci de votre aide votre solution fonctionne en revanche j'ai une autre petite complementaire

dans les cellule N1

j'utilise deja une condition

=SI(E5<>"";SI(E5<"7:00"*1;"7:00"*1;E5-$A$1);"")

puis je l'associer à votre formule sans avoir d'erreur

je vous est mis mon fichier joins

en gros j'ai 2 planning celui de mon travail et celui de ma nourice.

je remplie celui de mon travail qui lui remplie automatiquement celui de ma nourice les heures de ma nourice sont incrementé de 45 mn de plus (pour le trajet)

sachant que avant 7h00 c'est ma femme qui depose et apres 20h00 c'est elle qui le recupere.

bref c'etait pour expliquer un peu mes intentions.

donc pour faire fonctionner les condition si dessus j'ai utilisé grace a l'aide du forum cette formule

=SI(E5<>"";SI(E5<"7:00"*1;"7:00"*1;E5-$A$1);"")

et je souhaite également ajouter votre solution a ses condition existant puis je le faire si oui comment svp merci d'avance

 

[Tibo]

Re : Une erreur dans ma formule de condition

Bonjour,

Il aurait été intéressant que tu nous donnes manuellement le résultat attendu pour quelques lignes.

En faisant la fusion de ta formule et de celle proposée plus tôt, ça donne ceci :

=SI(OU(M5<>"dimanche";M5<>"samedi");SI(E5<>"";SI(E5<"7:00"*1;"7:00"*1;E5-$A$1);"");N5)

Sans trop de conviction.

Je ne vois pas ce que viens faire le N5 dans la formule (pour les samedi et dimanche)

A te (re)lire avec plus de détails.

@+

 

[creolia]

Re : Une erreur dans ma formule de condition

bonjour tibo ta solution ne fonctionne pas car il m'efface pas les valeurs pour mieux comprendre j'ai refais un tableau manuellement avec les explication en face

je reste a votre disposition pour plus d'explication et merci d'avance

 

[JNP]

Re : Une erreur dans ma formule de condition

Re, salut Tibo 🙂

ta solution ne fonctionne pas car il m'efface pas les valeurs

C'est surtout que par formule, tu ne peux pas effacer une valeur d'une autre cellule 🙄...

J'ai l'impression que tu tournes en rond 🙄...
En P5

=SI(OU(E5=0;$B5="samedi";$B5="dimanche");"";MAX(E5-$A$1;TEMPS(7;0;0)))

et en Q5

=SI(OU(F5=0;$B5="samedi";$B5="dimanche");"";MIN(F5+$A$1;TEMPS(20;0;0)))

les 2 à tirer vers le bas 😛...
Bon courage 😎

 

[creolia]

Re : Une erreur dans ma formule de condition

Re bonjour JNP merci pour ta solution sa fonctionne super bien une derniere question si je peur me permettre rien à voir avec ce projet mais qui y ressemble

si je veut mettre une condition en D5 exemple si E5 vide ecrire REPOS si heures inférieures à 12:00 Matin superieur à 12:00 Aprés midi comment puis je faire svp j'ai trouvez un début de solution aprés plusieur essais

=SI(E5<(TEMPS(12;0;0));"MAT";"")

mais j'ai pas réussi à les cumulé du genre

=SI(E5<(TEMPS(12;0;0));"MAT";"");SI(E5>(TEMPS(12;0;0));"AP";"");Si(E5<>("");OFF)

merci d'avance de l'aide

 

[JNP]

Re : Une erreur dans ma formule de condition

Re 🙂,
Techniquement, j'écrirais

=CHOISIR(ARRONDI.SUP((E5)*2;0)+1;"Repos";"Matin";"Après-midi")

sachant que pour moi (et pour Excel 😛), l'après-midi commence à 12:01 et non à 12:00 🙄...
Bon courage 😎

 

[creolia]

Re : Une erreur dans ma formule de condition

Merci JPN mais malgré ta solution j'ai une erreur quand les cellules sont vide(#valeur)je pense sa viens du fait que les valeurs sont charger dans la cellule par une formule.

peut ont y remedier stp merci

 

[JNP]

Re : Une erreur dans ma formule de condition

Re 🙂,
le plus logique serait de modifier

=SI(OU(E5=0;$B5="samedi";$B5="dimanche");0;MAX(E5-$A$1;TEMPS(7;0;0)))

pour ne pas mélanger des caractères et des nombres, et d'utiliser une MFC pour dre que si la cellule est égale à 0, le texte est de la même couleur que le fond 🙄...
Sinon, mais la formule est plus lourde et moins belle 😛

=SI(E5="";"Repos";CHOISIR(ARRONDI.SUP(E5*2;0);"Matin";"Après-midi"))

Bonne soirée 😎

 

[creolia]

Re : Une erreur dans ma formule de condition

Merci JPN pour ta patience et ton aide précieuse je vais tester toute tes proposition et je te tiens au courant un grand merci et une bonne soirée à toi à trés bientot

 

[creolia]

Re : Une erreur dans ma formule de condition

bonjour JNP j'ai tous tester sa fonctionne à part un truc dans ma demande je faisais par d'une des conditions qui n'apparait pas je demandais que si l'heure de début en E5 etait inférieur à 7:00 celui ci affiche en P5 07:00 sa c'est OK grace à ta formule

=SI(OU(E5=0;$B5="samedi";$B5="dimanche");0;MAX(E5-$A$1;TEMPS(7;0;0)))

mais je souhaitais également si en G5 l'heure de fin etait supérieur à 20:00
en P5 s'affiche 20:00

peut tu me faire cette petite modification stp j'ai bien essayer ceci

=SI(OU(F5=0;$M5="samedi";$M5="dimanche");"";MAX(G5+$A$1;TEMPS(20;0;0)))

mais il me met tous à 20:00

je te remercie d'avance de tous l'aide apporté à mon projet

à bientot

 

[JNP]

Re : Une erreur dans ma formule de condition

Re 🙂,

mais je souhaitais également si en G5 l'heure de fin etait supérieur à 20:00
en P5 s'affiche 20:00

peut tu me faire cette petite modification stp j'ai bien essayer ceci

=SI(OU(F5=0;$M5="samedi";$M5="dimanche");"";MAX(G5+$A$1;TEMPS(20;0;0)))

mais il me met tous à 20:00

Il me semble que je t'avais déjà donné la solution 🙄...

en Q5

=SI(OU(F5=0;$B5="samedi";$B5="dimanche");"";MIN(F5+$A$1;TEMPS(20;0;0)))

Bon WE 😎

 

[creolia]

Re : Une erreur dans ma formule de condition

Re désolé j'avais pas vue tu me l'avais déja donnée et bien tous fonctionne parfaitement merci à toi sans ton aide je ne serais jamais arrivée merci également au intervenant pour leur aide bon week end à tous et un grand merci