Macro lien hypertexte feuille

[SAMWRC]

Bonjour à tous,

Sur une feuille de mon fichier, j'ai un lien hypertexte vers une autre feuille de ce même fichier. J'aimerais lancer ce lien hypertexte à partir d'une macro.

With ActiveSheet.Range("A1")
    If .Hyperlinks.Count > 0 Then .Hyperlinks(1).Follow NewWindow:=False, AddHistory:=True
End With

Cette macro marche lorsque le lien hypertexte pointe vers un autre fichier, mais en ce qui concerne une autre feuille du même fichier, ça ne marche plus ...

Je vous joint un fichier avec mon problème.

Une idée ?
Merci d'avance pour votre aide

Bonne journée
Sam

 

[JNP]

Re : Macro lien hypertexte feuille

Bonjour SamWRC 🙂,
A tester

With ActiveSheet.Range("A1")
    If .Hyperlinks.Count > 0 Then
        With .Hyperlinks(1)
            If UBound(Split(.SubAddress, "\")) <> 0 Then
                .Follow NewWindow:=False, AddHistory:=True
            Else
                Sheets(Split(.SubAddress, "!")(0)).Select
                Range(Split(.SubAddress, "!")(1)).Select
            End If
        End With
    End If
End With

Bonne suite 😎

 

[SAMWRC]

Re : Macro lien hypertexte feuille

Bonjour JNP 🙂,

Merci beaucoup pour ton aide. Ton code marche parfaitement 😀
Je note juste que si il y a un espace dans le nom de la feuille de destination, le code retourne une erreur (cf. nouvelle pj). Une parade pour ce problème ? 😕

Merci

 

[SAMWRC]

Re : Macro lien hypertexte feuille

J'ai trouvé une solution :

Sub Macro1()
With ActiveSheet.Range("A1")
    If .Hyperlinks.Count > 0 Then
        With .Hyperlinks(1)
            If UBound(Split(.SubAddress, "\")) <> 0 Then
                .Follow NewWindow:=False, AddHistory:=True
            Else
                Dim ws As String
                ws = Split(.SubAddress, "!")(0)
                If Left(ws, 1) = "'" Then ws = Right(Left(ws, Len(ws) - 1), Len(ws) - 2)
                Sheets(ws).Select
                Range(Split(.SubAddress, "!")(1)).Select
            End If
        End With
    End If
End With
End Sub

Ca a l'air de fonctionner. Merci encore JNP 🙂

 

[JNP]

Re : Macro lien hypertexte feuille

Re 🙂,
Effectivement, on évite en général les espaces dans les noms d'onglets 😛,
Autre solution :

                Sheets(Replace(Split(.SubAddress, "!")(0), "'", "")).Select
                Range(Replace(Split(.SubAddress, "!")(1), "'", "")).Select

Bonne suite 😎

 

[job75]

Re : Macro lien hypertexte feuille

Bonjour SAMWRC, salut Jean-Noël 🙂

Autre solution :

On Error Resume Next
[A1].Hyperlinks(1).Follow
If ActiveWorkbook.Name = ThisWorkbook.Name Then _
  Application.Goto Evaluate([A1].Hyperlinks(1).SubAddress)

A+

 

[SAMWRC]

Re : Macro lien hypertexte feuille

Merci JNB et job75,

Vos 2 solutions fonctionnent. Je vais utiliser le code de job75 car il est plus concis.

Bonne journée 🙂