Problème de formules...

job75

XLDnaute Barbatruc

• 21 Mars 2009

• #2

Re : Problème de formules...

Bonjour oslo,

Pour la 1ère question, formule en I2 :

Code:

=SI(OU(A2="";NB.SI(A$1:A1;A2));"";D2-SOMMEPROD((A$2:A$1000=A2)*F$2:F$1000))

A tirer vers le bas, ou plutôt à entrer dans la plage en validant par Ctrl+Entrée.

Je vais dîner, la 2ème question pour plus tard ou pour d'autres.

A+

 

Vote positif 0 Vote négatif

O

oslo71

Guest

• 21 Mars 2009

• #3

Re : Problème de formules...

Carrément Génial Job75.
J'étais pas prêt de la trouver celle là !!!
Ca fonctionne impeccable. Grand merci.
Pour la 2ème question, t'inquiète pas, si le résultat est aussi génial, j'attendrai le temps qu'il faudra...
Merci
Cordialement.

 

Vote positif 0 Vote négatif

W

wamme

XLDnaute Occasionnel

• 21 Mars 2009

• #4

Re : Problème de formules...

Bonsoir pour la 2e question essayer en J2
=SI(E2<>"";AUJOURDHUI()-E2;"")

ou mieux
=SI(ET(E2<>"";E2<AUJOURDHUI());AUJOURDHUI()-E2;"")

 

Dernière édition: 21 Mars 2009

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 21 Mars 2009

• #5

Re : Problème de formules...

Re,

La soupe n'était pas encore prête. En J2 :

Code:

=SI(OU(I2="";AUJOURDHUI()<=E2);"";AUJOURDHUI()-E2)

Edit : salut wamme, c'est idem

A+

 

Dernière édition: 21 Mars 2009

Vote positif 0 Vote négatif

JCGL

XLDnaute Barbatruc

• 21 Mars 2009

• #6

Re : Problème de formules...

Bonjour à tous,
Salut Job,

A essayer, aussi, en I6 :

Code:

=SI($D2="";"";SOMMEPROD(($B$2:$B$8=$B2)*($D$2:$D$8-$F$2:$F$8)))

Pas bien compris la deuxième demande

A+ à tous

 

Vote positif 0 Vote négatif

O

oslo71

Guest

• 21 Mars 2009

• #7

Re : Problème de formules...

Super. Merci à tous les deux.
Puis-je me permettre de vous poser une autre question par rapport à la 1ère formule.
Si je veux clore la commande.
Dans la colonne "K" il y aura un "C" en face de la cmde que je veux clore.
Serait-il possible que le reste à livrer passe à zero si il y a un "C" dans la colonne K ?
Merci encore.

 

Vote positif 0 Vote négatif

JCGL

XLDnaute Barbatruc

• 21 Mars 2009

• #8

Re : Problème de formules...

Bonjour à tous,

En I2 et tirer vers le bas :

Code:

=SI(K2="C";0;SI($D2="";"";SOMMEPROD(($B$2:$B$8=$B2)*($D$2:$D$8-$F$2:$F$8))))

A+ à tous

 

Vote positif 0 Vote négatif

O

oslo71

Guest

• 21 Mars 2009

• #9

Re : Problème de formules...

Merci JCGL, c'est vraiment trop fort..
On joue vraiment dans la cour des grands ici...
Je vous souhaite un bon week-end à TOUS
Encore Merci.
Cordialement.
Oslo

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 21 Mars 2009

• #10

Re : Problème de formules...

Re, salut JCGL,

On a tous compliqué inutilement, il me semble.

Comme l'a fait JCGL, il suffit de tester uniquement sur la colonne D, et ma 1ère formule se simplifie donc :

Code:

=SI(D2="";"";D2-SOMMEPROD((A$2:A$1000=A2)*F$2:F$1000))

et avec les "C" en colonne K (Edit : si l'on ne veut pas mettre des 0 sur toutes les lignes) :

Code:

=SI(D2="";"";(K2<>"C")*(D2-SOMMEPROD((A$2:A$1000=A2)*F$2:F$1000)))

A+

 

Dernière édition: 21 Mars 2009

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 23 Mars 2009

• #11

Re : Problème de formules...

Bonjour Oslo, JCGL, le fil,

Oslo par MP m'a fait part d'une remarque intéressante : quand les valeurs de certaines cellules sont le résultat de formules, la formule :

Code:

=SI(D2="";"";(K2<>"C")*(D2-SOMMEPROD((A$2:A$1000=A2)*F$2:F$1000)))

renvoie une erreur.

En effet, il en est ainsi si des cellules dans la plage F$2:F$1000 ne sont pas vides mais contiennent le texte vide "" (renvoyé par une formule).

Dans ce cas il faut entrer en I2 la formule matricielle (validation par Ctrl+Maj+Entrée) suivante et la copier vers le bas :

Code:

=SI(D2="";"";(K2<>"C")*(D2-SOMME((A$2:A$1000=A2)*SI(F$2:F$1000<>"";F$2:F$1000))))

A+

 

Vote positif 0 Vote négatif

O

oslo71

Guest

• 23 Mars 2009

• #12

Re : Problème de formules...

Merci Job75 et JCGL,

Cette dernière formule fonctionne à merveille (même en prenant des cellules dans lesquelles il y a déja des formules avex des "")
Grand merci à vous deux.
Cdlt.
Oslo.

 

Vote positif 0 Vote négatif