Fonction SI + espaces insécable

[bloublou]

Bonjour à tous,

J'aurais besoin de vos lumières sur une formule.

Je voudrais faire une fonction SI qui permette de supprimer des espaces insécables car32dans un premier temps ou sinon de prendre les 8 premiers caractères.

Excel ne reconnait pas ma formule avec l'espace insécable, pouvez-vous m'aider ? 😕

Merci

BlouBlou

 

[Jocelyn]

Re : Fonction SI + espaces insécable

Bonjour le Forum
Bonjour Bloublou,

Tu peux tester ta formule de cette façon

=SI(ESTNUM(CHERCHE(CAR(32);A1));SUBSTITUE(A1;CAR(32);"");GAUCHE(A1;8))

par contre par exemple pour A1 une fois les espaces supprimé tu as plus de 8 caractère, si donc tu ne veux toujours que 8 caractères il faut modifier de cette façon

=SI(ESTNUM(CHERCHE(CAR(32);A1));GAUCHE(SUBSTITUE(A1;CAR(32);"");8);GAUCHE(A1;8))

Cordialement

 

[Monique]

Re : Fonction SI + espaces insécable

Bonjour,

Ou bien les espaces enlevés, ou bien 8 caractères

=SI(ESTNUM(TROUVE(CAR(32);A1;1));SUBSTITUE(A1;CAR(32);"");GAUCHE(A1;8))

8 caractères, une fois enlevés ou non les espaces insécables

=GAUCHE(SUBSTITUE(A1;CAR(32);"");8)

Re, Jocelyn, on a pensé à la même chose

 

[bloublou]

Re : Fonction SI + espaces insécable

Bonjour,

Merci à Jocelyn et Monique ca marche nickel 🙂 🙂 🙂

Bonne journée

BlouBlou

 

[Modeste geedee]

Re : Fonction SI + espaces insécable

Bonsour®
😕
le caractère "espace insécable" a pour code Ascii =160...
il n'y a aucun caractère de ce type dans les données fournies en exemple.

soit remplacement des espaces insécables par des espaces standard
=Substitue(A1;Car(160);Car(32))
soit remplacement des espaces insécables par rien ("")
=Substitue(A1;Car(160);"")

ensuite appliquer une troncature à 8 caractères :
=Gauche(Substitue(A1;Car(160);Car(32));8) ' on garde les espaces insécables devenus "normaux"
ou bien
=Gauche(Substitue(A1;Car(160);"");8)' on ne supprime que les espaces insécables
ou encore
=Gauche(Substitue(Substitue(A1;Car(160);"");Car(32);"");8) ' suppression des 2 types d'espaces