Liste déroulante sans cellules vides

[gaetan2812]

Bonjour au forum, ou re-bonjour pour certains.

J'essaie depuis maintenant 1 h de me créer une liste déroulante en souhaitant faire disparaître mes cellules vides. J'ai cherché sur internet, et je n'arrive pas à adapter les différents exemples trouvés.

J'ai une liste en haut de ma colonne A. Cette liste peut contenir au maximum 10 éléments. Pour le moment, j'en ai que 5. Je souhaite créer une liste déroulante avec ces 5 choix possibles et sans les 5 cellules vides. Mais cette liste doit pouvoir s'étendre aux 10 éléments maxi si je rajoute 5 autres éléments dans ma liste, éléments que je peux rajouter en insérant entre deux autres (mettre 2 entre 1 et 3 par exemple). Ma liste serait donc au maximum entre la ligne 2 et la ligne 11.

C'est ce 2e paragraphe sur lequel je bloque. Je suis dispo si vous avez des questions.

Merci d'avance !

 

[CHALET53]

Re : Liste déroulante sans cellules vides

bonjour,

Regarde en E4
Données Validation de données
a+

 

[job75]

Re : Liste déroulante sans cellules vides

Rebonjour gaetan2812, hello CHALET53,

Voyez le fichier joint avec cette formule matricielle en C2 :

=SI(LIGNES(C$2:C2)>NB(A$2:A$11);"";MIN(SI(ESTNUM(A$2:A$11)*(NB.SI(C$1:C1;A$2:A$11)=0);A$2:A$11)))

A valider par Ctrl+Maj+Entrée.

Edit : oui en effet, je pense que j'ai mal compris le problème et l'ai compliqué inutilement...

A+

 

[gaetan2812]

Re : Liste déroulante sans cellules vides

Je viens de voir vos deux fichiers :

- CHALET53 : si j'ajoute quelquechose en A8 en laissant A7 vide, cela ne marche pas.

- job75 : la formule matricielle ne marche qu'avec les nombres/valeurs mais pas avec du texte (j'avais mis 1 2 3 pour exemple, mais j'ai du texte à la place comme tableau 1, tableau 2, ...) et est ce qu'il y a myen que ça ne mette pas forcément dans l'ordre la liste ?

Merci à vous deux en tous cas !

 

[CHALET53]

Re : Liste déroulante sans cellules vides

Effectivement, il ne faut pas de blanc dans la série
Pourquoi laisser des blancs?
a+

 

[gaetan2812]

Re : Liste déroulante sans cellules vides

Au cas où ce n'est pas moi qui utilise le fichier 🙁

Désolé.

 

[job75]

Re : Liste déroulante sans cellules vides

Re,

Bon alors j'avais bien compris le problème 🙂

Cette formule matricielle fonctionne aussi bien avec des textes qu'avec des nombres :

=SI(LIGNES(C$2:C2)>NBVAL(A$2:A$11);"";INDEX(A:A;MIN(SI(NON(ESTVIDE(A$2:A$11))*(NB.SI(C$1:C1;A$2:A$11)=0);LIGNE(A$2:A$11)))))

Comme vous le demandez, la liste n'est pas triée.

Fichier (2).

A+

 

[job75]

Re : Liste déroulante sans cellules vides

Re,

Et enfin, si vous voulez utiliser la plage C2:C11 pour définir une liste de validation, voici la formule :

=DECALER(C2;;;NB.SI(C2:C11;"><"))

Fichier (3).

A+

 

[gaetan2812]

Re : Liste déroulante sans cellules vides

Normalement c'est tout bon, merci beaucoup !!

 

[alka229]

Bonjour,
J'ai bien suivi les explications plus haut, mais je n'y arrive pas.
Je joins mon fichier.
J'ai deux feuilles, la 1ère contenant les "Données" et la 2è nommée "select" permet de faire les choix; en fonction de l'activité principale en colonne A choisir la sous activité en colonne B.
Trois problèmes :
- Comment éviter les blancs dans la liste de choix ?
- Je n'arrive pas à faire apparaitre toutes les sous-activités
- Lorsque je rajoute ou supprime une activité principale avec ses ses activités que mes listes de choix se mettent automatiquement à jour, ce que j'arrive pas à faire actuellement.
Merci de votre précieuse aide.

 

[R@chid]

Bonsoir @ tous,
ton fichier corrigé.


Cordialement

 

[alka229]

Bonjour R@chid
Merci pour la correction, j'ai un problème qui reste non résolu,
L'ajout d'une nouvelle activité principale avec ses sous-activités n'est pas prise en compte automatiquement,
il faut remodifier la formule à chaque fois?
Merci encore.

 

[JHA]

Bonjour à tous,

Ci-joint un autre essai. Mise en place d'une colonne sup "H" masquée.
Changement de la formule "Lst_TypeSsActivite"

=DECALER(Données!$G$5;EQUIV(Select!$A7;Données!$F$6:$F$147;0);;NB.SI(Données!$H$6:$H$147;Select!$A7))

mis les données sous mode tableau.


JHA

 

[job75]

Bonjour alka229, R@chid, JHA,

Définir le nom Liste1 : =DECALER(Données!$B$6;;;NBVAL(Données!$B:$B)-2) Sélectionner A7 et définir le nom Liste2 : =DECALER(Données!$G$1;EQUIV(Select!$A7;Données!$F:$F;0)-1;;NB.SI(Données!$F:$F;Select!$A7)) Attention, pas de $ devant le 7... En fait ce sont les mêmes formules que celles de R@chid mais avec des plages illimitées. A+

 

[alka229]

Bonjour alka229, R@chid, JHA,

Définir le nom Liste1 : =DECALER(Données!$B$6;;;NBVAL(Données!$B:$B)-2) Sélectionner A7 et définir le nom Liste2 : =DECALER(Données!$G$1;EQUIV(Select!$A7;Données!$F:$F;0)-1;;NB.SI(Données!$F:$F;Select!$A7)) Attention, pas de $ devant le 7... En fait ce sont les mêmes formules que celles de R@chid mais avec des plages illimitées. A+

[/QUOTE
Super merci !!