Imbriquer 2 formules

Marie123 · 17 Septembre 2018

Bonjour à tous,

J'ai 2 formules dans mon fichier. J'ai besoin de réunir ces formules dans une seule cellule mais quand je n'ai pas "VALEUR!", j'ai "Impossible d'entrer la formule car trop d'imbrication etc"...... Il est vrai que j'ai du mal avec toutes ces parenthèses...

Les voici:

=SI((J2<>"Pierre");"0";SI(NON(ESTVIDE($Z2));SI(ET(ESTVIDE($AD2);ESTVIDE($AV2));SI(ESTVIDE(AM2);SI(AUJOURDHUI()>DATE(ANNEE($Z2);MOIS($Z2)+2;JOUR($Z2));1;0);SI(AUJOURDHUI()>DATE(ANNEE(AM2);MOIS(AM2)-4;JOUR(AM2));1;0));0);0))

et

=SI(ESTNUM(CHERCHE("1";G2));"0";SI(ESTNUM(CHERCHE("4";S2));"0";"1"))

Pourriez-vous m'aider svp?
Merci et bonne journée

Victor21 · 18 Septembre 2018

Bonjour, Marie123.

Sans exemple, difficile de tester.
Une piste cependant :

=SI(NON(ESTVIDE(Z2));1;0)

équivaut à

=SI(Z2<>"";1;0)

et

=DATE(ANNEE(AM2);MOIS(AM2)-4;JOUR(AM2))

équivaut à

=MOIS.DECALER(AM2;-4)

Ce qui devrait raccourcir votre formule

job75 · 18 Septembre 2018

Bonjour Marie123, Patrick,

A priori la 1ère formule doit pouvoir s'écrire :

Code:

=SI((J2="Pierre")*NON(ESTVIDE($Z2))*ESTVIDE($AD2)*ESTVIDE($AV2);SI(ESTVIDE(AM2);--(AUJOURDHUI()>DATE(ANNEE($Z2);MOIS($Z2)+2;JOUR($Z2)));--(AUJOURDHUI()>DATE(ANNEE(AM2);MOIS(AM2)-4;JOUR(AM2))));0)

Pour la seconde formule il faudrait en effet voir le fichier pour savoir comment l'insérer.

A+

job75 · 18 Septembre 2018

Re,

Par exemple si l'insertion peut se faire après le 1er SI on écrira :

Code:

=SI((J2="Pierre")*NON(ESTVIDE($Z2))*ESTVIDE($AD2)*ESTVIDE($AV2)*ESTERREUR(CHERCHE("1";G2))*ESTERREUR(CHERCHE("4";S2));SI(ESTVIDE(AM2);--(AUJOURDHUI()>DATE(ANNEE($Z2);MOIS($Z2)+2;JOUR($Z2)));--(AUJOURDHUI()>DATE(ANNEE(AM2);MOIS(AM2)-4;JOUR(AM2))));0)

A+

Imbriquer 2 formules

Marie123

XLDnaute Junior

Victor21

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Discussions similaires