XL 2013 Somme suivant un critère unique

[erwan31190]

Bonjour à tous,

Je m'arrache les cheveux pour trouver une formule (hier j'avais mal aux cheveux et aujourd'hui j'en ai plus...).

Je voudrais faire la somme des valeurs d'une colonne (B dans mon fichier) lorsque les valeurs de la colonne A sont comprises entre 168000 et 168999 (dans cette colonne se trouvent des numéros de comptes comptables).
Le résultat doit donc être 55 dans mon exemple.

Merci d'avance pour votre aide.

Erwan

 

[JHA]

Re : Somme suivant un critère unique

Bonjour à tous,

Peut être,

=SOMME.SI.ENS($B$2:$B$16;$A$2:$A$16;">="&168000;$A$2:$A$16;"<="&168999)

ou

=SOMMEPROD(($A$2:$A$16>=168000)*($A$2:$A$16<=168999);$B$2:$B$16)

JHA

 

[CB60]

Re : Somme suivant un critère unique

bonsoir
A tester:

=SOMMEPROD((B2:B16)*(A2:A16>=168000)*(A2:A16<=168999))

 

[excfl]

Re : Somme suivant un critère unique

Bonjour le forum,

=SOMMEPROD((A2:A16>=168000)*(A2:A16<168999)*B2:B16)

 

[Paf]

Re : Somme suivant un critère unique

Bonjour erwan31190, JHA

une solution avec Sommeprod pour ceux qui aurait encore une version XL antérieure à 2007

=SOMMEPROD((A2:A16>=168000)*(A2:A16<=168999)*(B2:B16))

A+

Edit : juste trop tard; bonjour excfl , CB60

 

[erwan31190]

Re : Somme suivant un critère unique

Ça fonctionne !
Merci JHA pour ta rapidité et ton efficacité.
Premier post et réponse obtenue en 10 minutes.
Hummm je vais aimer ce site !
Bonana 2016 comme on dit au Congo

 

[excfl]

Re : Somme suivant un critère unique

Ou :

=SOMME.SI.ENS(B2:B16;A2:A16;">="&"168000";A2:A16;"<="&"168999")

 

[JCGL]

Re : Somme suivant un critère unique

Bonjour à tous,

En D2 : 168
En E2 :

=SOMMEPROD((GAUCHE(A2:A16;3)*1=D2)*B2:B16)

A+ à tous

 

[excfl]

Re : Somme suivant un critère unique

=sommeprod((a2:a16>=168*10^3)*(a2:a16<169*10^3)*(b2:b16))

 

[excfl]

Re : Somme suivant un critère unique

Ou avec un simple somme.si :

=SOMME.SI(A1:A1000;">="&"168000";B1:B1000)-SOMME.SI(A1:A1000;">="&"169000";B1:B1000)