tri automatique

[picronte]

bonsoir
sur le fichier j'aimerai qu'il me tri automatiquement dans l'onglet feuil le resultat de l'onglet base de ad à bd par rapport à ah
je joint le fichier pour mieux comprendre
merci

 

[job75]

Re : tri automatique

Re,

Bon maintenant c'est clair : il faut renseigner 22 colonnes à droite du filtre.

Pas besoin d'ajouter des données en feuille BASE :

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [B1]) Is Nothing Then Exit Sub
Range("A2:Z" & Rows.Count).ClearContents 'RAZ
If [B1] = "" Then Exit Sub
Dim lig&, cel As Range, col%
Application.ScreenUpdating = False
With Feuil1 'CodeName
  .AutoFilterMode = False
  With .Range("AH7", .Cells(.Rows.Count, "AH").End(xlUp))
    .AutoFilter 1, IIf([B1] = "Tous", "*", [B1]) 'filtre automatique
    .Offset(, -2).Resize(, 4).SpecialCells(xlCellTypeVisible).Copy [A2]
    .Offset(, -4).Resize(, 2).SpecialCells(xlCellTypeVisible).Copy [C2]
    lig = 2
    For Each cel In .SpecialCells(xlCellTypeVisible)
      For col = 3 To 24
        If LCase(.Parent.Cells(cel.Row, col)) = "o" Then _
          Cells(lig, col + 2) = .Parent.Cells(5, col)
      Next
      lig = lig + 1
    Next
  End With
  .AutoFilterMode = False
End With
End Sub

Nota : j'ai ajouté "*" comme critère du filtre pour "Tous".

Fichier (2).

A+

 

[picronte]

Re : tri automatique

re,job75
grace à vous et a mon entêtement je reussi à faire un bout de chemin.
il reste à mettre en premier en ligne A2 dans l'onglet feuil, quand la colonne E est renseigné puis f,g,h,i; et ainsi de suite.
Picronte

 

[job75]

Re : tri automatique

Re,

Le filtre que vous utilisez nécessite des formules dans les 22 colonnes AH:BC de la feuille BASE, libre à vous.

Maintenant pour trier le filtre :

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [D1]) Is Nothing Then Exit Sub
If [D1] = "" Then Exit Sub
Dim n&
With Feuil1 'CodeName
  .AutoFilterMode = False
  With .Range("BD7", .Cells(.Rows.Count, "BD").End(xlUp))
    .AutoFilter 1, [D1] 'filtre automatique
    .Offset(, -26).Resize(, 26).SpecialCells(xlCellTypeVisible).Copy [A2]
    n = .SpecialCells(xlCellTypeVisible).Count
  End With
  .AutoFilterMode = False
End With
'---tri du filtre---
[AA2].Resize(n).FormulaR1C1 = "=MATCH(""?*"",RC5:RC26,0)"
[A2:AA2].Resize(n).Sort [AA2], xlAscending, Header:=xlYes
[AA:AA].ClearContents
Range([A2:Z2].Offset(n), Cells(Rows.Count, 1)).ClearContents
End Sub

La macro entre en colonne AA une formule qui permet le tri.

A+

 

[picronte]

Re : tri automatique

re,
Voila j'ai fini le fichier, j’aurai bien voulu que le trie se fasse automatiquement!!!!!!!
À bientôt et merci pour tous sans vous je n'aurai jamais pu le finir.
Picronte

 

[job75]

Re : tri automatique

Voila j'ai fini le fichier, j’aurai bien voulu que le trie se fasse automatiquement!!!!!!!

Mon post #18 une minute avant le vôtre...

A+

 

[picronte]

Re : tri automatique

Bonsoir job75,
Après plusieurs heures passées sur le fil, j'ai fini par trouver les aides que j'attendais.
je tiens personnellement a vous remerciez pour votre patience.
le fichier fonctionne très bien, je ne sais pas comment j'aurai pu faire sans vous.
je le met en pièce jointe pour celui à qui ça intéresse.
je suis intéressé par excel, pouvez-vous m'indiquer un cd ou un livre qui expliquer les codes.
Merci
Picronte

 

[job75]

Re : tri automatique

Re,

Perso j'ai surtout appris (et je continue à apprendre) VBA en consultant l'aide VBA.

Mais il existe de bons bouquins dans toute librairie spécialisée.

A+

 

[job75]

Re : tri automatique

Bonjour picronte,

Vous vous rendrez peut-être compte que dans certains cas les formules de BASE!AH:BC sont copiées en filtrant :

- si l'on introduit "Tous" dans la liste de validation en D1

- si la plage filtrée par BASE!BD8 est unique (jointive).

Il vaut donc mieux faire un Collage spécial-Valeurs :

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [D1]) Is Nothing Then Exit Sub
If [D1] <> "" Then
  Dim n&
  With Feuil1 'CodeName
    Application.ScreenUpdating = False
    .AutoFilterMode = False
    With .Range("BD7", .Cells(.Rows.Count, "BD").End(xlUp))
      .AutoFilter 1, IIf([D1] = "Tous", "*", [D1]) 'filtre automatique
      .Offset(, -26).Resize(, 26).SpecialCells(xlCellTypeVisible).Copy
      [A2].PasteSpecial xlPasteValues
      n = .SpecialCells(xlCellTypeVisible).Count
    End With
    .AutoFilterMode = False
  End With
  '---tri du filtre---
  [AA2].Resize(n).FormulaR1C1 = "=MATCH(""?*"",RC5:RC26,0)"
  [A2:AA2].Resize(n).Sort [AA2], xlAscending, Header:=xlYes
  [AA:AA].ClearContents
  Target.Select
End If
Range([A2:Z2].Offset(n), Cells(Rows.Count, 1)).ClearContents
End Sub

Fichier joint.

A+