Noms associés aux 3 plus grandes valeurs

[Help_01]

Bonjour,

Trouver les noms associés aux 3 plus grandes valeurs dans le petit tableau du fichier.

Merci.

 

[joss56]

Re : Noms associés aux 3 plus grandes valeurs

Bonjour,

Chercher du côté de index et equiv.

De rien

 

[david84]

Re : Noms associés aux 3 plus grandes valeurs

Bonjour,
voir ici sur le site de JB.
A+

 

[JBOBO]

Re : Noms associés aux 3 plus grandes valeurs

Bonjour,

Un peu tordu mais ça semble fonctionner, en F2 à tirer vers le bas :

=INDIRECT("A"&SOMMEPROD(GRANDE.VALEUR((Score=GRANDE.VALEUR(Score;D2))*LIGNE(Noms);D2)))

 

[R@chid]

Re : Noms associés aux 3 plus grandes valeurs

Bonjour @ tous,
en E2 :

=GRANDE.VALEUR(Score;LIGNES($2:2))

@ tirer vers le bas


en F2 :

=SI(E2="";"";INDEX(Noms;PETITE.VALEUR(SI(Score=E2;LIGNE(INDIRECT("1:"&LIGNES(Score))));NB.SI(E$2:E2;E2))))

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas


@ + +

 

[Help_01]

Re : Noms associés aux 3 plus grandes valeurs

Bonjour R@chid,

La solution que tu as proposée dans le cas où les 3 plus grandes valeurs seraient identiques fonctionne bien. Merci.

Merci à toi et à tous ceux qui sont intervenus sur ce fil de discussion.

 

[R@chid]

Re : Noms associés aux 3 plus grandes valeurs

Re,
la formule fonctionne parfaitement avec n'importe quel cas dont tu parles.


Noter que la formule est matricielle et qu'elle nécessite une validation matricielle avec la combinaison des touches Ctrl+Shift+Enter et qu'après une validation matricielle réussie tu vas voir apparaitre des accolades {} qui entourent la formule dans la barre de formules.


@ + +

Edit : t'as édité ton post ? 🙂

 

[Help_01]

Re : Noms associés aux 3 plus grandes valeurs

Tout est Ok.

Merci.

 

[Help_01]

Re : Noms associés aux 3 plus grandes valeurs

Si je peux me permettre, est-ce possible d'obtenir le même résultat c'est-à-dire les noms des 3 plus hauts résultats sans passer par l'intermédiaire de la colonne des 3 résultats les plus hauts. En fait, il s'agirait d'extraire les 3 noms ayant le meilleur score directement sans passer par une colonne intermédiaire.

Merci!

 

[BOISGONTIER]

Re : Noms associés aux 3 plus grandes valeurs

Bonsoir,

cf PJ

Selectionner F2:F4

=INDEX(Noms;EQUIV(GRANDE.VALEUR(Score-LIGNE(Score)/10^10;LIGNE(INDIRECT("1:"&LIGNES(Score))));Score-LIGNE(Score)/10^10;0))
Valider avec maj+ctrl+entrée
ou

=INDEX(Noms;EQUIV(GRANDE.VALEUR(Score-LIGNE(Score)/10^10;{1;2;3});Score-LIGNE(Score)/10^10;0))

cf
Classement avec égalité

JB

 

[Help_01]

Re : Noms associés aux 3 plus grandes valeurs

Merci, tout est OK!