une data perdue lors d'un transpose

vgendron

XLDnaute Barbatruc

• 16 Octobre 2015

• #2

Re : une data perdue lors d'un transpose

Hello

il est ou ton code?? je ne vois pas de module vba dans ton fichier

 

Vote positif 0 Vote négatif

gosselien

XLDnaute Barbatruc

• 16 Octobre 2015

• #3

Re : une data perdue lors d'un transpose

oups ...
sorry j'ai fais une copie acceptable niveau taille mais oublié d'y mettre ce code:

Option Base 1
Sub Inverser_regrouper()
' regrouper les dates de la colonne A feuille Source et
' recopier celles-ci en feuille cible
' 10/2015
'
Set f = Sheets("source")
Set f1 = Sheets("cible")
Set d = CreateObject("Scripting.Dictionary")
Set d2 = CreateObject("Scripting.Dictionary")
f.Select
For Each c In [A2].Resize(Application.CountA([A:A]))
tmp = c.Value & c.Offset(, 1)
If c.Value <> "" Then
If Not d2.exists(tmp) Then d(c.Value) = d(c.Value) & "|" & c.Offset(, 1)
d2(tmp) = ""
End If
Next c
ligne = 1: col = 4
f1.Select
For Each c In d.keys 'pour chaque clé (clé = date ici)
f1.Cells(ligne, col) = c 'les dates une après l'autre de gauche à droite en commencant en colonne 4 ligne 1
a = Split(d.Item(c), "|")
f1.Cells(1, col).Offset(1).Resize(UBound(a)) = Application.Transpose(a)
col = col + 1
Next c
f1.Select
End Sub

 

Vote positif 0 Vote négatif

vgendron

XLDnaute Barbatruc

• 16 Octobre 2015

• #4

Re : une data perdue lors d'un transpose

Re,

suis pas top pour les dictionnaires.. mais à priori. ton souci numéro 2 vient du numéro 1

Code:

For Each c In d.keys 'pour chaque clé (clé = date ici)
f1.Cells(ligne, col) = c 'les dates une après l'autre de gauche à droite en commencant en colonne 4 ligne 1
a = Split(d.Item(c), "|")
f1.Cells(1, col).Offset(1).Resize(UBound(a)) = Application.Transpose(a)
col = col + 1
Next c

à remplacer par

Code:

For Each c In d.keys 'pour chaque clé (clé = date ici)
    f1.Cells(ligne, col) = c  'les dates une après l'autre de gauche à droite en commencant en colonne 4 ligne 1
    a = Split(d.Item(c), "|")
    f1.Cells(2, col).Resize(UBound(a)) = Application.transpose(a)
    col = col + 1
Next c

f1.Cells(1, col).Offset(1).Resize(UBound(a)) = Application.Transpose(a)
tu commences à la ligne 1 avec un offset de 1 ligne. pourquoi ne pas faire directement
f1.Cells(2, col).Resize(UBound(a)) = Application.transpose(a)

tu vois en ligne 2, du vide.. je pense qu'il s'agit en fait de ta ligne manquante..
c'est là où ma connaissance des dictionnaires est nulle.. quand tu le remplis, n'y a t il pas un risque que
data 14/10/15 10 soit vu comme déjà existant car il y a déjà data 14/10/15 1

 

Vote positif 0 Vote négatif

vgendron

XLDnaute Barbatruc

• 16 Octobre 2015

• #5

Re : une data perdue lors d'un transpose

et autre question..
il sert à quoi le dictionnaire 2 ?
j'ai l'impression que tu n'y mets jamais rien.

 

Vote positif 0 Vote négatif

gosselien

XLDnaute Barbatruc

• 16 Octobre 2015

• #6

Re : une data perdue lors d'un transpose

vgendron à dit:

c'est là où ma connaissance des dictionnaires est nulle.. quand tu le remplis, n'y a t il pas un risque que
data 14/10/15 10 soit vu comme déjà existant car il y a déjà data 14/10/15 1

Cliquez pour agrandir...

Hello,

non parce que si tu as 8 x la même donné pour une date et 2 autres; ça fait donc 3 data pour cette date et il devrait transposer 3 données pour une seule date...

 

Vote positif 0 Vote négatif

vgendron

XLDnaute Barbatruc

• 16 Octobre 2015

• #7

Re : une data perdue lors d'un transpose

tout est dans le Ubound...
avec ceci.. on récupère la donnée manquante..

f1.Cells(2, col).Resize(UBound(a) + 1) = Application.transpose(a)


J'adore le mode pas à pas et les espions. on apprend beaucoup sans passer par l'aide excel !! ;-)

 

Vote positif 0 Vote négatif

gosselien

XLDnaute Barbatruc

• 16 Octobre 2015

• #8

Re : une data perdue lors d'un transpose

Oui je m'en sers aussi du pas à pas mais j'ai quelques codes où je n'ai pas ce "+1" et quand tu mets ta souris sur le UBOUND il affiche bien le nombre de données contenues pour une date, mais le transpose en oublie une.

 

Vote positif 0 Vote négatif

vgendron

XLDnaute Barbatruc

• 16 Octobre 2015

• #9

Re : une data perdue lors d'un transpose

oui c'est ce que je viens de voir aussi..
je regarde si il y a des options à imposer au transpose en cause ;-)

 

Vote positif 0 Vote négatif

gosselien

XLDnaute Barbatruc

• 16 Octobre 2015

• #10

Re : une data perdue lors d'un transpose

Le transpose donne bien à présent toutes les données pour chaque date mais pas moyen de coller ça à la ligne 2 (qu'il efface en passant) 🙁

 

Vote positif 0 Vote négatif

vgendron

XLDnaute Barbatruc

• 16 Octobre 2015

• #11

Re : une data perdue lors d'un transpose

en attendant de trouver mieux...reste le Rows(2).delete ....

 

Vote positif 0 Vote négatif

Paf

XLDnaute Barbatruc

• 16 Octobre 2015

• #12

Re : une data perdue lors d'un transpose

Bonjour gosselien, vgendron

Même avec Option Base 1, l'indice du tableau a commence à 0; s'il y a 10 éléments Ubound(a) vaut 9. D'où le +1 nécessaire

Pour la ligne vide insérée en ligne 2, elle est du à l'élément a(0) qui est vide, car les item du dico d commencent par un "|" et le split génére un élément supplémentaire vide.

Il faudrait modifier le chargement du dico ainsi:

Code:

 For Each c In f.[A2].Resize(Application.CountA(f.[A:A]))
    If c.Value <> "" Then
        If Not d.exists(c.Value) Then
            d(c.Value) = c.Offset(, 1)
        Else
            d(c.Value) = d(c.Value) & "|" & c.Offset(, 1)
        End If
    End If
 Next c

A+

 

Vote positif 0 Vote négatif

vgendron

XLDnaute Barbatruc

• 16 Octobre 2015

• #13

Re : une data perdue lors d'un transpose

hello Paf.. et merci

c'est pourtant si simple ;-)

bon. c'est pas tout. mais ca m'a donné soif cette histoire
Bon week end à tous

 

Vote positif 0 Vote négatif

gosselien

XLDnaute Barbatruc

• 16 Octobre 2015

• #14

Re : une data perdue lors d'un transpose

vgendron à dit:

en attendant de trouver mieux...reste le Rows(2).delete ....

Cliquez pour agrandir...

pas très élégant, tu admettras 🙂

 

Vote positif 0 Vote négatif

gosselien

XLDnaute Barbatruc

• 16 Octobre 2015

• #15

Re : une data perdue lors d'un transpose

De fait c'était simple ....
Merci Paf pour les explications !!!

P.

 

Vote positif 0 Vote négatif