Requête et récupération données HTML

[porcinet82]

Bonjour à tous,

Même si je ne suis plus très présent sur le forum, je vais avoir besoin de la communauté pour un petit problème que j'ai du mal à résoudre malgré mes recherches. J'espère donc que vous pourrez m'aider. 🙂

Brièvement ce que j'aimerai arriver a faire, c'est paramétrer des champs (textbox et liste déroulante) sur une page html puis exécuter la requête pour ensuite copier le résultat dans mon classeur excel.
J'arrive à faire cette dernière partie (le copié/collé) et à naviguer entre différentes pages (en récupérant les liens attribués a des images/boutons) mais même en connaissant le noms des différents champs sur lequel il faudrait que j'agisse, je n'arrive pas trouver la syntaxe pour y parvenir.

Le site internet est le suivant : Application Epreuves Individuelles Grand Public
Je voudrai donc agir sur les champs "Type", "Compétition en cours", "débutant dans les X mois suivants" et "Ligue" puis exécuter la requête.
Dans le code ci-dessous, j'ai un maigre début avec le chargement de la page et le "chemin" vers les champs ci-dessus, mais je bloque sur le paramétrage.

Sub Test()Dim IE As InternetExplorer
Dim maPageHtml As HTMLDocument
Dim maTable As IHTMLTable


Set IE = CreateObject("InternetExplorer.Application")
IE.Visible = True
IE.navigate "http://www.ei.applipub-fft.fr/eipublic/competitionRecherche.do?dispatch=afficher"
Do Until IE.readyState = READYSTATE_COMPLETE
    DoEvents
Loop


Set maPageHtml = IE.document


'maPageHtml.forms.Item(1).elements.Item(3) 'hoi_atp
'maPageHtml.forms.Item(1).elements.Item(4) 'dtdate
'maPageHtml.forms.Item(1).elements.Item(5) 'mois
'maPageHtml.forms.Item(1).elements.Item(8) 'lig_cod_1
End Sub

J'espère que ma demande est assez claire et je remercie par avance les personnes qui prendront un peu de temps pour jeter un oeil à mon soucis.
Et en espérant que ça vous inspire... 😉

@+

 

[Mytå]

Re : Requête et récupération données HTML

Salut le forum

Essaye comme ceci (Url du site à adapter)

Sub Test()
Dim IE As InternetExplorer
Dim maPageHtml As HTMLDocument
Dim maTable As IHTMLTable
Dim Elem As Object


Set IE = CreateObject("InternetExplorer.Application")
IE.Visible = True
IE.navigate "http://www.lesite.com"
Do Until IE.readyState = READYSTATE_COMPLETE
    DoEvents
Loop


Set maPageHtml = IE.document


Set Elem = maPageHtml.getElementsByName("hoi_atp")
Elem.Item(0).Value = "C"
DoEvents

Set Elem = maPageHtml.getElementsByName("dtdate")
Elem.Item(0).Value = "01/02/2013"
DoEvents

Set Elem = maPageHtml.getElementsByName("mois")
Elem.Item(0).Value = 6
DoEvents

Set Elem = maPageHtml.getElementsByName("lig_cno_1")
Elem.Item(0).Value = "01" 'Alsace
DoEvents

Set Elem = maPageHtml.getElementsByTagName("input")
Elem.Item(15).Click

End Sub

Mytå

 

[porcinet82]

Re : Requête et récupération données HTML

Hello Mytå,

Un grand merci à toi pour ta solution qui fonctionne parfaitement !!! 😀
Au plaisir.

@+