petite.valeur/grande.valeur + index/equiv

[JMDBOULE78]

Bonjour,

Je m'arrache les cheveux avec la combinaison des ces 2 formules.
Quelqu'un aurait il une piste ?

Merci @ vous bonne journée et bon weekend

 

[JCGL]

Re : petite.valeur/grande.valeur + index/equiv

Bonjour à tous,

Un essai avec :

=SOMMEPROD(($B$2:$B$12=$I$2)*($C$2:$C$12=C2)*$D$2:$D$12)

et une MeFC

A + à tous

 

[JMDBOULE78]

Re : petite.valeur/grande.valeur + index/equiv

Merci pour la proposition, mais sommeprod dans ce cas ne remonte que le resultat de la colonne D, alors que cela devrait remonter colonne C et D.
@+

 

[CB60]

Re : petite.valeur/grande.valeur + index/equiv

Bonjour à tous
Une formule de Monique😀

 

[JCGL]

Re : petite.valeur/grande.valeur + index/equiv

Bonjour à tous,
Salut Bruno,

Alors le TCD me semble approprié...

A + à tous

 

[R@chid]

Re : petite.valeur/grande.valeur + index/equiv

Salut @ tous,
en G2 :

=SI(LIGNES($2:2)<=NB.SI($B$2:$B$12;$I$2);INDEX(C$2:C$12;PETITE.VALEUR(SI($B$2:$B$12=$I$2;LIGNE(INDIRECT("1:"&LIGNES(C$2:C$12))));LIGNES($2:2)));"")

@ valider Par Ctrl+Maj+Entree
@ tirer vers le bas et vers la droite
Bon Dimanche

Edit : Si les donnees sont bien triees sur la colonne B ( colonne critere ) :

=SI(LIGNES($2:2)<=NB.SI($B$2:$B$12;$I$2);INDEX(C$2:C$12;EQUIV($I$2;$B$2:$B$12;0)+LIGNES($2:2)-1);"")

@ valider par une simple Entree
@ tirer vers le bas et vers la droite

 

[JMDBOULE78]

Re : petite.valeur/grande.valeur + index/equiv

Le TCD est juste dans ce cas. Cependant ce n'est pas ce que je recherche car je dois integrer ces formules dans une feuille qui elle meme en comporte d'autres....

A+

 

[JMDBOULE78]

Re : petite.valeur/grande.valeur + index/equiv

Merci Rachid, la deuxieme sans matricielle fonctionne parfaitement.

Je vais decortiquer ta formule pour la comprendre. La fonction ligne, je ne l'a connait pas forcement bien.

Bon dimanche

Jmdboule

 

[R@chid]

Re : petite.valeur/grande.valeur + index/equiv

Salut @ tous,

La fonction ligne, je ne l'a connait pas forcement bien

c'est pas LIGNE() que j'ai utilise mais c'est LIGNES().
la fonction LIGNES($2:2) va generer une suite d'entier commencant par 1 quand on la tire vers le bas.
on peut donner comme equivalente par LIGNE()-1 et il va donner le meme resultat, mais je ne le prefere pas parceque si on ajoute des lignes au dessus de tableau on va etre obliger de modifier le nombre 1 par le nombre de lignes au dessus du tableau.
J'espere etre bien clair sur mes explications.
Bonne journee

 

[hbenalia]

Re : petite.valeur/grande.valeur + index/equiv

Bonjour à tous,

La même idée que celle de Rachid_0661 avec une formule matricielle dans le fichier attaché...

Cordialement

 

[JMDBOULE78]

Re : petite.valeur/grande.valeur + index/equiv

Bonsoir Rachid et Hben, merci beaucoup pour votre aide. J'ai bien travaillé à essayer de comprendre vos formules et j'ai pu l'appliquer dans un autre fichier en integrant aussi la condition "ou" dont j'avais besoin.

Par contre je butte sur OU METTRE une condition de resultat. En effet dans la colonne C, j'ai des lettres, mais si j'ai des chiffres, je voudrai que cela ne remonte rien. Ou puis je l'inserer ?

Bonne soiree.

Merci Rachid pour tes explications de la fonction LIGNES.

A bientot

 

[R@chid]

Re : petite.valeur/grande.valeur + index/equiv

Salut @ tous,
il faut une formule matricielle @ valider par Ctrl+Maj+Entree toujours en G2 :

=SI(LIGNES($2:2)<=SOMME(ESTTEXTE($C$2:$C$12)*($B$2:$B$12=$I$2));INDEX(C$2:C$12;PETITE.VALEUR(SI(($B$2:$B$12=$I$2)*(ESTTEXTE($C$2:$C$12));LIGNE(INDIRECT("1:"&LIGNES(C$2:C$12))));LIGNES($2:2)));"")

fonctionne sur toutes les versions d'excel.

=SIERREUR(INDEX(C$2:C$12;PETITE.VALEUR(SI(($B$2:$B$12=$I$2)*(ESTTEXTE($C$2:$C$12));LIGNE(INDIRECT("1:"&LIGNES(C$2:C$12))));LIGNES($2:2)));"")

Excel 2007 et superieur

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas et vers la droite
Amicalement

 

[JMDBOULE78]

Re : petite.valeur/grande.valeur + index/equiv

Salut Rachid,

En G2 j'ai mis la premiere formule en matricielle mais les valeurs numeriques remontent malgre tout. N'a un truc que je pige pas avec la matricielle alors !

 

[R@chid]

Re : petite.valeur/grande.valeur + index/equiv

Salut,
voir PJ si ca ce que tu veux

 

[R@chid]

Re : petite.valeur/grande.valeur + index/equiv

Salut,
je viens de voir le fichier "TEST 2",
c'est pas celle que je t'ai conseille sur le POST #12.
veirfie les Msj
Amicalement