Recherchev selon 2 critères

[Vilain]

Bonjour à tous,

Je fais appel aux pros de la formule.
Je cherche à faire une recherchev selon 2 critères. Je m'explique. J'ai un fichier avec un onglet base de donnée. Dans cette bdd, j'ai en colonne le code rubrique, la date et le montant. Je voudrais faire une recherchev qui me ramène le montant par mois de chaque rubrique. Je joins un fichier pour plus de clarté.

D'avance merci pour votre aide et n'hésitez pas à me demander de préciser si j'ai pas été clair ! 🙂

 

[mth]

Re : Recherchev selon 2 critères

Bonjour,

Un essai avec cette formule en C3 et copiée sur le reste du tableau

=SOMMEPROD((Feuil2!$B$3:$B$19=Feuil1!$B3)*(Feuil2!$E$3:$E$19=Feuil1!C$2)*(Feuil2!$F$3:$F$19))

Ceci dit, un tableau croisé dynamique semble très adapté, j'en ai glissé un en PJ.

Bon après-midi,

mth

 

[Tibo]

Re : Recherchev selon 2 critères

Bonjour,

Une tentative avec cette formule en C3 :

=SOMMEPROD((TEXTE(Feuil2!$E$3:$E$18;"mmaa")=TEXTE(C$2;"mmaa"))*(Feuil2!$B$3:$B$18=$B3)*Feuil2!$F$3:$F$18)

à recopier vers le bas et vers la droite

@+

 

[Vilain]

Re : Recherchev selon 2 critères

J'avais pensé au tableau croisé dynamique mais je ne peux pas l'appliquer à mon fichier.
Je vais donc utiliser ta formule, mth, qui semble adaptée.

Merci pour votre rapidité et pour la qualité de vos réponses 🙂

 

[gnina1973]

Re : Recherchev selon 2 critères

Bonjour à tous

Je te propose d'utiliser la fonction matricielle index+equiv combiné avec SIERREUR , pour ne faire apparaître les N#A


=SIERREUR(INDEX(Feuil2!$F$3:$F$18;EQUIV($B$4&" "&C2;Feuil2!$B$3:$B$18&" "&Feuil2!$E$3:$E$18;0));"")

Bien à vous tous !!!

 

[Vilain]

Re : Recherchev selon 2 critères

Bonjour à tous et merci pour les solutions proposées.
Un petit problème subsiste : ma base de données ne fait pas toujours le même nombre de ligne. Hors, sauf erreur de ma part, il n'est pas possible d'utiliser la formule de mth =SOMMEPROD((Feuil2!$B$3:$B$19=Feuil1!$B3)*(Feuil2!$E$3:$E$19=Feuil1!C$2)*(Feuil2!$F$3:$F$19)) sur l'ensemble d'une colonne plutôt que sur une plage de données.
Existe-t-il une solution (et j'aimerais éviter les macro) pour l'adapter à la "taille" de ma base de données ?

Encore une fois, merci à tous pour votre disponibilité et votre réactivité. 🙂

 

[mth]

Re : Recherchev selon 2 critères

Bonjour à tous 🙂

Il faudrait se baser sur la colonne la plus longue, est-ce toujours la même où faudrait-il la calculer?

@+

mth

 

[Vilain]

Re : Recherchev selon 2 critères

Toutes les colonnes font la même longueur à l'exception de la colonne A qui fait une ligne de plus que les autres (mais si c'est un problème, je peux supprimer cette dernière ligne)
Merci pour ton aide 🙂

 

[mth]

Re : Recherchev selon 2 critères

re 🙂

Sourire... je viens de te faire une réponse idiote 🙂
Donc je reprends ...
Si tu transformes ta base en tableau en utilisant l'outil TABLEAU d'Excel, il suffit d'y faire référence dans ta formule et peu importe le nombre de lignes, tout étant géré par le "TABLEAU" qui se redimensionne automatiquement à chaque ligne ajoutée.

Sélectionne ta base, puis dans le ruban onglet Accueil choisie "Mettre sous forme de tableau".

La formule devient:

=SOMMEPROD((Tableau1[C Rubrique P]=Feuil1!$B3)*(Tableau1[D Rubrique P]=Feuil1!C$2);(Tableau1[Montant]))

Exemple en PJ,

Bien à toi,

mth

 

[mth]

Re : Recherchev selon 2 critères

re 🙂

Tu peux aussi nommer tes zones, la formule sera encore plus lisible, par exemple:

=SOMMEPROD((LigneSalaire=Feuil1!$B3)*(D_Rubrique_P=Feuil1!C$2)*(Montant))

toutes les zones nommées prenant la taille de la plus grande colonne (B dans ton fichier), par exemple pour Montant:

=DECALER(Feuil2!$F$3;;;NBVAL(Feuil2!$B:$B)-1)

Vois en PJ si cela te va,

Bien à toi,

mth

 

[Vilain]

Re : Recherchev selon 2 critères

Merci pour cette précieuse aide qui marche parfaitement dans mon fichier d'exemple, mais qui évidemment me pose problème dans "la vie réelle". 😉
Je ne comprend pas pourquoi cela change la manière de rédiger la fonction sommeprod (la première fois, tu as multiplié tout les arguments alors que dans la "nouvelle formule", il y a un point virgule entre les deux derniers...).
De plus, je ne connaissais pas ce système de "TABLEAU" et me pose une question bête : comment tu rédiges ? Je veux dire par la est ce que tu écrit tout ou tu cliques comme une formule "classique" ?

Encore merci pour ta patience et tes explications 🙂


Edit : Je n'ai pas vu ta dernière réponse, trop plongé dans ton fichier. J'essaie ça demain et reviendrai vers toi en cas de galère

 

[mth]

Re : Recherchev selon 2 critères

re 🙂

Effectivement je te laisse voir la dernière proposition, peut-être plus simple.

Ceci dit pour répondre à tes questions, le ; à la place du *, c'était juste un exercice de style, en effet si par hasard tu as tu texte quelque part dans le champ montant, SOMMEPROD() renvoie #VALEUR!, ce qui n'est pas le cas quand on remplace le * par ;

Pour les formules, oui tu peux tout à fait saisir comme une formule normale.
Un peu fastidieux à la mimine, donc sous 2007 dans le bouton Office, menu "options Excel", onglet "Formules" tu peux cocher la case "Utiliser les noms de tableaux dans les formules".
Ainsi, quand tu feras référence à un tableau en sélectionnant tes cellules avec la souris, Excel traduira tout seul.

Très bonne soirée Gillus et à bientôt,

mth

 

[Vilain]

Re : Recherchev selon 2 critères

Décidement, cette méthode ne doit pas être pour moi, je n'y arrive vraiment pas. Si quelqu'un se sent de m'aider avec un "pas à pas"...
D'avance merci

 

[Vilain]

Re : Recherchev selon 2 critères

Après bataille, je suis arrivé à faire fonctionner la formule mais je ne parviens pas à la tirer sur la droite (cela décalle la sélection).
Comment figer la colonne testée grâce à l'outil "tableau" ?

Edit : Mission finalement réussie 🙂