donner des noms aux feuilles à partir de cellules de la première feuille

[Rd01]

Bonjour à tous,
Je souhaiterais recevoir de l’aide pour donner des noms aux feuilles à partir de cellules de la première feuille.

Explication :
Ma première feuille est une liste de nom (environs 150).
Je souhaiterais savoire (exemple : une macro) comment crée automatiquement une feuille pour chaque nom de ma liste et qui serait automatiquement nommé.
De plus je souhaiterai que dans cette feuille soit inscrit le nom dans une cellule.
Voir image ci-dessous :
Mon niveau en macro est très bas(voir inexistant).

Je vous remerci par avance de votre aide, en esperant que ma demande soit comprehensible.

 

[Pierrot93]

Re : donner des noms aux feuilles à partir de cellules de la première feuille

Bonjour,

essaye ceci :

Option Explicit
Sub test()
Dim i As Long
With Sheets("Liste des noms")
For i = 1 To .Cells(.Rows.Count, 1).End(xlUp).Row
    Sheets.Add(, Sheets(Sheets.Count)).Name = .Cells(i, 1)
Next i
End With
End Sub

bonne journée
@+

 

[Pierrot93]

Re : donner des noms aux feuilles à partir de cellules de la première feuille

Re,

oups... oublié de mettre le nom dans la cellule...

Option Explicit
Sub test()
Dim i As Long
With Sheets("Liste des noms")
For i = 1 To .Cells(.Rows.Count, 1).End(xlUp).Row
    Sheets.Add(, Sheets(Sheets.Count)).Name = .Cells(i, 1)
    Cells(1, 1) = .Cells(i, 1)
Next i
End With
End Sub

 

[CBernardT]

Re : donner des noms aux feuilles à partir de cellules de la première feuille

Bonjour Rd01,

Salut Pierrot93,

Un classeur avec liste des noms en premier onglet.
Avec le bouton de commande, ajout des onglets dont les noms sont absents de la liste.

 

[Rd01]

Re : donner des noms aux feuilles à partir de cellules de la première feuille

Bonjour Pierrot93 et CBernardT,
je tiens a vous remercier de votre rapidité et de vos reponses qui correspondent parfaitement a mon besoin 🙂
Pourriez vous m'aider a nouveau,
1: je souhaite que ma premiere page soit un "sommaire" et que lorsque je clique sur le nom, j'atteri sur la page du meme nom (lien hypertexte).
Est ce qui existe un moyen de le faire en automatique, ou alors je suis obligé de crée un lien hypertexte pour chaques nom
2: Je n'arive pas a ajouter un lien hypertexte identique (retour sommaire) sur toutes les pages en mode simultané quel methode existe t-il?

Cordialement

 

[Pierrot93]

Re : donner des noms aux feuilles à partir de cellules de la première feuille

Re,
Bonjour Bernard

essaye ceci :

Option Explicit
Sub test()
Dim i As Long
With Sheets("Liste des noms")
For i = 1 To .Cells(.Rows.Count, 1).End(xlUp).Row
    Sheets.Add(, Sheets(Sheets.Count)).Name = .Cells(i, 1)
    Cells(1, 1) = .Cells(i, 1)
    .Hyperlinks.Add Anchor:=.Cells(i, 1), Address:="", SubAddress:= _
        .Cells(i, 1).Value & "!A1", TextToDisplay:=.Cells(i, 1).Value
    ActiveSheet.Hyperlinks.Add Anchor:=Cells(1, 2), Address:="", SubAddress:= _
        "'Liste des noms'!A1", TextToDisplay:="Retour sommaire"
Next i
End With
End Sub

 

[Pierrot93]

Re : donner des noms aux feuilles à partir de cellules de la première feuille

Re,

si espace dans le nom des feuilles :

Option Explicit
Sub test()
Dim i As Long
With Sheets("Liste des noms")
For i = 1 To .Cells(.Rows.Count, 1).End(xlUp).Row
    Sheets.Add(, Sheets(Sheets.Count)).Name = .Cells(i, 1)
    Cells(1, 1) = .Cells(i, 1)
    .Hyperlinks.Add Anchor:=.Cells(i, 1), Address:="", SubAddress:= _
        "'" & .Cells(i, 1).Value & "'!A1", TextToDisplay:=.Cells(i, 1).Value
    ActiveSheet.Hyperlinks.Add Anchor:=Cells(1, 2), Address:="", SubAddress:= _
        "'Liste des noms'!A1", TextToDisplay:="Retour sommaire"
Next i
End With
End Sub

 

[Rd01]

Re : donner des noms aux feuilles à partir de cellules de la première feuille

Re,
Un très grand merci a toi Pierrot93 pour l'aide que tu m'a apporté, ta macro fonctionne très bien et correspond parfaitement a mes attentes.

Pouvez vous me conseillez un didactitiel pour apprendre a créer des macros avec la meme complexité que tu m'a crée?

Cordialement.

Rd01