Somme si cellule contient texte spécifique

[Niouf]

Bonjour le Forum,

Je cherche à insérer dans une SOMME.SI.ENS la condition suivante :
Faire la somme si ma plage de cellule contient un texte spécifique.

Je vous ai joint un fichier exemple:
J'ai une formule test dans la cellule jaune, une première SOMME.SI.ENS est présente en fonction de 3 premiers critères. Et j'aimerai ajouter en 4ème critère la condition, SI je trouve "panne" dans la colonne "CommentaireAlea" je fais la somme ...

J'éspère avoir été assez explicite !

Merci d'avance à celui ou celle qui m'aidera 🙂

 

[mutzik]

Re : Somme si cellule contient texte spécifique

bonjour

ajouter
;I4;D : D;"*panne*"
à la fin de ta formule avant le ')' de terminaison

enlever les espaces avant et après le :

 

[Lord Nelson]

Re : Somme si cellule contient texte spécifique

Salut,

Essaies ceci :

=SOMME.SI.ENS(B:B;C:C;M4;D:D;N4;K:K;O4;G:G;"*panne*")

Les * remplacent tous les autres caractères. Donc *panne* signifie "Texte qui contient le mot panne à n'importe quelle position.

A+
H

 

[Niouf]

Re : Somme si cellule contient texte spécifique

Merci messieurs,

Cela fonctionne nickel de cette façon !

Est il possible de renseigner une cellule avec le texte à rechercher ?
Je remplacerai mon "*panne*" dans ma formule par le texte situé en cellulle D10.
De cette façon je n'aurai que cette cellule à modifier pour faire évoluer le résultat affiché par ma formule .

Vous voyez ou je veux en venir ?

 

[mutzik]

Re : Somme si cellule contient texte spécifique

re,

ben oui, c bien sur
si tu mets le mot cherché en N5, par ex, dans ta condition tu mets
à la place de "*panne*"
"*"&N5&"*"

 

[Niouf]

Re : Somme si cellule contient texte spécifique

PARFAIT !

Merci 🙂

 

[syldo]

Bonjour,

Je ré-ouvre cette discussion car j'ai un souci... Voici le fichier en PJ. J'ai appliqué sur la 1ère feuille la formule mentionnée plus haud (celle proposée par mutzik), mais cela ne fonctionne pas. Pourquoi ?

 

[Jocelyn]

Bonjour le Forum,
Bonjour syldo, Mutzik, Lord Nelson, Niouf,

Tu n'as pas utilisé la formule proposée mais une formule SOMME(SI()) matricielle

alors tu peux l'écrire de cette façon en validant matriciellement

=SOMME(SI((EXPORT!$X:$X=1)*(ESTNUM(CHERCHE(A2;EXPORT!$G:$G)));1))

ou bien sans le besoin de la validation matricielle

=SOMMEPROD((EXPORT!$X:$X=1)*(ESTNUM(CHERCHE(A2;EXPORT!$G:$G))))

Cordialement

 

[syldo]

Super, merci !

Et si je veux rajouter une condition, ça donnerait ça ?

=SOMME(SI(ET(EXPORT!$T:$T=RESUME!B8;EXPORT!$X:$X=1)*(ESTNUM(CHERCHE(A7;EXPORT!$G:$G)));1))

Pour compter le nombre de place qui répondent à toutes ces conditions :
- à 4 € dans la colonne T (feuille EXPORT)
- avec un 1 dans la colonne X
- et avec le titre A7 (feuille résumé)

Merci de votre aide...

 

[Jocelyn]

re

si tu veux ajouter une condition ca donne

=SOMME(SI((EXPORT!$T:$T=RESUME!B8)*(EXPORT!$X:$X=1)*(ESTNUM(CHERCHE(A7;EXPORT!$G:$G)));1))

Cordialement

 

[syldo]

Merci...

Il y a quelque chose que je ne dois pas faire correctement car cela ne fonctionne pas vrament (seulement une partie fonctionne, mais les 3 conditions ne sont pas forcément remplies et donc le compte n'est pas bon)...

 

[Jocelyn]

re

revoila ton fichier avec explication

cordialement

 

[syldo]

Un énorme merci !
C'est parfait.

Cordialement,

 

[syldo]

Oups, j’ai crié victoire un tout petit peu trop vite.
Je voulais ajouter cette partie "*"&cell&"*" pour que la recherche se fasse sur une partie du mot... mais ça n renvoie rien.

J'ai fait un test sur la cellule en vert dans le fichier. Qu'est ce qui bloque ?

 

[JHA]

Bonjour à tous,

Le problème vient que tu as des chiffres comparés à du texte.
Soit en colonne "B" de l'onglet "RESUME" tu écris "4.60" ou tu utilises la fonction substitue()

=SOMME(SI((EXPORT!$T:$T=SUBSTITUE(TEXTE($B13;"0,00");",";"."))*(EXPORT!$X:$X=1)*(ESTNUM(CHERCHE("*"&$A$12&"*";EXPORT!$G:$G)));1))

Validation matricielle

Je pense que tu ne dois pas laisser le calcul sur la totalité des lignes (ex:EXPORT!$T:$T), si tu veux que le calcul soit plus rapide soit tu nommes tes plages ou tu les figes (exEXPORT!$T2:$T100).


JHA