XL 2013 récupérer les dates dans une chaine (formule excel)

[patricktoulon]

Bonjour à tous
je vais commencer a me faire un recueil d'exemple de formule excel pour le texte

aujourd'hui je cherche une formule qui pourrait me donner la Nieme( de 1 à x) date dans une chaine
à l'heure actuelle j'ai la première simplement avec STXT ET CHERCHE

=STXT(A1;CHERCHE("??/??/????";A1;1);10)

j'aimerais trouver une formule qui me permette d'avoir la 2d , la 3eme etc...

 

[patricktoulon]

re
bizarre chez moi çà passe pas

 

[AtTheOne]

RE
Voir le post #14 (EDIT en gros)

 

[AtTheOne]

La formule matricielle se propage bien si tu valides la 1ère par CTRL MAJ ENTREE
Mais tu peux aussi la coller dans un nom pour éviter le problème (les noms sont toujours interprétés comme des formules matricielles)

 

[patricktoulon]

re
ok en matriciel ça repart
je sais pas pourquoi cette cellule n’était pas valider en matriciel et les deux autres oui

nikel et de une formule qui marche

 

[mapomme]

Bonjour à tous ,

Comme assez régulièrement, je viens sans doute après la bataille.
Je précise que je n'ai regardé aucune formule précédente de ce fil ; j'espère que ma formule ne fait pas double-emploi avec une formule déjà publiée . Je ne voudrais froisser personne.

C'est une formule matricielle. Le texte est en A2, l'occurrence N à trouver en A6.

Voici la formule en A10 :
=SIERREUR(STXT($A$2;PETITE.VALEUR(SI(ESTNUM(DATEVAL(SI(ESTNUM(--STXT($A$2;LIGNE($2:$258);2)) * (STXT($A$2;LIGNE($2:$258)+2;1)="/")* ESTNUM(--STXT($A$2;LIGNE($2:$258)+3;2)) * (STXT($A$2;LIGNE($2:$258)+5;1)="/") * ESTNUM(--STXT($A$2;LIGNE($2:$258)+6;4));STXT($A$2;LIGNE($2:$258);10);"")));LIGNE($2:$258);"");A6);10);"")

Notez :

• on fait une vérification de la date. C'est pourquoi, dans l'exemple, la formule ne trouvera que 3 occurrences (29/02/1999 n'étant pas une date correcte, ce n'est pas une occurence).
• la valeur 258 peut-être augmentée ou diminuée. Cette valeur doit être supérieure au nombre de caractères possibles du texte
• les dates doivent être au format 10 caractères : jj/mm/aaaa

 

[patricktoulon]

re
excellent @mapomme avec la verif en plus

 

[job75]

Bonsoir à tous,

Une formule matricielle très simple en A10 :

=STXT(A2;PETITE.VALEUR(SI(ESTNUM(--STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));10));LIGNE(INDIRECT("1:"&NBCAR(A2))));A6);10)

A+

 

[patricktoulon]

re
bonsoir @job75
il faut ajouter le outoffcount car si je demande la 4 alors qu'il y en a que 3 , j'ai "#NOMBRE"
une gestion globale de l'erreur

=SIERREUR(STXT(A2;PETITE.VALEUR(SI(ESTNUM(--STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));10));LIGNE(INDIRECT("1:"&NBCAR(A2))));A6);10);"OutOffCount")

 

[patricktoulon]

re
le grand gagnant c'est @job75 avec sa formule simplissime+gestion erreur
bravo à tous

 

[JHA]

Bonjour à tous,

Je me permets une petite remarque.
J'ai essayé la formule de job75 que je félicite avec des espaces dans la phrase et cela ne donne pas satisfaction. J'ai donc enlevé les espaces avec la fonction substitue.

=STXT(SUBSTITUE(A2;" ";"");PETITE.VALEUR(SI(ESTNUM(--STXT(SUBSTITUE(A2;" ";"");LIGNE(INDIRECT("1:"&NBCAR(SUBSTITUE(A2;" ";""))));10));LIGNE(INDIRECT("1:"&NBCAR(SUBSTITUE(A2;" ";"")))));A6);10)

JHA

 

[patricktoulon]

re
Bonjour @JHA
plutôt que faire un substitue dans tout les segments des antécédents
on peut faire un SUPPRESPACE global

=SUPPRESPACE(SIERREUR(STXT(A2;PETITE.VALEUR(SI(ESTNUM(--STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));10));LIGNE(INDIRECT("1:"&NBCAR(A2))));A6);10);"-"))

 

[JHA]

Bonjour à tous,

plutôt que faire un substitue dans tout les segments des antécédents
Cela ne fonctionne pas

JHA

 

[patricktoulon]

re
ha bon ?
bon ben on garde la tienne alors puisqu'elle fonctionne sur les deux
allez une dernière ligne droite
comment faire pour la rendre étirable vers le bas ou vers la droite
j'ai essayé ligne(A1) à la place de A6 mais ça ne fonctionne pas

 

[job75]

Bonjour à tous,

Eh oui si l'on insère un espace après "1999" ma formule renverra "9/02/1999 "

Pourquoi serait-ce gênant ?

De même #NOMBRE! n'est pas gênant, SIERREUR est bien inutile.

A+

 

[AtTheOne]

Bonjour à toutes & à tous, @patricktoulon, @mapomme , @job75, @JHA
Un petit bug dans la formule de @job75, s'il y a une suite de 10 chiffres ou plus dans la chaîne la formule extrait aussi cette suite ...

Mais c'est quand bien plus concis que ma formule !