Microsoft 365 utiliser la fonction INDEX + EQUIV avec 2 possibilités

[Mat65000]

Bonjour à toute la communauté, je cale sur une formule.

Dans l'onglet "général", je gère un classement (coupe du monde foot) et je veux que dans les colonnes AF, AG et AH ne s'affichent les scores que s'il y a des égalités au niveau de la colonne X. J'affiche donc que les scores des matchs entre les équipes qui se retrouvent à égalité. En l'occurrence ici les 2 équipes à 4 points qui ont fait un "2-2".
La formule =SI(X6=X8;INDEX(G:G;EQUIV(1;(E:E=U6)*(J:J=U8);0));"0") marche très bien.

Là où ça se complique c'est lorsque dans l'onglet "préparation" j'inverse "A1" et "A3", il me faudrait la formule suivante:
=SI(X6=X8;INDEX(H:H;EQUIV(1;(E:E=U8)*(J:J=U6);0));"0")

Comment puis-je faire pour pouvoir mettre une fonction OU entre ces 2 formules de manière à ce que cela fonction si il y a un match A1-A3 ou A3-A1

Merci d'avance à tous

 

[sylvanu]

Bonjour Mat,
Essayez peut être en utilisant SIERREUR :

=SIERREUR(SIERREUR(SI(X6=X8;INDEX(G:G;EQUIV(1;(E:E=U6)*(J:J=U8);0));"0");SI(X6=X8;INDEX(H:H;EQUIV(1;(E:E=U8)*(J:J=U6);0));"0"));"")

( toujours en matriciel )
Cela se traduit par :
Si X6=X8 alors Formule1
S'il y a erreur alors Formule2
Sinon ""

SIERREUR - Support Microsoft

Comment utiliser la fonction SIERREUR dans Excel pour intercepter et gérer les erreurs dans une formule.

support.microsoft.com

Addon : Peut être un chouia plus simple avec le même principe :

=SIERREUR(SI(X6=X8;SIERREUR(INDEX(G:G;EQUIV(1;(E:E=U6)*(J:J=U8);0));INDEX(H:H;EQUIV(1;(E:E=U8)*(J:J=U6);0)));0);"")

 

[Mat65000]

Bonjour Mat,
Essayez peut être en utilisant SIERREUR :

=SIERREUR(SIERREUR(SI(X6=X8;INDEX(G:G;EQUIV(1;(E:E=U6)*(J:J=U8);0));"0");SI(X6=X8;INDEX(H:H;EQUIV(1;(E:E=U8)*(J:J=U6);0));"0"));"")

( toujours en matriciel )
Cela se traduit par :
Si X6=X8 alors Formule1
S'il y a erreur alors Formule2
Sinon ""

SIERREUR - Support Microsoft

Comment utiliser la fonction SIERREUR dans Excel pour intercepter et gérer les erreurs dans une formule.

support.microsoft.com

Addon : Peut être un chouia plus simple avec le même principe :

=SIERREUR(SI(X6=X8;SIERREUR(INDEX(G:G;EQUIV(1;(E:E=U6)*(J:J=U8);0));INDEX(H:H;EQUIV(1;(E:E=U8)*(J:J=U6);0)));0);"")

Bonjour Sylvanu, c'est parfait, merci pour ton aide et à très bientôt pour de nouvelles solutions 🙂