RECHERCHEV avec NBCAR dans la table matrice

[joel8301]

Bonjour à tous,

Je recherche une formule et je suis un peu bloqué.
En fait ce que je veux faire c'est,
A1 = Credit Agricole B1 = FORMULE M1 = Credit Agricole SA N1 = Banque

Je voudrais faire une RECHERCHEV du type =RECHERCHEV(A1;gauche($M:$N;nbcar(A1));2;FAUX)

Cette formule devrait me sortir le résultat Banque, car dans la Table matrice j'ai limité la recherche au nombre de caractère composé par la Valeur cherchée en A1.

Une idée ? car ça marche pas et je coince ...

Merci.

Joël

 

[R@chid]

Re : RECHERCHEV avec NBCAR dans la table matrice

Bonsoir,
sans fichier exemple, on ne peut pas voir ce que tu veux obtenir.


@ + +

 

[joel8301]

Re : RECHERCHEV avec NBCAR dans la table matrice

Bonsoir R@chid,

Voilà un fichier pour exemple.

Merci pour ce que tu pourras faire.

Joël

 

[job75]

Re : RECHERCHEV avec NBCAR dans la table matrice

Bonsoir joel8301, R@chid,

Utiliser l'astérisque * (caractère générique) :

=RECHERCHEV(A1&"*";M:N;2;FAUX)

Bonne nuit.

 

[joel8301]

Re : RECHERCHEV avec NBCAR dans la table matrice

Re Job75,

Merci pour ta réponse ... ;-)

Je me suis rendu compte que je n'avais pas bien exprimé ce que je voulais faire.

Je remets un fichier en pièce jointe que je pense plus clair.

Merci ...

Joël

 

[job75]

Re : RECHERCHEV avec NBCAR dans la table matrice

Re,

et si oui, renvoyer F13 dans AH13

et si non que fait-on ?

Tel quel votre problème n'a guère de sens.

Encore bonne nuit.

 

[job75]

Re : RECHERCHEV avec NBCAR dans la table matrice

Re,

Avec le texte vide "" si la recherche n'aboutit pas :

=REPT(F13;SIGNE(NB.SI(AI:AI;F13&"*")))

A+

 

[Denis132]

Re : RECHERCHEV avec NBCAR dans la table matrice

Bonsoir joel8301, job75,


Semblable à job75, (avec les mêmes questionnements)

=SI(NB.SI($AI:$AI;F13&"*");F13;"")

@+

Denis

 

[job75]

Re : RECHERCHEV avec NBCAR dans la table matrice

Bonsoir Denis,

Formule de mon post #7 => 32 octets en mémoire

Formule de ton post #7 => 45 octets en mémoire.

La fonction SI "pèse" lourd (18 octets) je l'évite quand c'est possible.

A+

 

[Denis132]

Re : RECHERCHEV avec NBCAR dans la table matrice

Bonsoir job75,

Tu as raison mais je trouve que la fonction "si" est plus facile à comprendre.

Justement, pourquoi la fonction "signe" car j'ai essayé ta formule sans cette fonction et tout va.

Merci

@+

Denis

 

[job75]

Re : RECHERCHEV avec NBCAR dans la table matrice

[Bonjour Denis, le forum,

Justement, pourquoi la fonction "signe" car j'ai essayé ta formule sans cette fonction et tout va.

S'il y avait plus d'une valeur trouvée en colonne AI, on aurait NB.SI > 1 et REPT afficherait plusieurs fois F13.

Bonne journée.

 

[job75]

Re : RECHERCHEV avec NBCAR dans la table matrice

Re,

Pour une recherche avec NBCAR il faut délimiter la plage et utiliser une formule matricielle.

Avec SI (54 octets) :

=SI(OU(GAUCHE(AI$1:AI$1000;NBCAR(F13))=F13);F13;"")

Avec REPT (38 octets) :

=REPT(F13;OU(GAUCHE(AI$1:AI$1000;NBCAR(F13))=F13))

Ces formules sont à valider par Ctrl+Maj+Entrée.

Ne pas oublier les signes $ puisqu'on tire les formules vers le bas.

A+