Interactions entre Checkboxs dans différents onglets

[Sanguinair]

Bonjour à tous,

Je m'excuse de vous déranger.

Voilà 2 semaines que je me casse les dents sur ce problème, en général j'essaye de me débrouiller par moi même, avec l'aide des discussions du forum, mais là je n'ai rien trouvé qui réponde à mes attentes et à mon problème.

Voici le problème que je rencontre. Pour le contexte, je m'occupe de l'organisation de tournois pour mon club de badminton. Nous avons 7 terrains, 4 de simples et 3 de doubles. A chaque tournoi, il y a plusieurs poules de simples et plusieurs de doubles, à chaque poule correspond 1 onglet. Je voudrais afin de faciliter l'organisation et le déroulement du tournoi, pouvoir connaitre la disponibilité ou non des terrains afin de pouvoir affecter ceux-ci ou non à un match.

Les terrains sont numérotés comme suit : Terrain de simple 1, 3, 5, 7 et Terrain de double 2, 4, 6

Je m'explique, par exemple sur mes 4 terrains de simples, au départ je vais lancer 4 matchs, un dans la poule SH1 (Simple Homme 1) sur le terrain 1, je coche la case du terrain 1 afin de l'affecter, ensuite un dans la poule SJ1 (Simple Jeune) sur le terrain 3, je cocher la case du terrain 3, et ainsi de suite. Mes 4 terrains de simple sont affectés, il faudrait donc que dans chaque onglets de simples les 4 checkboxs soient cochées et qu'il y ait marqué à coté "Occupé", si on pouvait également indiqué par quelle poule le terrain est occupé ce serait la fleur sur le gâteau, mais bon c'est pas le principal. Après un match se termine par exemple sur le terrain 7, où il y avait un match de la poule SD1 (Simple Dame) , je vais donc libérer le terrain 7 en cliquant sur la checkbox "Terrain7" et dans tous les onglets je voudrais voir que le terrain 7 est libre, en voyant la Checkbox "Terrain 7" non coché et en voyant à coté de celle-ci "Libre".

J'espère avoir été assez clair.

Je ne sais pas si cela est réalisable.

En tous je vous remercie d'avance pour votre aide, je reste à votre disposition, pour toutes informations complémentaires.

A bientôt

 

[PMO2]

Re : Interactions entre Checkboxs dans différents onglets

Bonjour,

Une démarche un peu compliquée qui semble faire ce que vous demandez. L'idée est de fabriquer une pseudo procédure évènementielle sur les CheckBox.

1) copiez le code suivant dans la fenêtre de code de ThisWorbook

Private Sub Workbook_Activate()
Call InitializeCheckBox
End Sub

2) dans un module standard, copiez le code suivant

Sub InitializeCheckBox(Optional dummy As Byte)
Dim CB As Excel.CheckBox
Dim S As Worksheet
Dim R As Range
Dim i&
Dim A$
For Each S In ThisWorkbook.Worksheets
  For i& = 1 To S.CheckBoxes.Count
    Set CB = S.CheckBoxes(i&)
    Set R = S.Range("b" & 5 + ((i& - 1) * 2))
    CB.Top = R.Top
    CB.Left = R.Left
    A$ = CB.TopLeftCell.Parent.Name & "|" & CB.Caption
    CB.OnAction = "'ExcelCheckbox_Clic """ & A$ & """'"
  Next i&
Next S
End Sub

Sub ExcelCheckbox_Clic(Param As String)
Dim CB As Excel.CheckBox
Dim S As Worksheet
Dim R As Range
Dim Feuille$
Dim ChexckBoxCaption$
Dim Valeur&
Feuille$ = Mid(Param, 1, InStr(1, Param, "|") - 1)
ChexckBoxCaption$ = Mid(Param, Len(Feuille$) + 2)
For Each CB In Sheets(Feuille$).CheckBoxes
  If CB.Caption = ChexckBoxCaption$ Then
    Valeur& = CB.Value
    Exit For
  End If
Next CB
For Each S In ThisWorkbook.Worksheets
  For Each CB In S.CheckBoxes
    If CB.Caption = ChexckBoxCaption$ Then
      CB.Value = Valeur&
      Set R = CB.TopLeftCell.Offset(0, 1)
      If Valeur& = 1 Then
        R = Feuille$
        R.Interior.Color = vbRed
      Else
        R = ""
        R.Interior.Color = vbGreen
      End If
    End If
  Next CB
Next S
End Sub

3) le classeur doit comporter des feuilles avec des CheckBox comme dans la pièce jointe. Il n'y a plus qu'à faire des tests en cliquant sur les CheckBox.

Cordialement.

PMO
Patrick Morange