formule de dates (again!)

[C@thy]

Bonjour le forum,

je cherche une formule qui me calculerait le jour suivant corrigé des samedis et des dimanches ex.
si on est vendredi ou samedi j'obtiens lundi, sinon j'obtiens le lendemain

idem pour le jour précédent ex.
si on est lundi ou dimanche j'obtiens vendredi, sinon j'obtiens le jour précédent

Si c'est trop compliqué, on peut supposer qu'on ne sera jamais un samedi ou un dimanche,
dans ce cas, pour calculer le jour ouvré suivant, ceci fonctionne :
=A1+1+2*(JOURSEM(A1+6)
mais je n'ai pas trouvé le jour précédent😡...

P.S. on ne tient pas compte des fériés.

Un grand Merci à vous,

et bises🙂 très pluvieuses🙁

C@thy

 

[R@chid]

Re : formule de dates (again!)

Bonjour C@thy 😱,
essayer avec :

=A1+1+(JOURSEM(A1)>5)*(7-JOURSEM(A1;2))

Amicalement

 

[tdenfert]

Re : formule de dates (again!)

Bonjour,

avec la date en b3

le jour suivant =SI(JOURSEM(B3;2)<5;B3+1;B3+8-JOURSEM(B3;2))
le jour d'avant =SI(ET(JOURSEM(B3;2)>1; JOURSEM(B3;2)<7);B3-1;SI(JOURSEM(B3;2)=1;B3-3;B3-2))

Il y a surement plus simple

 

[C@thy]

Re : formule de dates (again!)

Bravo Rachid, c'est parfait pour le jour suivant 😉😉😉

mais je butte encore sur le précédent (c'est plus dur!!!)

Merci bôcoup,

Bises

C@thy

 

[C@thy]

Re : formule de dates (again!)

Merci tdenfer, c'est diabolique!!!

C@thy

 

[Tibo]

Re : formule de dates (again!)

Coucou Cathy,

Deux petits essais (si j'ai bien compris) :

=A1+1+(JOURSEM(A1+1;2)=7)

et

=A1-1-(JOURSEM(A1;2)=1)

Bises

@+

Edit : bonjour tout le monde !

@+

 

[C@thy]

Re : formule de dates (again!)

Merci Tibo, tes formules sont diablement concises, mais je ne dois jamais obtenir le samedi...

La formule de R@chid me paraît très bien, je la prèfère à celle de tdenfert car il n'y a pas de SI (toujours la concision)
(ne pas lire SI r concision!!!😉😉😉)

Merci et Bises à vous tous, j'adore ces formules!

C@thy

 

[tdenfert]

Re : formule de dates (again!)

Bonjour, à tous

Merci Tibo pour cette proposition je vais essayer de retenir l’esprit de cette écriture concise
Toutefois si j'ai bien compris cela ne réponds pas complétement à la demande la première pour un vendredi on devrait avoir lundi et pour l'autre pb avec le dimanche qui revoie le samedi au lieu du vendredi.

 

[mapomme]

Re : formule de dates (again!)

Bonjour à tous,

Peut-être ces deux formules:
Suivant:

=A1+CHOISIR(JOURSEM(A1);1;1;1;1;1;3;2)

Précédent:

=A1-CHOISIR(JOURSEM(A1);2;3;1;1;1;1;1)

 

[C@thy]

Re : formule de dates (again!)

Yaisse, myapple😛, ces deux formules fonctionnent,

un grand merci à toi,

cela dit, comme je suis curieuse (qualité ou défaut plus particulièrement féminin???) j'attends de voir si Tibo va nous trouver une soluce dans le style de ses formules précédentes, c'est à dire dans le style de celle de R@chid qui marche très bien, pour le jour suivant... pour le précédent, c'est plus dur!!!

Bises à tous

C@thy

 

[piga25]

Re : formule de dates (again!)

Bonjour

Un essai avec cela si date en A1

Jour après :

=SERIE.JOUR.OUVRE(A1;1)

Jour avant :

=SERIE.JOUR.OUVRE(A1;-1)

 

[piga25]

Re : formule de dates (again!)

Re

Et avec les fériés

=SERIE.JOUR.OUVRE.INTL(A3;-1;;férié)

 

[C@thy]

Re : formule de dates (again!)

Ah oui, très juste, Piga, je n'y avais pas pensé, c'est une autre soluce,
cela dit, il faut installer l'utilitaire d'analyse, ce qui n'est pas toujours le cas chez mes utilisateurs...

merci d'être sorti de ta grotte pour moi! 😉

Bises

C@thy

C@thy

 

[R@chid]

Re : formule de dates (again!)

Bonjour @ tous,
Pardon je suis allé faire la prière on est le vendredi,
essayer avec :

=A1-1-(JOURSEM(A1)<=2)*(JOURSEM(A1))

Amicalement

 

[YANN-56]

Re : formule de dates (again!)

Bonjour C@thy, aux participants et à tous,
(Clin d'oeil particulier à R@chid 🙂)

Je pense que, ci-dessus, tu as trouvé aide efficace en matière de formule.
Là je ne sais rien faire, et suis impressionné par cet art de savoir utiliser une feuille Excel.

De mon coté, je suis en train de m'amuser avec la gestion des dates sur un calendrier via VBA.

J'ai constaté que les manipulations s'avèrent moins complexes, et plus souples qu'avec les formules.

Si, dans ton projet, tu penses que la présence d'un USF ne va pas effrayer tes utilisateurs,
on peut partir dans ce sens.

Pour le reste, j'aurai à te demander les résultats escomptés, et les options qui en découlent.

Amicalement, et disposé à avancer avec toi, si tu le souhaites.

Yann