supprimer le texte et garder le nombre

[jeromear]

Bonjour, j'ai une colonne qui apparait comme ceci :
7Emincé volaille
1Ile flottante
3Flan


et je souhaite une colonne qui me donne juste les nombres:
7
1
3

Est ce que qq un peut m'aider?

 

[tototiti2008]

Re : supprimer le texte et garder le nombre

Bonjour jeromear,

si les nombres n'occupent qu'un caractère :

=gauche(A1;1)

si tu veux qu'ils soient considérés comme un nombre :

=gauche(A1;1)*1

par contre si tes nombres dépassent 9, ça complique

 

[vbacrumble]

Re : supprimer le texte et garder le nombre

Bonjour

Formules à utiliser si plus d'un caractère numérique en début de cellule.

en A1: les données alphanumériques


Formule matricielle à valider avec CTRL+SHIFT+ENTER
en b1

=1*STXT(A1;EQUIV(VRAI;ESTNUM(1*STXT(A1;LIGNE($1:$9);1));0);NB(1*STXT(A1;LIGNE($1:$9);1)))

Autre solution avec une formule non matricielle

=RECHERCHE(99^99;--(0&STXT(A1;MIN(TROUVE({0.1.2.3.4.5.6.7.8.9};A1&1234567890));LIGNE(INDIRECT("1:"&NBCAR(A1)+1)))))

A+

 

[tototiti2008]

Re : supprimer le texte et garder le nombre

Bonjour vbacrumble,
Re,

une autre formule matricielle :

=GAUCHE(C1;SOMME(1*ESTNUM(1*STXT(C1;LIGNE($1:$10);1))))

 

[vbacrumble]

Re : supprimer le texte et garder le nombre

Bonjour tototiti2008


J'adopte ta formule sur le champ. 😉

Pour convertir la chaine extraite avect ta formule en format nombre

=[B]1[/B]*GAUCHE(A1;SOMME(1*ESTNUM(1*STXT(A1;LIGNE($1:$10); 1))))

A+

 

[jeromear]

Re : supprimer le texte et garder le nombre

Génial, ça marche nickel!!!

merci beaucoup à tous les bilingues français-Excel et chapeau!

 

[jeromear]

Re : supprimer le texte et garder le nombre

bonjour tototii2008 et vbacrumble,

Une petite remarque :
avec la formule retranscrite en nombre,
=1*GAUCHE(A1;SOMME(1*ESTNUM(1*STXT(A1;LIGNE($1:$10);1))))
si rien n'est inscrit dans la cellule A1, on obtient #VALEUR! dans la cellule B1.

Est il possible d'obtenir la valeur 0 dans B1 si rien n'est inscrit dans A1?
😕

 

[jeanpierre]

Re : supprimer le texte et garder le nombre

Bonsoir jeromear, vbacrumble, tototiti,

Essaie avec : =SI(A1="";0;1*GAUCHE(A1;SOMME(1*ESTNUM(1*STXT(A1;LIGNE($1:$10 );1)))))

Bonne soirée.

Jean-Pierre

 

[jeromear]

Re : supprimer le texte et garder le nombre

Vraiment trop fort sr ce forum, merci bcp Jean Pierre tototiti et vbacrumble
une nuit blanche évitée!!!
bonne fin de soirée

 

[vbacrumble]

Re : supprimer le texte et garder le nombre

Re, Bonsoir jeromear, , tototiti, jeanpierre

Avec cette formule (non matricielle) , si A1 vide, B1 renvoie 0

=RECHERCHE(99^99;--(0&STXT(A1;MIN(TROUVE({0.1.2.3.4.5.6.7.8.9};A1&1234567890));LIGNE(INDIRECT("1:"&NBCAR(A1)+1)))))

A+