Moyenne

[patrick]

Comment faire pour que la fonction MOYENNE ne tienne pas compte des zéros dans son calcul.

 

[Monique]

Bonjour,

=SOMME(A1:A15)/NB.SI(A1:A15;">"&0)

Ou bien en matriciel :
=MOYENNE(SI(A1:A15>0;A1:A15))
à valider en appuyant simultanément sur ctrl, maj et entrée

 

[patrick]

Merci monique,

Mais comment faire si les cellules ne sont pas voisines ?
Exemple:
=MOYENNE(H8;K8;N8;Q8;T8;W8;Z8;AC8;AF8;AI8;AL8;AO8;AR8;AU8;AX8;BA8)


cordialement

Patrick LEPRUN

 

[Monique]

Re,

Si c'est vraiment une cellule sur 3 et pas seulement un exemple :

=SOMME(Plage)/SOMMEPROD((MOD(COLONNE(H8:BA8);3)=2)*(H8:BA8>0)*1)

Pour faire la somme de tes cellules discontinues, tu peux donner un nom à cet ensemble de cellules.
Tu les sélectionnes toutes en maintenant la touche ctrl en foncée,
Barre de menu - Insertion - Nom - Définir et tu tapes le nom choisi.
Ou bien tu les sélectionnes et tu tapes directement le nom choisi dans la zone "nom", à gauche de la barre de formule.

Pour avoir le nombre de cellules, 1 colonne sur 3, contenant une valeur > 0 :
=SOMMEPROD((MOD(COLONNE(H8:BA8);3)=2)*(H8:BA8>0)*1)
La fonction MOD(nombre;3) donne le reste de la division par 3 du nombre
=COLONNE(A1) donne 1
=COLONNE(B1) donne 2
=COLONNE(C1) donne 0
Et si on continue, ça donne 1 2 0 1 2 0 etc
Tes cellules sont dans des colonnes multiples de 3, plus 2
Et SOMMEPROD te donne rien que le nombre de cellules situées dans ces colonnes et rien que celles qui ont une valeur > 0

 

[Monique]

Re,

Il n'y a pas besoin du *1 à la fin de la formule.