Min.si (en ne comptant pas les 0)

[Vilain]

Salut à tous,

J'ai un petit souci.
Il y a peu, j'avais besoin d'utiliser une fonction Max.si (enfin si elle existait bien sur). Renauder m'avait alors grandement aider en me dirigeant vers une fonction matricielle.
Aujourd'hui, sur le même principe, j'ai besoin de faire un min.si (qui n'existe évidemment pas non plus). J'ai voulu faire la même chose, en matricielle, mais ça ne marche pas. De plus, j'ai un paramètre supplémentaire à prendre en compte, les 0 ne doivent pas faire partie de ce mini.

Comment faire ?

Merci d'avance pour votre aide.
Je joins un fichier pour plus de clarté, mais n'hésitez pas à me demander de préciser.

A plus

 

[hoerwind]

Re : Min.si (en ne comptant pas les 0)

Bonjour,

Effacé, erreur de message, avec mes excuses !

 

[job75]

Re : Min.si (en ne comptant pas les 0)

Bonjour Gillus69,

Formule matricielle en D2 :

=MIN(SI($A$2:$A$15=$A2;$B$2:$B$15))

Et si l'on ne veut pas du tout de 0 :

=MIN(SI($B$2:$B$15*($A$2:$A$15=$A2);$B$2:$B$15))

Edit salut hoerwind

A+

 

[Vilain]

Re : Min.si (en ne comptant pas les 0)

Salut hoerwind,
Je ne comprends pas bien ta solution.
Ou veux tu que j'inscrive cette fonction ?
Quand j'essaie de l'adapter, cela ne fonctionne pas et me renvoie que des 0. J'ai du rater qqch...
Encore merci

 

[JCGL]

Re : Min.si (en ne comptant pas les 0)

Bonjour à tous,
Salut Gilles,

Peux-tu essayer en matricielle :

=MIN(SI(($A$2:$A$15=A2);$B$2:$B$15))

A + à tous

Edition : Salut HoerWind, Salut Gérard... Très en retard.

 

[Vilain]

Re : Min.si (en ne comptant pas les 0)

Salut Job, Salut JC,

Merci beaucoup pour votre aide.
La solution de Job marche parfaitement. Je vais prendre celle-ci pour le moment sans trop réfléchir (par faute de temps). Ceci dit, je vais me replonger sur cette question car je galère toujours un peux avec les matricielles. Il me semble que c'est un bon exercice.
Merci à tous, vous m'avez, encore une fois, sorti une épine du pied.

A plus

Edit : Hoerwind tu as changé ta formule, non ?

 

[job75]

Re : Min.si (en ne comptant pas les 0)

Re,

Edit : Hoerwind tu as changé ta formule, non ?

Non mais moi j'ai changé la mienne en effet.

J'avais écrit :

=MIN(SI($A$2:$A$15=$A2;$B$2:$B$15*($A$2:$A$15=$A2)))

Mais ceci suffit :

=MIN(SI($A$2:$A$15=$A2;$B$2:$B$15))

Idem pour ma 2ème formule.

A+

 

[R@chid]

Re : Min.si (en ne comptant pas les 0)

Bonjour @ tous,
Matricielle :

=MIN(SI((A$2:A$15=A2)*(B$2:B$15>0);B$2:B$15))

Simple :

=PETITE.VALEUR(DECALER(B$1;EQUIV(A2;A:A;0)-1;;NB.SI(A:A;A2));NB.SI(DECALER(B$1;EQUIV(A2;A:A;0)-1;;NB.SI(A:A;A2));0)+1)

Amicalement

 

[Vilain]

Re : Min.si (en ne comptant pas les 0)

Salut Rachid,

Re les autres,
Merci à tous pour votre aide.

Job : il me semblait bien, je n'y comprenais plus rien. Ta première version était quand même juste, non (Je t'avoue que je l'utilise maintenant dans quelques dizaines de colonne paramétré différemment, j'ai un peu la flemme de tout changer...).

A plus