Somme de colonne qui contiennent un mot

[greg0852]

bonjour,

je cherche en vain une solution, pour compter le nombre de colonne qui contiennent une ou plusieurs fois un mots.
le problème c'est qu'il doit ne compter qu'une seule fois le colonne, qu'elle contiennent 1 ou 10 fois le mot recherché.
si quelqu'un a une piste, merci d'avance

 

[CISCO]

Re : Somme de colonne qui contiennent un mot

Bonsoir

Pour être sûr de répondre correctement à ta question, pourrais tu nous mettre un fichier exemple en pièce jointe.

@ plus

 

[greg0852]

Re : Somme de colonne qui contiennent un mot

Re bonsoir
voilà un fichier d'exemple
en bref ce que je veux c'est qu'il m'indique :
Le nombre de colonne ou il y a "AR" > c'est à dire 3
ou alors CG > c'est a dire 2

 

[Philippe68]

Re : Somme de colonne qui contiennent un mot

Bonsoir, re CISCO,

on en revient à la fonction NB.SI non CISCO ?

 

[greg0852]

Re : Somme de colonne qui contiennent un mot

NB.SI va me renvoyer le nombre total de AR ou CG.
à moins que je ne me trompe

 

[Philippe68]

Re : Somme de colonne qui contiennent un mot

ha oui, faut que je remette mes lunettes 😱

 

[CISCO]

Re : Somme de colonne qui contiennent un mot

Bonsoir à tous, bonsoir Philippe68 et greg0852

Une possibilité parmi d'autres, avec une formule matricielle à valider avec ctrl+maj +entrer :

SI(SOMME((A3:A9=E3)*1)>=1;1;0)+SI(SOMME((B3:B9=E3)*1)>=1;1;0)+SI(SOMME((C3:C9=E3)*1)>=1;1;0)

ou encore, cette fois ci avec une formule non matricielle

(NB.SI(A3:A9;E3)>0)+(NB.SI(B3:B9;E3)>0)+(NB.SI(C3:C9;E3)>0)

en mettant en E3 le mot


Si tu as beaucoup de colonnes, il faudra trouver une autre méthode.
@ plus

 

[ROGER2327]

Re : Somme de colonne qui contiennent un mot

Bonjour à tous.

Avec le mot à rechercher en E3, avec la plage de recherche A3:C16, essayez :

=SOMME(--(PRODUITMAT(TRANSPOSE(-($A$3:$C$16=E3));SIGNE(LIGNE($3:$16)))<0))

(Formule à valider par Ctrl Maj Entrée.)​

ROGER2327
#5399

Mercredi 25 Décervelage 139 (Saint Petiot, expert - fête Suprême Quarte)
2 Pluviôse An CCXX, 0,9092h - mousse
2012-W03-7T02:10:55Z

 

[JNP]

Re : Somme de colonne qui contiennent un mot

Bonjour le fil 🙂,
Une proposition adaptable au nombre de colonnes souhaitées (il suffit de modifier LIGNE($1:$3)-1)) avec la valeur cherchée en E3

=SOMME(SI(NB.SI(DECALER(A3:A9;;LIGNE($1:$3)-1);E3)>0;1;0))

formule matricielle à valider avec Ctrl+Maj+Enter 😛
Bon dimanche 😎

 

[greg0852]

Re : Somme de colonne qui contiennent un mot

Bonsoir à tous, bonsoir Philippe68 et greg0852

Une possibilité parmi d'autres, avec une formule matricielle à valider avec ctrl+maj +entrer :

SI(SOMME((A3:A9=E3)*1)>=1;1;0)+SI(SOMME((B3:B9=E3)*1)>=1;1;0)+SI(SOMME((C3:C9=E3)*1)>=1;1;0)

ou encore, cette fois ci avec une formule non matricielle

(NB.SI(A3:A9;E3)>0)+(NB.SI(B3:B9;E3)>0)+(NB.SI(C3:C9;E3)>0)

en mettant en E3 le mot


Si tu as beaucoup de colonnes, il faudra trouver une autre méthode.
@ plus

Bonjour à tous,
merci pour toutes vos réponses.
la 2° solution de Cisco fonctionne nickel.
mais comme je dois l'appliquer sur 62 colonnes, ni aurait-il pas une solution pour la simplifier.
merci d'avance.

 

[CISCO]

Re : Somme de colonne qui contiennent un mot

Bonjour

Roger2327 et JNP (que je salue au passage) t'ont proposé, ci-dessus, des formules matricielles (à valider avec ctrl+maj+entrer) fonctionnnant pour un nombre plus important de colonnes (à adapter si besoin est).

@ plus

 

[greg0852]

Re : Somme de colonne qui contiennent un mot

Merci de ta réponse,
mais celle de Roger2327 me renvoi un défaut de valeur et celle de JNP me renvoi toujours le chiffre 1
il n'y a que la tienne qui fonctionne.
ou alors c'est moi qui suis trop mauvais pour les appliquer correctement 🙂
@ plus

 

[JNP]

Re : Somme de colonne qui contiennent un mot

Re 🙂,
Donc pour 62 colonnes, en admettant une centaine de lignes et pour trouver AR :

=SOMME(SI(NB.SI(DECALER(A2:A100;;LIGNE($1:$62)-1);"AR")>0;1;0))

mais surtout en n'oubliant pas de valider en Ctrl+Maj+Enter 🙄...
Bonne suite 😎

 

[CISCO]

Re : Somme de colonne qui contiennent un mot

Rebonjour

Cf. en pièce jointe (Il faut valider la formule en appuyant simultanément sur les trois touches ctrl+maj+entrer, ce qui fait apparaitre les accolades devant et derrière la formule).

Une petite variante de la formule proposée par JNP

SOMME((NB.SI(DECALER(A3:A9;;COLONNE(A3:C3)-1);E3)>0)*1)

DECALER(A3:A9;;COLONNE(A3:C3)-1) permet de sélectionner les unes après les autres chacune des colonnes : A3:A9, puis B3:B9 puis C3:C9.

NB.SI(......;E3) compte le nombre de E3 dans chacune des colonnes
NB.SI(DECALER(A3:A9;;COLONNE(A3:C3)-1);E3)>0 renvoit VRAI lorsque E3 est au moins une fois dans la colonne testée
(NB.SI(DECALER(A3:A9;;COLONNE(A3:C3)-1);E3)>0)*1 remplace ces VRAI par des 1
et SOMME additionne ces 1.

Passes par l'onglet "formules", puis par "évaluation de formule" pour voir les calculs intermédiaires. Ne soit pas surpris par les messages #valeur provoqués par la fonction NB.SI., les calculs suivants s'afficheront qu'en même.


@ plus

 

[greg0852]

Re : Somme de colonne qui contiennent un mot

ok merci je regarde