Microsoft 365 ombrage bouton

[riv]

bonjour a tous comment peut on ajouter un effet d'ombrage a un bouton sur Excel 365, on m'a parler de l'onglet "outils de dessin" mais je n'ai rien

merci d'avance

 

[patricktoulon]

Bonjour
si ton bouton est un shape
pour les shapes c'est dans le menu contextuel
format de la forme et dans le menu à gauche "Effet" puis "Ombre"
voir capture

si ton bouton est un activX dans ses propriéte (dans VBE) c'est shadow (true ou false )

 

[riv]

pour ma par ce sont des bouton "contrôles de formulaire"

 

[patricktoulon]

re
ben tu es chocolat me semble t il
si vraiment c'est important il va te falloir bricoler

 

[patricktoulon]

bon allez un peu de bricolage ne fait pas de mal ça détend

Option Explicit

Sub clearOmbre()
    With ActiveSheet
        For Each shap In .Shapes
            If Left(shap.Name, 5) = "Ombre" Then shap.Delete
        Next
    End With
End Sub

Sub Ombre_a_mes_boutons()
    Dim decalOmbre, shap As Shape, shadowShap As Shape

    decalOmbre = 4
    With ActiveSheet
        clearOmbre
        For Each shap In .Shapes
            If shap.Type = 8 Then
                Set shadowShap = .Shapes.AddShape(5, shap.Left + decalOmbre, shap.Top + decalOmbre, shap.Width, shap.Height)
                With shadowShap
                    .Name = "Ombre" & shap.Name
                    .ZOrder msoSendToBack
                    .Fill.ForeColor.RGB = vbRed
                    .Fill.Transparency = 0.7
                    .Line.Visible = msoFalse
                    .ZOrder msoSendToBack
                    .OnAction = shap.OnAction
                End With
            End If
        Next
    End With
End Sub

 

[riv]

a cool sympa ton petit bricolage 🙂

merci

 

[riv]

j'ai essayer ton code et il me colle une erreur d'entrer lol

 

[riv]

bonjour @patricktoulon
voici Excel sur lequel l'ombre ne fonctionne pas, si tu veut bien aussi m'expliquer les ligne que tu as écris pour que j'essai de comprendre merci

 

[patricktoulon]

re
Bonjour
avant de dire que ca ne fonctionne pas il faut le faire correctement

1. si tu utilise option explicit tache de déclarer toute les variables
2. et pour que ça fonctionne au click du bouton il faut bien évidement lui affecter la macro "Ombre_a_mes_boutons"

 

[patricktoulon]

re
et pour te facilité la tache
je te propose de mettre les variable en constante
de façon a ce que tu n'est que ces 4 lignes a modifier pour changer la couleur , la transparence , le decalage de l'ombre
et je te montre comment on peut utiliser une des 4 façons d'initier la couleur de l'ombre

Option Explicit

Const decalOmbre& = 5           ' le decalge que l'on veut (c'est en point)
Const transparence# = 0.6       'la transparence de 0  à 1

'la couleur de l'ombre ( elle peut être exprimée en (long  , vbconstante , hex )
'exemple ici la couleur bleue(ces  4 lignes designent la même couleur )
 Const couleurOmbre& = vbBlue           'exprimé en vbconstante
'Const couleurOmbre& = &HFF0000         'exprimé en hex
'Const couleurOmbre& = 16711680         'exprimé en long
'Const couleurOmbre& = 5                'exprimé en index de la palette couleur excel

Sub clearOmbre()
    Dim shap As Shape
    With ActiveSheet
        For Each shap In .Shapes
            If Left(shap.Name, 5) = "Ombre" Then shap.Delete
        Next
    End With
End Sub

Sub Ombre_a_mes_boutons()
    Dim shap As Shape, shadowShap As Shape, couleurombreB&
    If couleurOmbre <= 56 Then couleurombreB = ThisWorkbook.Colors(couleurOmbre) Else couleurombreB = couleurOmbre
    With ActiveSheet
        clearOmbre
        For Each shap In .Shapes
            If shap.Type = 8 Then
                Set shadowShap = .Shapes.AddShape(5, shap.Left + decalOmbre, shap.Top + decalOmbre, shap.Width, shap.Height)
                With shadowShap
                    .Name = "Ombre" & shap.Name
                    .ZOrder msoSendToBack
                    .Fill.ForeColor.RGB = couleurombreB
                    .Fill.Transparency = transparence
                    .Line.Visible = msoFalse
                    .ZOrder msoSendToBack
                    .OnAction = shap.OnAction
                End With
            End If
        Next
    End With
End Sub

 

[riv]

re
Bonjour
avant de dire que ca ne fonctionne pas il faut le faire correctement

bonjour Patrick
oui c'est une certitude que c'est moi qui fait mal les chose dsl

 

[riv]

merci beaucoup je teste ca