XL 2016 Retirer + a une série de nombre

Staple1600

XLDnaute Barbatruc

• 27 Mai 2023

• #2

Bonjour @cmdavid, le fil

Fonctionne sur Office 365
=FRACTIONNER.TEXTE(B3;;"+")

NB: Je ne sais plus si cette fonction est disponible sur Excel 2016

 

Vote positif 0 Vote négatif

C

cmdavid

XLDnaute Occasionnel

• 27 Mai 2023

• #3

Bonjour Staple1600,
non la formule Fractionner ne fonctionne pas sur Excel 2016,

 

Vote positif 0 Vote négatif

mapomme

XLDnaute Barbatruc

Supporter XLD

• 27 Mai 2023

• #4

Bonjour à tous,

Formule en C3 à recopier vers le bas :

VB:

=SIERREUR(--STXT($B$3;CHERCHE("[";SUBSTITUE("+"&$B$3&"+";"+";"[";LIGNES($3:3)));CHERCHE("]";SUBSTITUE("+"&$B$3&"+";"+";"]";1+LIGNES($3:3)))-CHERCHE("[";SUBSTITUE("+"&$B$3&"+";"+";"[";LIGNES($3:3)))-1);"")

 

Pièces jointes

• cmdavid- Nombre sans plus- v1.xlsx

  9.5 KB · Affichages: 3

Vote positif 0 Vote négatif

Staple1600

XLDnaute Barbatruc

• 27 Mai 2023

• #5

Re

Décidemment @mapomme a mangé du @lion 😉
Avec une colonne intermédiaire
Et cette formule en C3 (à recopier vers le bas)
=SUPPRESPACE(STXT(SUBSTITUE($B$3;"+";REPT(" ";NBCAR($B$3)));($D3-1)*NBCAR($B$3)+1;NBCAR($B$3)))


NB: Si la vue de colonne intermédiaire gêne, on peut lui appliquer ce format : ;;;
(pour la masquer)

 

Dernière édition: 27 Mai 2023

Vote positif 0 Vote négatif

sylvanu

XLDnaute Barbatruc

Supporter XLD

• 27 Mai 2023

• #6

Bonjour Cmdavid, Mapomme, Staple,
Ou encore avec cette petite fonction perso en VBA :

VB:

Function Découpe(C$, N)
    On Error GoTo Fin: Découpe = ""
    Découpe = Val(Split(C, "+")(N - 1))
Fin:
End Function

 

Pièces jointes

• Nombre sans plus.xlsm

  13.8 KB · Affichages: 2

Vote positif 0 Vote négatif

Staple1600

XLDnaute Barbatruc

• 27 Mai 2023

• #7

Bonjour @sylvanu

@cmdavid
Je joue à Madame Irma
Au cas où, le but recherché serait de sommer les nombres contenus en B3
Cette formule le fera 😉
=SOMMEPROD(--SUPPRESPACE(STXT(SUBSTITUE(B3;"+";REPT(" ";99));(LIGNE($A$1:INDEX(A:A;NBCAR(B3)-NBCAR(SUBSTITUE(B3;"+";""))+1))-1)*99+1;99)))
Avec cette formule en B5, j'obtiens : 542
(résultat identique à la somme de C3:C10, affichée en C11))

NB: Pour sommer C3:C10, j'ai modifié ainsi ma 1ère formule en (C3)
=SIERREUR(SUPPRESPACE(STXT(SUBSTITUE($B$3;"+";REPT(" ";NBCAR($B$3)));($D3-1)*NBCAR($B$3)+1;NBCAR($B$3)))*1;"")

 

Dernière édition: 27 Mai 2023

Vote positif 0 Vote négatif

Solution

C

cmdavid

XLDnaute Occasionnel

• 27 Mai 2023

• #8

Bonjour à tous,
Un grand merci pour votre aide. Maintenant je dois choisir parmi toutes vos solutions.
Cordialement,

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 27 Mai 2023

• #9

Bonjour cmdavid, JM, mapomme, sylvanu,

Une solution un peu plus soft que celle de mapomme :

Code:

=SIERREUR(--STXT(X;PETITE.VALEUR(pos;LIGNE(C1))+1;PETITE.VALEUR(pos;LIGNE(C1)+1)-1-PETITE.VALEUR(pos;LIGNE(C1)));"")

A+

 

Pièces jointes

• Nombre sans plus.xlsx

  10.4 KB · Affichages: 1

Vote positif 0 Vote négatif

C

cmdavid

XLDnaute Occasionnel

• 28 Mai 2023

• #10

job75 à dit:

Bonjour cmdavid, JM, mapomme, sylvanu,

Une solution un peu plus soft que celle de mapomme :

Code:

=SIERREUR(--STXT(X;PETITE.VALEUR(pos;LIGNE(C1))+1;PETITE.VALEUR(pos;LIGNE(C1)+1)-1-PETITE.VALEUR(pos;LIGNE(C1)));"")

A+

Cliquez pour agrandir...

Merci

 

Vote positif 0 Vote négatif