'Cet exemple consiste à ajouter une nouvelle feuille, un bouton
'de commande sur cette feuille et le code de l'événement Click
'du bouton.
'Denis Michon, mpfe
Sub Ajouter_Feuille_Bouton()
Dim NouvelleFeuille As Worksheet, NouveauBouton As OLEObject
Dim Code$, NextLine&
' Ajoute une Nouvelle feuille
Set NouvelleFeuille = Sheets.Add
' Ajoute un bouton de Commande
Set NouveauBouton = NouvelleFeuille.OLEObjects.Add _
("Forms.CommandButton.1")
With NouveauBouton
.Left = 4
.Top = 4
.Width = 100
.Height = 30
.Object.Caption = "Retour feuille 1..."
End With
' Comment ajouter le code se rapportant au bouton...
Code = "Sub CommandButton1_Click()" & vbCrLf
Code = Code & " On Error Resume Next" & vbCrLf
Code = Code & " Sheets(""Feuil1"").Activate" & vbCrLf
Code = Code & " If Err <> 0 Then" & vbCrLf
Code = Code & " MsgBox ""Impossible d'activer la feuille1.""" & vbCrLf
Code = Code & " End If" & vbCrLf
Code = Code & "End Sub"
' Ecriture du code dans le module de la feuille (fs)
With ThisWorkbook.VBProject.VBComponents(ActiveSheet.Name).CodeModule
NextLine = .CountOfLines + 1
.InsertLines NextLine, Code
End With
End Sub