Intégrer une variable sur extraction minutes

[fleet21]

Bonjour à tous,

Je souhaite insérer une variable appelée col sur la fonction d'extraction des minutes suivantes : Minute(["B" & col]).

Le problème est que ce code est incorrect. Problème de syntaxe ou tout simplement pas possible ?

 

[Lone-wolf]

Bonsoir fleet21

ton fichier en retour.

 

[fleet21]

Merci Lone-wolf je ne vois pas le lien avec ce que je veux faire. Peut être que j'ai raté quelquechose il serait de décrire les lignes de codes.

 

[pierrejean]

bonjour à tous

A tester
nb: format cellule colonne B=Standard

Sub c()
 For n = 3 To Range("A" & Rows.Count).End(xlUp).Row
   Range("B" & n) = (Range("A" & n) * 24 - Int(Range("A" & n) * 24)) * 60
 Next
End Sub

 

[fleet21]

ah oui là je comprends merci Pierre Jean

 

[Lone-wolf]

Bonsoir fleet 🙂, pierrejean 🙂

@ fleet21: désolé, j'ai mal compris.

 

[job75]

Bonjour fleet21, Lone-wolf, Pierre, le forum,

Sur un grand tableau ceci est très rapide car on ne traite pas les cellules une par une :

Sub Minutes()
With ActiveSheet.UsedRange.Columns(2).Offset(1) 'une ligne de titres
    If .Parent.FilterMode Then .Parent.ShowAllData 'si la feuille est filtrée
    .FormulaR1C1 = "=IFERROR(MINUTE(""""&RC[-1]),"""")"
    .Value = .Value 'supprime les formules
End With
End Sub

PS : les valeurs zéro ont un sens, il faut les afficher.

Bonne journée.

 

[job75]

Re,

Complément si l'on veut supprimer les cellules vides en 1ère colonne :

Sub Minutes()
With ActiveSheet.UsedRange.Columns(2).Offset(1)
    If .Parent.FilterMode Then .Parent.ShowAllData 'si la feuille est filtrée
    .FormulaR1C1 = "=IFERROR(MINUTE(RC[-1]),"""")"
    .Value = .Value 'supprime les formules
    With .Offset(, -1).SpecialCells(xlCellTypeBlanks) 'cellules vides en 1ère colonne
        Union(.Cells, .Offset(, 1)).Delete xlUp
    End With
    With .Parent.UsedRange: End With 'actualise la barre de défilement verticale
End With
End Sub

A+

 

[job75]

Re,

J'ai supprimé On Error Resume Next qui était inutile dans la macro précédente.

A+

 

[Lone-wolf]

Bonjour job75, pierre jean, fleet 🙂

@ fleet: ma macro donne le même résultat.

Sub test()
Dim plage As Range, cel As Range, derlig As Long

    derlig = Range("a" & Rows.Count).End(xlUp).Row  'dernière ligne remplie

    Set plage = Range("b2:b" & derlig) 'Plage résultats

    For Each cel In plage 'Pour chaque cellule de la colonne B
        'la cellule extrait les minutes de la colonne A, avec la fontion Minute
        cel.Value = minute(cel.Offset(, -1).Value)
    Next cel

End Sub