Tableau récapitulatif

[arborigene56]

Bonjour tout le monde

je dois créer un tableau de prospects récapitulant plusieurs listes de participants a divers salon.
Pour cela j'ai crée un onglet par salon et j'ai rempli plusieurs colonnes ( tous mes onglets sont identiques).
Je veux créer un tableau récapitulatif dans un nouveau classeur qui cumule à la suite les infos des différents onglets et qui se met a jour quand je fais des modifs sur mon classeur de base...est ce possible?

 

[Victor21]

Re : Tableau récapitulatif

Bonjour, et bienvenue sur le forum.

est ce possible?

Oui, probablement...

Copié-collé d'une réponse récente :
"Comme il est conseillé à l'alinéa C du paragraphe 3 de Lien supprimé, un court extrait représentatif de vos fichiers permettrait à ceux qui veulent vous aider de tester les solutions qu'ils sont prêts à vous proposer. "

 

[arborigene56]

Re : Tableau récapitulatif

pour des raisons de confidentialité j'ai remplacé les noms par n'importe quoi mais en gros mon classeur de base ressemble à la pièce jointe sauf qu'il y a plus d'onglets et que le nombre de lignes peut évoluer

 

[arborigene56]

Re : Tableau récapitulatif

le mieux que j'ai trouvé pour le moment est le copier/coller avec liaison , sur le principe c'est bon mais je ne peux pas rajouter de lignes facilement... :s

 

[Victor21]

Re : Tableau récapitulatif

Re,

Un essai en pj.

Le code :

Option Explicit

Sub Regroupe()
    Dim Sh As Worksheet

    testme
    With Sheets("RECAP")
        .Cells.ClearContents
        Sheets(2).Range("1:1").Copy .Range("A1")
    End With
    For Each Sh In ActiveWorkbook.Sheets
        If Sh.Name <> "RECAP" Then
            Sh.Range("A2:J" & Sh.Range("A" & Rows.Count).End(xlUp).Row).Copy Sheets("RECAP").Range("A" & Rows.Count).End(xlUp).Offset(1, 0)
        End If
    Next Sh

End Sub

Private Sub testme()
    If WorksheetExists("RECAP", ActiveWorkbook) Then
    'do nothing
    Else
        ActiveWorkbook.Worksheets.Add(Before:=Sheets(1)).Name = "RECAP"

    End If
End Sub

Function WorksheetExists(SheetName As String, _
                         Optional WhichBook As Workbook) As Boolean
    'from Chip Pearson
    Dim WB As Workbook
    Set WB = IIf(WhichBook Is Nothing, ThisWorkbook, WhichBook)
    On Error Resume Next
    WorksheetExists = CBool(Len(WB.Worksheets(SheetName).Name) > 0)
End Function

 

[arborigene56]

Re : Tableau récapitulatif

Ca m'a l'air pas mal merci beaucoup d'avoir répondu aussi vite !!!