evaluer formule sommeprod + equiv

[bricorico83]

Bonjour à tous,

Mon cas de figure :

la formule suivante fonctionne bien :
=SOMMEPROD(1/NB.SI('Janv'!$A$4:$A$2850;'Janv'!$A$4:$A$2850))
par contre la formule suivante ne fonctionne pas
=SOMMEPROD(1/NB.SI('Fev'!$A$4:$A$2850;'Fev!$A$4:$A$2850))
tout simplement parce que le mois de février contient moins de lignes renseignées que le mois de janvier.

La solution envisagée :

Je recherche le nombre de ligne non-vide par la formule :
=EQUIV("zz";'fev'!A:A)
qui fonctionne et me renvoie le bon n° de ligne (ex : 2442)

Mon problème :

Impossible de concaténer ces 2 fonctions et les faire fonctionner ensemble !!!
Je sais que cela doit être très simple et que par conséquent je suis un idiot mais à mon âge je crois que c'est trop tard 😉

Merci pour votre aide

Eric

 

[tdenfert]

Re : evaluer formule sommeprod + equiv

Bonjour;

=SOMMEPROD(SI(ESTVIDE(Janv!$A$1:$A$2850);0;(1/NB.SI(Janv!$A$1:$A$2850;Janv!$A$1:$A$2850))))
Formule matricielle a valider en faisant ctrl maj enter

 

[bricorico83]

Re : evaluer formule sommeprod + equiv

Merci,

Cela ne répond pas à mon pb d'interprétation des 2 fonctions mais cette solution fonctionne parfaitement.
Je ne suis pas un amateur des formules matricielles car nécessitent de multiples manipulation lorsque l'on souhaite les coller dans d'autres fichiers
Mais l'objectif est rempli !
Merci bp

 

[job75]

Re : evaluer formule sommeprod + equiv

Bonjour bricoricot83, tdenfert,

Formule "normale" qui devrait fonctionner quel que soit le nombre de cellules vides :

=SOMMEPROD(1/NB.SI(Fev!$A$4:$A$2850;""&Fev!$A$4:$A$2850))-SIGNE(NB.VIDE(Fev!$A$4:$A$2850))

En effet l'ensemble des cellules vides correspond a une cellule sans doublons.

Edit : j'avais oublié ""& dans NB.SI 😡

A+

 

[job75]

Re : evaluer formule sommeprod + equiv

Re,

S'il y a dans la plage des formules qui renvoient le texte vide "" il faut utiliser plutôt :

=SOMMEPROD(1/NB.SI(Fev!$A$4:$A$2850;""&Fev!$A$4:$A$2850))-SIGNE(NB.SI(Fev!$A$4:$A$2850;""))

Edit : j'avais oublié ""& dans le 1er NB.SI 😡

A+