XL 2016 remplacement de Table.AddRankColumn sous Excel 2016

AtTheOne

XLDnaute Accro

Supporter XLD

• 27 Mars 2023

• #2

Bonsoir à toutes & à tous,
Bonsoir @keks038

Une solution sans VBA ni PowerQuery mais avec 4 noms définis.

Nom	Définition en ligne 3	Objet
Lgn_Entête	=LIGNE(INDIRECT(Suivi_Bis!$A3&"[#En-têtes]"))	Ligne des entêtes du tableau correspondant à la cellule A3
Evt_Type	=INDIRECT(Suivi_Bis!$A3&"[Type evt]")	colonne "Type evt" du tableau correspondant à la cellule A3
Evt_Date	=INDIRECT(Suivi_Bis!$A3&"[Date premiere occurrence]")	colonne "Date première occurrence" du tableau correspondant à la cellule A3
Evt_Résolu	=INDIRECT(Suivi_Bis!$A3&"[Résolu]")	colonne "Résolu" du tableau correspondant à la cellule A3

Le nom des tableaux scrutés doit respecter la règle de ton exemple (T_Evt suivi d'un N° : T_Evt1, T_Evt2 ...)

Le tableau du fichier joint s'arrête volontairement à T_Evt6, tu peux le tirer vers le bas :

EDIT : Oups ! fonction Max.si.ens non supportée par excel 2016 et formules matricielles à valider par CTRL MAJ ENTREE (implicites avec ma version 2021)​

Je change le fichier et j'ajoute 3 autres noms pour remplacer les formules matricielles dans les formule du tableau de suivi :​

EDIT2 ; Re-Oups! correction : colonnes en absolu dans la définition des noms:​

Noms	Définition en ligne 2	Objet
Nb_Evt	=GRANDE.VALEUR(NB.SI.ENS(Evt_Type;Evt_Type;Evt_Résolu;"<>"&"OUI")*(Evt_Résolu<>"OUI");SOMME.SI(Suivi!$A$1:$A1;Suivi!A1;Suivi!$C$1:$C1)+1)	Nbre d'événements comptés
Evt_Top3	=SI(NB.SI(Suivi!$A$2:$A2;Suivi!$A2)=1;INDEX(Evt_Type;MIN(SI(NB.SI.ENS(Evt_Type;Evt_Type;Evt_Résolu;"<>OUI")=Suivi!C2;LIGNE(Evt_Type)-Lgn_Entête;LIGNES(Evt_Type)+1)));INDEX(Evt_Type;MIN(SI(ESTNA(EQUIV(Evt_Type;DECALER(Suivi!$B1;-1*(NB.SI(Suivi!$A$2:$A2;Suivi!$A2)-2);0;NB.SI(Suivi!$A$2:$A2;Suivi!$A2)-1;1);0))*NB.SI.ENS(Evt_Type;Evt_Type;Evt_Résolu;"<>OUI")=Suivi!C2;LIGNE(Evt_Type)-Lgn_Entête;LIGNES(Evt_Type)+1))))	Libellé de l'événement du top3
Der_Date	=MAX(SI((Evt_Type=Suivi!$B2)*(Evt_Résolu<>"OUI");Evt_Date;0))	Dernière date correspondant

Voir la pièce jointe

Bon courage

 

Pièces jointes

• Top3 Evts NON & NR .xlsx

  60.9 KB · Affichages: 0

Dernière édition: 28 Mars 2023

Vote positif 0 Vote négatif

Solution

K

keks038

XLDnaute Nouveau

• 28 Mars 2023

• #3

Bonjour @AtTheOne,
wow merci beaucoup, c'est assez incroyable !
Je ne connaissais pas cette technique des noms définis !
ça fonctionne parfaitement avec 2016 et ça remplit tout à fait son usage.
Merci beaucoup !!

 

Vote positif 0 Vote négatif

AtTheOne

XLDnaute Accro

Supporter XLD

• 28 Mars 2023

• #4

Bonjour à toutes & à tous,
Bonjour @keks038

AtTheOne à dit:

Le nom des tableaux scrutés doit respecter la règle de ton exemple (T_Evt suivi d'un N° : T_Evt1, T_Evt2 ...)

Cliquez pour agrandir...

Si tu dois modifier cette règle, pour utiliser un nom de tableau plus explicite que "T_Evt", tu n'as qu'à changer la formule en colonne A :

Enrichi (BBcode):

="T_Evt"&ENT((LIGNE()-LIGNE(Tb_Suivi[#En-têtes])-1)/3)+1

Si tu veux afficher un nombre d'événements différent de 3, remplace le 3 dans la formule par le nombre souhaité :

Enrichi (BBcode):

="T_Evt"&ENT((LIGNE()-LIGNE(Tb_Suivi[#En-têtes])-1)/3)+1

A bientôt

 

Vote positif 0 Vote négatif

K

keks038

XLDnaute Nouveau

• 28 Mars 2023

• #5

Re @AtTheOne,
Merci beaucoup pour ces infos complémentaires.
Est ce que tu sais si je peux utiliser un nom de tableau différent pour chaque page ?
Si c'est trop compliqué j'ai la solution alternative de rajouter une colonne dans ma feuille suivi et cela fera tres bien le travail !
Merci encore mille fois pour ton aide.
A bientôt
Keven

 

Vote positif 0 Vote négatif

AtTheOne

XLDnaute Accro

Supporter XLD

• 28 Mars 2023

• #6

Re-Bonjour,

keks038 à dit:

Est ce que tu sais si je peux utiliser un nom de tableau différent pour chaque page ?

Cliquez pour agrandir...

Le mieux pour garder l'automatisation en colonne 1 c'est d'avoir des noms de tableau numérotés (MonNouveauNom_1, MonNouveauNom_2 etc..) et de changer la formule en colonne A :

Enrichi (BBcode):

="MonNouveauNom_"&ENT((LIGNE()-LIGNE(Tb_Suivi[#En-têtes])-1)/3)+1

ainsi les formules s'adapteront en rallongeant le tableau.
Sinon, tu mets toi-même le nom des tableaux dans la colonne A et ça fonctionnera.

 

Vote positif 0 Vote négatif