fonction MAX() mais avec du texte ??

[christophe90]

Bonjour le forum,

J'ai une vingtaine d' arguments dans une colonne et je voudrais savoir quel est celui qui est le plus fréquent, il s'agit en gros de la fonction max mais vu que c'est du texte ca marche pas, je peux utiliser quoi SVP ??

Salutations

 

[Monique]

Re : fonction MAX() mais avec du texte ??

Bonjour,

A essayer.
Les arguments en colonne A
=INDEX(A2:A10;EQUIV(MAX(NB.SI(A2:A10;A2:A10));NB.SI(A2:A10;A2:A10);0))
Formule matricielle, à valider par ctrl, maj et entrée.

 

[christophe90]

Re : fonction MAX() mais avec du texte ??

Non ca ne marche pas , dans ma cellule ça me met #Nom? que je mette la cellule en format standard ou texte, vous avez pas une autre idée SVP ??

 

[Jocelyn]

Re : fonction MAX() mais avec du texte ??

Bonjour le Forum,
Bonjour christophe90, Monique,

Si si la formule de Monique fonctionne parfaitement comme toutes ses formules d'ailleurs.

ton probleme de renvoie d'erreur #Nom vient simplement du fait que tu as fait un copié collé de la formule hors si tu regarde bien

=INDEX(A2:A10;EQUIV(MAX(NB.SI(A2:A10;A2:A10));NB.S I(A2:A10;A2:A10);0))

dans le NB.SI ecrit en rouge le forum a ajouté un espace entre le S et le I il suffit de l'enlever de valider et ca fonctionne.

Jocelyn

 

[christophe90]

Re : fonction MAX() mais avec du texte ??

Ah oki !! Désolé et merci à vous deux , bonne journée à bientot

Salutations
Christophe

 

[christophe90]

Re : fonction MAX() mais avec du texte ??

Euh zut y'a toujours une erreur, maintenant c'est "N/A

 

[Monique]

Re : fonction MAX() mais avec du texte ??

Re,

Je viens de malmener la formule dans tous les sens,
j'ai obtenu #N/A en plaçant mal les parenthèses.

Vérifie bien la place de tes parenthèses
=INDEX(Zone;EQUIV(MAX(NB.SI(Zone;Zone));NB.SI(Zone;Zone);0))

 

[Jocelyn]

Re : fonction MAX() mais avec du texte ??

re,

Dans le fichier joint il y a deux fois la formule qui renvoie #N/A avec l'explication et une fois ou elle est bonne.

http://cjoint.com/?hgra6XpmC0

j'espere que cela te permetras de coriger.

Jocelyn

 

[ZZR09]

Re : fonction MAX() mais avec du texte ??

Bonjour Christophe90, Monique, Jocelyn et au forum,

cette question m'intéressait et j'ai donc fait quelques essais (infructueux je dois l'avouer). J'ai fini par tester la formule de Monique qui, comme le souligne Jocelyn, fonctionne à merveille... sauf que dans mon essai (une liste de prénoms) j'ai deux ex-equo. Cette formule ne me renvoit que le premier des deux résultats. je me suis tourné du coté des tableaux croisés dynamiques mais, sans résultats ... avis aux amateurs de questions tordues :

comment peut-on (hors VBA) savoir le nombre d'ex-equos et tous les afficher si nécessaire ?

A+
Je vais me torturer un peu les méninges!

 

[christophe90]

Re : fonction MAX() mais avec du texte ??

Merci à tous, pour le savoir si y'a des ex aquo , ca m'intéresse aussi 🙂

 

[christophe90]

Re : fonction MAX() mais avec du texte ??

Ah je viens de comprendre pourquoi ca ne marchait pas des fois, en fait g plein de cellules vides ( c un tableau que je viens coller avec trie non vides ), donc ca ne m'affiche rien car ce que g le plus c du vide, alors je vous sollicite encore :

C possible de faire pareil mais en ignorant les vides ??

Merci d'avance et dsl d'avoir mal posé les données de départ mais j'y avait pas pensé

Salutations
Christophe

 

[Monique]

Re : fonction MAX() mais avec du texte ??

Bonjour,

Une plage de noms nommée "Zone"

Extraction sans doublons du plus fréquent au moins fréquent :
en C2 :
=INDEX(Zone;EQUIV(MAX(SI(NB.SI(C$1:C1;Zone)=0;NB.SI(Zone;Zone)));SI(NB.SI(C$1:C1;Zone)=0;NB.SI(Zone;Zone));0))&""
puis copier-coller vers le bas
Formule matricielle, à valider par ctrl, maj et entrée
Le &"" fait que les 0 n'apparaissent pas.

 

[christophe90]

Re : fonction MAX() mais avec du texte ??

Ah super, ça y est c parfait pour moi !!!

Merci beaucoup Monique, c très gentil !!!!!

Passe une bonne journée
Salutations
Christophe

 

[Monique]

Re : fonction MAX() mais avec du texte ??

Re,

Suite…

Extraction sans doublons du moins fréquent au plus fréquent.
(il y a une condition à mettre en plus)
en D2 :
=INDEX(Zone;EQUIV(MIN(SI(Zone<>"";SI(NB.SI(D$1😀1;Zone)=0;NB.SI(Zone;Zone))));SI(NB.SI(D$1😀1;Zone)=0;NB.SI(Zone;Zone));0))&""
puis copier-coller vers le bas
Formule matricielle, à valider par ctrl, maj et entrée

Edit
A la place du truc vert, deux point puis D