Microsoft 365 excel

[louis59]

Bonjour à tous

J'ai besoin d'aide…

Je souhaite créer un tableau Excel qui se présente de la façon suivante :

• Colonne A : liste de dates parfois répétées (format 22/10/2022)
• Colonne B : listes d'heures toutes différentes liées au dates de la colonne A (format 08:00)
• Colonne C : listes de valeurs liées aux heures de la colonne B (format nombre sans décimale)

Je souhaite extraire une valeur ( de C) pour un jour spécifique de la colonne A et a une plage d'heure ( de B) spécifique.

Par exemple :

Quelle est la valeur mini de C qui correspond la plage horaire 8h00 – 9h00 du 22/10/2022.

J'ai songé à la formule MIN.SI.ENS…

…Mais cela ne fonctionne pas !

J'ai du mal à comprendre comment formuler ma plage d'heure

 

[Wayki]

Bonsoir,
Sans fichier c'est pas très clair surtout sur l'utilité de la colonne C si elle est égal à B. Il faut savoir qu'une journée de 24h dans excel est égal à 1 (12:00 = 0,5 car 12/24 = 0,5).
Par conséquent, la formule que vous recherchez doit être celle ci :

=TEXTE(INDEX(A1:A7+B1:B7;PETITE.VALEUR(SI(((A1:A7+B1:B7)<B10)*((A1:A7+B1:B7)>A10);LIGNE(1:7));1));"jj/mm/aaaa hh:mm:ss")

A condition de trier les données par ordre croissant au préalable.
A +

 

[job75]

Bonsoir louis59, Wayki,

Quelle est la valeur mini de C qui correspond la plage horaire 8h00 – 9h00 du 22/10/2022.

J'ai songé à la formule MIN.SI.ENS…

Oui :

=MIN.SI.ENS(C1:C1000;A1:A1000;"22/10/2022";B1:B1000;">=8:0";B1:B1000;"<=9:0")

Limite 1000 à adapter.

A+

 

[sylvanu]

Bonjour Louis,Wayki, Job,
Ou encore avec aussi peu d'informataions, une tentative en PJ avec :

=MIN(SI(A:A  = F6;SI(B:B>=G6;SI(B:B<=H6;B:B;""))))

A valider avec Maj+Ctrl+Entrée.

 

[job75]

Limite 1000 à adapter.

Les plages illimitées sont acceptées :

=MIN.SI.ENS(C:C;A:A;"22/10/2022";B:B;">=8:0";B:B;"<=9:0")

 

[louis59]

Bonsoir louis59, Wayki,

Oui :

=MIN.SI.ENS(C1:C1000;A1:A1000;"22/10/2022";B1:B1000;">=8:0";B1:B1000;"<=9:0")

Limite 1000 à adapter.

A+

bonjour,
merci, tout fonctionne, ta réponse a solutionné mon problème.
je l'ai employée pour d'autres formules : SI.MIN.ENS, MAX, MOY, etc.
mon souci était la syntaxe.
il me reste un dernier point a comprendre ; comment remplacer le résultat d'une formule dans sa cellule par du texte (par exemple "non mesuré) lorsque le résultat obtenu est zéro (souvent parce qu'il manquait une info dans la plage MINI ).
merci encore, il est plus important pour moi de comprendre que d'obtenir un résultat.

 

[job75]

Bonjour louis59,

comment remplacer le résultat d'une formule dans sa cellule par du texte (par exemple "non mesuré) lorsque le résultat obtenu est zéro

Par exemple :

=SIERREUR(EXP(LN(MIN.SI.ENS(C:C;A:A;"22/10/2022";B:B;">=8:0";B:B;"<=9:0")));"non mesuré")

Quand MIN.SI.ENS est nulle la fonction LN renvoie une valeur d'erreur.

A+